12

有人可以帮我理解命令文件的语法吗

IF "%INPUT_PATH%"=="" (
    echo Searching for latest test results in: %TEST_RESULTS%
    FOR /F "delims=" %%i in ('dir /O-D /B "%TEST_RESULTS%\*.trx"') DO (
        SET INPUT_PATH=%TEST_RESULTS%\%%~ni
        GOTO :DoneInputPath
) )

我知道它首先检查 INPUT_PATH 变量是否为空，如果为空则进入内部 for 循环，否则我会迷路

具体来说

  1. FOR /F "delims=" %%i in ('dir /O-D /B "%TEST_RESULTS%\*.trx"')
  2. SET INPUT_PATH=%TEST_RESULTS%\%%~ni
4

2 回答 2

16

您需要的大部分信息都可以在内置帮助中找到，但如果您是批处理编程的新手，这可能会让人望而生畏。例如，键入HELP FOR或FOR /?从命令提示符获取有关 FOR 命令的帮助。

解释：

FOR /F "delims=" %%i in ('dir /O-D /B "%TEST_RESULTS%\*.trx"') ...

DIR 命令列出路径中的所有*.TRX文件。%TEST_RESULTS%该/B选项提供简要格式（仅文件名）。该/O-D选项按上次修改日期降序（最新的优先）对文件进行排序。

FOR /F 命令具有三种模式，具体取决于 IN() 子句的格式。IN() 子句用单引号括起来的事实意味着 FOR /F 将内容视为命令，并处理命令的输出，一次一行。该"delims="选项表示不解析为标记（保留每一整行）。所以每一行都被迭代地加载到%%i变量中。该%%i变量仅存在于 FOR 命令的上下文中。

SET INPUT_PATH=%TEST_RESULTS%\%%~ni

我想你知道这个命令的大部分内容。唯一“不寻常”的方面是%%~ni语法。该语法仅将 的值扩展%%i为基本文件名，没有任何扩展名。

GOTO :DoneInputPath

GOTO 导致 FOR 循环在第一次迭代后中止。这意味着 INPUT_PATH 将设置为最近修改的*.trx文件的名称，因为它排在最前面。

如果 GOTO 不存在，那么最终结果将是最旧的*.trx文件。

于 2013-08-19T16:15:49.573 回答
0

试试这个，解释在评论中：

IF NOT DEFINED INPUT_PATH (
    echo Searching for latest test results in: %TEST_RESULTS%
    REM dir /OD means older files first and the youngest last, the last remains in INPUT_PATH; use "%%~nxi" for file name + file extension
    FOR /F "delims=" %%i in ('dir /OD /B "%TEST_RESULTS%\*.trx"') DO SET "INPUT_PATH=%TEST_RESULTS%\%%~ni"
)
于 2013-08-19T15:25:06.153 回答