1

更新： 我已将此错误隔离到在此选择中注册 onchange 事件。如果我删除了 onchange，页面将无错误地呈现，否则我会收到No javascript provider错误。

<g:select optionKey="id" optionValue="name" name="course" id="course"
   from="${com.TourneyCard.Course.list(sort:'name')}" value="${homeCourse.id}"
   onchange="${remoteFunction(controller:'foursome', action:'ajaxGetTeesJSON',
     params:'\'id=\' + escape(this.value)', 
     onSuccess:'updateTees(data);')}">
</g:select>

由于各种原因，我想使用资源插件而不是 jQuery 插件来包含 jQuery。它大部分都在工作，但我有一个不会呈现的页面，而是发出错误No javascript provider is configured。

我的 ApplicationResources.groovy 定义了 jquery：

jquery {
    resource url: 'js/jquery/jquery-1.9.1.min.js', disposition: 'head'
}

我的 main.gsp 布局如下所示：

<head>
    <g:layoutHead/>
    <g:javascript library="jquery"/>
    <r:require module="jquerymobile"/>
    <r:layoutResources />
</head>

发出未配置提供程序错误的页面如下所示：

<head>
    <meta content="main" name="layout">
    <r:require modules="jqmdatebox,jqmgrid960,updateTees"/>
    ....
</head>
<body>
    ....
    <g:javascript>
        var zselect = document.getElementById('tee')
        var zopt = zselect.options[zselect.selectedIndex]
    </g:javascript>
</body>
4

5 回答 5

2

由于您手动设置 JQuery 资源，因此无需设置：

<g:javascript library="jquery"/>

相反，只需要你的模块：

<r:requires module="jquery, jquerymobile"/>

编辑

查看您的新信息，我认为您的问题出在remoteFunction方法上。因为它需要知道您正在使用哪个 javascript 库。尝试添加<g:setProvider library="jquery"/>到您的页面。

于 2013-08-20T23:20:46.420 回答
1

我刚刚解决了由g:remoteLink标签引起的相同错误。我发现我需要打电话 两次。一个在头部，另一个在你应该从中加载 js 文件的页脚。我还必须在 BuildConfig.groovy 中添加 jQuery 作为插件

plugins {
    runtime ":jquery:1.8.3"
    runtime ':resources:1.2'
    ...
}

我的 main.gsp 有

  <r:require modules="app, jquery" />
  <g:setProvider library="jquery" />
  <r:layoutResources/>
  <g:layoutHead />

我最后有 g:layoutHead，所以 jQuery 在可能需要它的脚本之前加载。

如果您只是内联一些脚本，则可能需要查看

如果您使用此标签来呈现内联 JavaScript 代码，建议您使用 Resources 插件的标签来生成包含在正文末尾或必要时包含在头部的内联脚本 - 而不是内联。如需更多控制，请直接使用 Resources 插件的标签。-

于 2013-09-04T04:11:03.457 回答
0

试着放

grails.views.javascript.library = "jquery"

进入 Config.groovy 或插入主布局：

<g:setProvider library="jquery"/>
于 2013-08-21T09:33:27.770 回答
0

这个解决方案对我有用：

将以下类（来自 jquery Grails 插件）添加到您的应用程序

import org.codehaus.groovy.grails.plugins.web.taglib.JavascriptProvider

class JQueryProvider implements JavascriptProvider {

