57

我不想在交叉编译项目的源代码树中包含静态库，而是直接将 boost 添加到 cmake 中并构建它。这是可用的吗？

4

2 回答 2

45

在我的工作场所，我们也为此苦苦挣扎。虽然我当然不能声称知道“最好”的方式，但我可以就我的经历提供以下想法。

我们最初只要求开发人员单独安装 boost，并让 CMake 以find_package(Boost...)调用的形式进行正常检查。这很容易，但不是自动化的，并且给已经安装了旧版本 boost 的开发人员带来了问题。

然后我们改变了策略并添加了我们从您上面提到的一个项目中克隆的增强源的副本。我不记得具体细节了，但我认为这是 Ryppl 项目目前正在开发的一个前身。重点是它已经支持 CMake。boost 库是通过add_library调用添加的实际 CMake 目标，这使得它们更容易在 CMake 代码中使用。

虽然这通过在我们的项目中自动使用 boost 解决了之前的问题，但它最终变成了维护的噩梦。我们克隆的 boost 项目发生了根本性的变化，现在非常依赖于 Ryppl 特定的 CMake 函数。我们不想将 Ryppl 添加为依赖项，所以我们再次改变了策略！

我们查看了您在问题中提到的项目，同样发现它们都不可用。

我们当前的设置使用了 CMake 的ExternalProject模块。这使我们能够下载并构建提升到我们的构建树。

优点：

  • 低维护
  • 自动化，因此所有开发人员都使用使用相同标志构建的相同版本
  • 使我们自己的源代码树不受第三方代码的影响
  • boost 的多个副本可以愉快地共存（因此不会意外链接到使用不同编译器/stdlib 组合构建的副本）

缺点

  • 删除构建树意味着必须从头开始下载和构建 boost。这可以通过例如下载到固定位置（例如，系统临时目录）来改善，因此如果找到了增强源的现有副本，则可以跳过下载/解压缩步骤。
  • boost 库不是正确的 CMake 目标（即它们没有通过add_library调用添加）

这是我们的 CMake 代码的链接。有几种方法需要改进，但它目前对我们来说效果很好。

我希望这个答案很快就会过时，并且可以使用一个体面的、模块化的、兼容 CMake 的解决方案。

于 2013-08-21T12:46:00.127 回答
5

我发现上面 Fraser 的回答是一个很好的起点，但是在我们的系统上使用 Boost 1.55.0 时遇到了一些问题。

首先，我们希望为我们的应用程序提供一个独立的源代码包，因此不希望使用 CMake ExternalProject。我们只使用了来自 Boost 的 thread 和 date_time 库，所以我们使用 bcp 创建了 Boost 的一个子集，其中包括构建工具、thread 和其他依赖库：

$ bcp tools/build thread system date_time ../boost_1_55_0_threads_only

并将其检查到我们的 svn 存储库中。

接下来，我能够调整 Fraser 的 CMake 文件以在 Linux 上构建，但在bootstrap.bat使用 CMake 的 execute_process 命令在 Windows 上运行该文件时遇到了问题。要运行 bootstrap.bat，我们首先需要运行相关的 Visual Studiovcvarsall.bat脚本来设置环境变量（我们可能会弄清楚需要设置哪些单独的变量，但运行整个脚本更容易）。为了使用 execult_process 在同一个 shell 中运行两个 .bat 文件，我们使用cmd /c并列出了由 a 分隔的文件&作为参数。

在失败的情况下也bootstrap.bat没有将退出代码设置为非零，因此使用 execute_process RESULT_VARIABLE 检查是否成功不起作用。相反，我们检查了在命令运行后是否创建了 b2.exe 可执行文件。

最后一个问题：支持不bootstrap.sh支持的--prefix=选项。bootstrap.bat我还发现在 windows 上指定--prefix选项是有效的，但是在 Linux 上使用选项而不指定它会给出错误。（我还不明白为什么）。b2.exe--prefixb2bootstrap.sh

