2

我有一个包含链接表的数据库——员工、课程和 Training_Record。每个工作人员都有一个数字主键，每个课程和 Training_Record 表中的每个条目也是如此。员工和课程的 Training_Record 参考记录中的 Staff_ID 和 Course_ID。

添加工作人员或课程时，Training_Record（字段：Staff_ID、Course_ID、Date_Taken、Notes）插入了工作人员、课程记录 - 因此添加工作人员 1 将插入记录 (1,1,,,), (1,2 ,,,) 等，添加课程 8 将插入记录 (1,8,,,), (2,8,,,) 等等。这行得通。

然后我有一个表格来记录培训。用户选择课程，输入日期并从列表框中选择工作人员。我有一个触发 VBA 代码的保存按钮。日期和课程从框中拉出，我在列表框周围循环，将选定的员工连接成一个字符串。这一切正常，并显示一个消息框，验证这一点。然后，应该运行更新 SQL 查询，更新 Training_Record。

我遇到的问题是 SQL 更新。我有一个可以在 SQL 查询编辑器中使用的更新查询，尽管它使用写入变量：

UPDATE Training_Record
SET Date_Taken = '12/12/12'
WHERE Staff_ID IN (1,2,3,4,5) AND Course_ID = 4

这将更新 Training_Record 以显示员工 1、2、3、4 和 5 于 2012 年 12 月 12 日参加了课程 4。但是，在 VBA 中这不起作用。这是我在 VBA 中的 SQL 查询：

strSQL = "UPDATE Training_Record" _
       & "SET Date_Taken = (" & strDate & ")" _
       & "WHERE Staff_ID IN (" & strCriteria & ") AND Course_ID = (" & strCourse & ")"

DoCmd.RunSQL strSQL

代码生成的错误是“运行时错误'3144'：UPDATE 语句中的语法错误”。并且调试器突出显示查询后的 DoCmd.RunSQL 语句。整个 VBA 代码：

Private Sub SaveTraining_Click()

Dim db As DAO.Database
Dim VarItem As Variant
Dim strCriteria As String
Dim strDate As Variant
Dim strCourse As Variant
Dim strSQL As String

Set db = CurrentDb()

'Extract the course ID and the training date from the form
strCourse = Me!CourseID.Value
strDate = Me!TrainingDate.Value

'Dealing with empty boxes- zero length
If IsNull(strCourse) Then
    MsgBox "Please select a course." _
        , vbOKOnly, "No course selected"
End If

If IsNull(strDate) Then
    MsgBox "Please enter a date." _
        , vbOKOnly, "No date given"
End If

If StaffMembers.ItemsSelected.Count = 0 Then
    MsgBox "Please select staff members." _
        , vbOKOnly, "No staff members"
End If

If (Not IsNull(strCourse)) And (Not IsNull(strDate)) And (StaffMembers.ItemsSelected.Count > 0) Then

    'Extract each selected member and concatenate into a string for sql query

    For Each VarItem In Me!StaffMembers.ItemsSelected
        strCriteria = strCriteria & "," & Me!StaffMembers.ItemData(VarItem)
    Next VarItem

    'Gets rid of extra comma on query string
    strCriteria = Right(strCriteria, Len(strCriteria) - 1)

    'Message box
    MsgBox ("Staff: " & strCriteria & vbNewLine & "Date: " & strDate & vbNewLine & "Course: " & strCourse & vbNewLine & "No. Selected staff: " & StaffMembers.ItemsSelected.Count)

    strSQL = "UPDATE Training_Record" _
           & "SET Date_Taken = (" & strDate & ")" _
           & "WHERE Staff_ID IN (" & strCriteria & ") AND Course_ID = (" & strCourse & ")"

    DoCmd.RunSQL strSQL

End If

Set db = Nothing

End Sub

TL；DR 我无法在 VBA 中运行 SQL UPDATE 查询

我有一种感觉，这是某个地方的语法错误，但我找不到在哪里。任何想法/建议将不胜感激，谢谢。

4

2 回答 2

2

我认为您只是在行尾缺少空格

你的旧查询打印出来

UPDATE Training_RecordSET Date_Taken = ()WHERE Staff_ID IN () AND Course_ID = ()

SET如您所见，在关键字和之前会有名称冲突WHERE

因此将您的更改strSQL为

strSQL = "UPDATE Training_Record " _
       & "SET Date_Taken = (" & strDate & ") " _
       & "WHERE Staff_ID IN (" & strCriteria & ") AND Course_ID = (" & strCourse & ")"

打印为（未提供任何值）

UPDATE Training_Record SET Date_Taken = () WHERE Staff_ID IN () AND Course_ID = ()

这在 SQL 语法方面是正确的

如果我是你，我还会检查Training_Record表中列的数据类型

通常 （这适用于 Type-mismatch error），

对于日期，您将变量或值包装在两侧#

例子& "SET Date_Taken = (#" & strDate & "#) ...

对于使用单引号的字符串'

例子WHERE Operator_Name = ('" & operName & "') ...

对于数值，您不需要使用任何东西，但可以提供正确的数据类型

于 2013-08-21T12:51:40.000 回答
0

我猜： 

strSQL = "UPDATE Training_Record" _
       & "SET Date_Taken = (#" & Format(strDate, "mm\/dd\/yyyy") & "#)" _
       & "WHERE Staff_ID IN (" & strCriteria & ") AND Course_ID = (" & strCourse & ")"

如果 staff_ID 是一个字符串： 

strSQL = "UPDATE Training_Record" _
       & "SET Date_Taken = (#" & Format(strDate, "mm\/dd\/yyyy") & "#)" _
       & "WHERE Staff_ID IN ('" & strCriteria & "') AND Course_ID = (" & strCourse & ")"
于 2013-08-21T12:27:38.527 回答