    /**
     * doRemoteFunction creates a jQuery-AJAX-Call
     *
     * @param taglib
     * @param attrs
     * @param out
     *
     * @return the jQuery-like formatted code for an AJAX-request
     */
    def doRemoteFunction(taglib, attrs, out) {
        // Optional, onLoad
        if (attrs.onLoading) {
            out << "${attrs.onLoading};"
        }

        // Start ajax
        out << /jQuery.ajax({/

        // Method
        def method = (attrs.method ? attrs.remove('method') : 'POST')
        out << "type:'$method'"

        // Optional, synchron call
        if ("false" == attrs.asynchronous) {
            out << ",async:false"
            attrs.remove('asynchronous')
        }

        // Optional, dataType to use
        if (attrs.dataType) {
            out << ",dataType:'${attrs.remove('dataType')}'"
        }

        // Additional attributes
        if (attrs.params || attrs.jsParams) {
            if (!(attrs?.params instanceof Map)) {
                // tags like remoteField don't deliver a map
                out << ",data:${attrs.remove('params')}"
            } else {
                out << ",data:{"

                boolean hasParams = false

                if (attrs?.params instanceof Map) {
                    hasParams = true
                    out << attrs.remove('params').collect { k, v ->
                        "\'" +
                                "${k}".encodeAsJavaScript() +
                                "\': \'" +
                                "${v}".encodeAsJavaScript() +
                                "\'"
                    }.join(",")
                }

                if (attrs?.jsParams instanceof Map) {
                    if (hasParams) {
                        out << ","
                    }

                    out << attrs.remove('jsParams').collect { k, v ->
                        "\'" +
                                "${k}".encodeAsJavaScript() +
                                "\': \'" +
                                "${v}".encodeAsJavaScript() +
                                "\'"
                    }.join(",")
                }

                out << "}"
            }
        }

        // build url
        def url = attrs.url ? taglib.createLink(attrs.remove('url')) : taglib.createLink(attrs);
        out << ", url:'${url}'"

        // Add callback
        buildCallback(attrs, out)

        // find all onX callback events
        def callbacks = attrs.findAll { k, v ->
            k ==~ /on(\p{Upper}|\d){1}\w+/
        }

        // remove all onX callback events
        callbacks.each { k, v ->
            attrs.remove(k)
        }

        out << "});"

        // Yeah, I know, return is not needed, but I like it
        return out
    }

    /**
     * Helper method to create callback object
     *
     * @param attrs Attributes to use for the callback
     * @param out Variable to attache the output
     */
    def buildCallback(attrs, out) {
        // TODO check for strlen
        if (out) {
            out << ','
        }

        //*** success
        out << 'success:function(data,textStatus){'

        if (attrs.onLoaded) {
            out << "${attrs.onLoaded};"
        }

        if (attrs.update instanceof Map) {
            if (attrs.update?.success) {
                out << "jQuery('#${attrs.update.success}').html(data);"
            }
        } else if (attrs.update) {
            out << "jQuery('#${attrs.update}').html(data);"
        }

        if (attrs.onSuccess) {
            out << "${attrs.onSuccess};"
        }

        out << '}'

        //*** failure
        out << ',error:function(XMLHttpRequest,textStatus,errorThrown){'

        if (attrs.update instanceof Map) {
            if (attrs.update?.failure) {
                // Applied to GRAILSPLUGINS-1919
                out << "jQuery('#${attrs.update?.failure}').html(XMLHttpRequest.responseText);"
            }
        }

        if (attrs.onFailure) {
            out << "${attrs.onFailure};"
        }

        out << '}'

        if (attrs.onComplete) {
            out << ",complete:function(XMLHttpRequest,textStatus){${attrs.onComplete}}"
        }
    }

    /**
     * Serializes the surrounding form.
     *
     * @param attrs attrs.params to serialize
     */
    def prepareAjaxForm(attrs) {
        // Fix for http://jira.codehaus.org/browse/GRAILSPLUGINS-1865
        if (attrs.forSubmitTag) {
            attrs.params = "jQuery(this).parents('form:first').serialize()".toString()
        }
        else {
            attrs.params = "jQuery(this).serialize()".toString()
        }
    }
}

将此类注册为提供者（用于 AJAX GSP 标签）Bootstrap.groovy

import org.codehaus.groovy.grails.plugins.web.taglib.JavascriptTagLib

class BootStrap {

    def init = { servletContext ->    
        JavascriptTagLib.PROVIDER_MAPPINGS.jquery = JQueryProvider
    }
}
于 2019-01-22T19:06:15.577 回答
-1

此链接非常有用，它显示了您可能需要采取的步骤。 https://grails.org/plugin/jquery

编辑：使用上面的网站，我可以这样做：

  1. 把它放在 config.groovy 中：grails.views.javascript.library = "jquery"
  2. 把这个 ins buildConfig.groovy 运行时 "org.grails.plugins:jquery:1.11.1"
  3. 注意（有人建议了另一个插件，它实际上破坏了我的）
  4. 我不需要做任何其他事情（我完全删除了 g:javascript 标签），它就可以工作了。
于 2018-08-31T15:07:52.627 回答