所以我们的 CMake 文件的相关部分如下所示：

  #
  # run bootstrap
  #
  if(WIN32)
    if(MSVC10)
      set(VCVARS_CMD "C:\\Program^ Files^ ^(x86^)\\Microsoft^ Visual^ Studio^ 10.0\\VC\\vcvarsall.bat")
    elseif(MSVC11)
      set(VCVARS_CMD "C:\\Program^ Files^ ^(x86^)\\Microsoft^ Visual^ Studio^ 11.0\\VC\\vcvarsall.bat")
    elseif(MSVC12)
      set(VCVARS_CMD "C:\\Program^ Files^ ^(x86^)\\Microsoft^ Visual^ Studio^ 12.0\\VC\\vcvarsall.bat")
    # elseif(...)
     # add more options here
    endif(MSVC10)
    set(BOOTSTRAP_CMD "${VCVARS_CMD} & bootstrap.bat")
    message("Executing command: ${BOOTSTRAP_CMD}")
    execute_process(COMMAND cmd /c "${BOOTSTRAP_CMD}" WORKING_DIRECTORY ${APT_BOOST_SRC}
                  RESULT_VARIABLE BS_RESULT OUTPUT_VARIABLE BS_OUTPUT ERROR_VARIABLE BS_ERROR)
    if(NOT EXISTS ${APT_BOOST_SRC}/b2.exe)
      message(FATAL_ERROR "Failed running cmd /c ${BOOTSTRAP_CMD} in ${APT_BOOST_SRC}:\n${BS_OUTPUT}\n${BS_ERROR}\n")
    else(NOT EXISTS ${APT_BOOST_SRC}/b2.exe)
      message("bootstrap output:\n${BS_OUTPUT}")
    endif(NOT EXISTS ${APT_BOOST_SRC}/b2.exe)
  else(WIN32)
    set(BOOTSTRAP_CMD "./bootstrap.sh")
    set(BOOTSTRAP_ARGS "--prefix=${APT_BOOST_BIN}")
    message("Executing command: ${BOOTSTRAP_CMD} ${BOOTSTRAP_ARGS}")
    execute_process(COMMAND "${BOOTSTRAP_CMD}" ${BOOTSTRAP_ARGS} WORKING_DIRECTORY ${APT_BOOST_SRC}
                  RESULT_VARIABLE BS_RESULT OUTPUT_VARIABLE BS_OUTPUT ERROR_VARIABLE BS_ERROR)
    if(NOT BS_RESULT EQUAL 0)
      message(FATAL_ERROR "Failed running ${BOOTSTRAP_CMD} ${BOOTSTRAP_ARGS} in ${APT_BOOST_SRC}:\n${BS_OUTPUT}\n${BS_ERROR}\n")
    endif()
  endif(WIN32)
  #
  # run b2
  #
  set(B2_ARGS "link=static" "threading=multi" "runtime-link=static" "variant=release")
  foreach(COMP IN LISTS APT_BOOST_COMPONENTS)
    set(B2_ARGS "--with-${COMP}" ${B2_ARGS})
  endforeach(COMP IN LISTS APT_BOOST_COMPONENTS)
  if(WIN32)
    if(MSVC11)
      set(B2_ARGS "--toolset=msvc-11.0" ${B2_ARGS})
    elseif(MSVC12)
      set(B2_ARGS "--toolset=msvc-12.0" ${B2_ARGS})
    endif(MSVC11)
    file(TO_NATIVE_PATH ${APT_BOOST_BIN} APT_BOOST_BIN_WIN)
    set(B2_ARGS "--prefix=${APT_BOOST_BIN_WIN}" ${B2_ARGS} "architecture=x86" "address-model=64")
  endif(WIN32)
  set(B2_ARGS ${B2_ARGS} install)
  set(B2_CMD "./b2")
  message("Executing command: ${B2_CMD} ${B2_ARGS}")
  execute_process(COMMAND ${B2_CMD} ${B2_ARGS} WORKING_DIRECTORY ${APT_BOOST_SRC}
                  RESULT_VARIABLE B2_RESULT OUTPUT_VARIABLE B2_OUTPUT ERROR_VARIABLE B2_ERROR)
  if(NOT B2_RESULT EQUAL 0)
    message(FATAL_ERROR "Failed running ${B2_CMD} in ${APT_BOOST_SRC}:\n${B2_OUTPUT}\n${B2_ERROR}\n")
  endif()

上面APT_BOOST_SRC是我们源目录中 Boost 子目录APT_BOOST_BIN的位置，是我们用来在 CMake 构建目录中存储库的位置，并且APT_BOOST_COMPONENTS是我们正在使用的 Boost 库的列表。

于 2014-07-28T19:42:06.687 回答