2

我有以下 XSL：

<?xml version='1.0'?>
<xsl:stylesheet xmlns:xsl='http://www.w3.org/1999/XSL/Transform' version='1.0'>
  <xsl:param name='width' select ="270"/>
  <xsl:param name='height' select="180"/>
  <xsl:variable name="counter" select="0" />
  <xsl:template name="while">
    <svg xmlns="http://www.w3.org/2000/svg" version="1.1">
      <line x1="{$counter}" y1="0.5" x2="{$counter}" y2="10.5" stroke="black" stroke-width="1" />
      <xsl:variable name="counter" select="$counter + 10" />
      <xsl:if test="$counter &lt; $width">
        <xsl:call-template name="while"/>
      </xsl:if>
    </svg>
  </xsl:template>
</xsl:stylesheet>

我试图在宽度上每隔 10 像素画一条线，就像标尺标记一样。

当我运行这段代码时，它陷入了一个循环。我无法调试，我只是得到一个堆栈溢出异常。我假设我的计数器值没有增加 10，或者我对检查计数器 < 宽度的评估是否不正确。

有人可以指出我正确的方向吗？

4

2 回答 2

2

我认为您需要在调用模板时传递参数。

就像是：

<xsl:template name="loop">
    <xsl:param name="count" select="1"/>

    <xsl:if test="$count > 0">
        <xsl:call-template name="loop">
            <xsl:with-param name="count" select="$count - 1"/>
        </xsl:call-template>

        <xsl:value-of select="$count"/>  
        <xsl:text> </xsl:text>

    </xsl:if>    
</xsl:template>
于 2013-08-21T17:15:48.033 回答
1

您需要通过使用将计数传递给您的模板xsl:with-param。

例子：

<xsl:stylesheet xmlns:xsl='http://www.w3.org/1999/XSL/Transform' version='1.0'>
    <xsl:output indent="yes"/>
    <xsl:param name='width' select ="270"/>
    <xsl:param name='height' select="180"/>

    <xsl:template match="/">
        <svg xmlns="http://www.w3.org/2000/svg" version="1.1">          
            <xsl:call-template name="while"/>
        </svg>
    </xsl:template>

    <xsl:template name="while">
        <xsl:param name="currentCount" select="0"/>
        <line x1="{$currentCount}" y1="0.5" x2="{$currentCount}" y2="10.5" stroke="black" stroke-width="1" />
        <xsl:variable name="counter" select="$currentCount + 10" />
        <xsl:if test="$counter &lt; $width">
            <xsl:call-template name="while">
                <xsl:with-param name="currentCount" select="$counter"/>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>

</xsl:stylesheet>
于 2013-08-21T17:20:39.463 回答