4

如何更改下面的代码以防止您在屏幕截图中看到。

我正在使用以下代码运行宏

Dim conn As ADODB.Connection
Dim rec1 As ADODB.Recordset
Dim thisSql As String

Set conn = New ADODB.Connection

Dim sConn As String
  sConn = "Provider=SQLOLEDB;Trusted_Connection=Yes;Server=xyz;Database=xyz;UID=xyz;PWD=xyz"
conn.Open sConn

' this is creating multiple connections.
Set rec1 = New ADODB.Recordset
rec1.Open thisSql, conn

它运行一个 SQL Server 查询（大约 20 行长，包含 4 个连接）。一切都很好，除了在运行几次后我的数据库管理员说我的查询加载了数据库太多。

现在，我的查询可能会导致问题，也可能是 Excel 开始同时运行多个连接。这方面的一些证据是下面的屏幕截图以及数据库上的负载似乎随时间增加的事实。

如何在不不断创建新连接的情况下建立数据库连接？

有没有人在使用 Excel DB 宏时遇到过类似的问题？

多个连接

更新

虽然下面的答案非常有用（尤其是对于刚开始使用 VBA 的人），但似乎我的查询占用负载的主要原因是多个连接的组合并且忽略了我的代码中的一行：

    With Sheets("FVols").QueryTables.Add(Connection:=rec1, Destination:=Sheets("FVols").Range("A1"))
    .name = "data"
    .FieldNames = True
    .Refresh BackgroundQuery:=True <<<<<<<<<<<<<<<<<<<<<<<-----

End With
4

2 回答 2

8

您只需要打开一次连接。这实际上意味着您可以在该一个活动连接上执行多个查询。您必须关闭连接并释放引用（特别是使用 ADODB）以避免遇到冲突和其他与连接相关的问题。

如果您知道要执行的查询，您可以创建一个数组（或集合）并将查询添加到队列中。

虽然您已经有一个开放的连接可以使用，但您可以继续执行查询。

扫描代码，你的和我的没有太大区别，所以你应该能够看到发生了什么以及在哪里。如果有任何不清楚的地方，请在评论中提问

   Sub DbConnection()

    Dim cn As ADODB.Connection
    Set cn = New ADODB.Connection
    Dim rs As ADODB.Recordset

    Dim strConn As String
    strConn = "Driver={SQL Server};Server=; Database=; UID=; PWD="

    cn.Open strConn

    Dim queryArr, i
    queryArr = Array("SELECT * FROM [MyTable]", "SELECT * FROM [MyOtherTable]")

    For i = LBound(queryArr) To UBound(queryArr)
        ExecuteQuery queryArr(i), cn, rs
    Next i

    cn.Close
    Set cn = Nothing
End Sub

Private Sub ExecuteQuery(query As Variant, ByRef cn As ADODB.Connection, ByRef rs As ADODB.Recordset)
    Set rs = New ADODB.Recordset
    With rs
        .ActiveConnection = cn
        .Open CStr(query)
        Sheets(1).Range("A1").CopyFromRecordset rs
        .Close
    End With
    Set rs = Nothing
End Sub

现在，您只需要执行DBConnection()一次，您在数组中列出的所有查询都将被执行。

或者，如果您的查询是在运行时创建的，您可以将其DbConnection()作为参数传递给 。

Sub DbConnection(queryQueue As Collection)

    Dim cn As ADODB.Connection
    Set cn = New ADODB.Connection
    Dim rs As ADODB.Recordset


    Dim strConn As String
    strConn = "Driver={SQL Server};Server=HELIUM\PRI; Database=sourcedata; UID=tabula; PWD=Tabula123!"

    cn.Open strConn

    For i = 1 To queryQueue.Count
        ExecuteQuery queryQueue.Item(i), cn, rs
    Next i

    cn.Close
    Set cn = Nothing
End Sub

Private Sub ExecuteQuery(query As Variant, ByRef cn As ADODB.Connection, ByRef rs As ADODB.Recordset)
    Set rs = New ADODB.Recordset
    With rs
        .ActiveConnection = cn
        .Open CStr(query)
        Sheets(1).Range("A1").CopyFromRecordset rs
        .Close
    End With
    Set rs = Nothing
End Sub

更新：

您可以将连接声明为全局变量。现在，您可以随意运行DBConnection()多次，并且不会每次都创建新连接。相反，您将使用全局连接对象。

Option Explicit

Public cn As ADODB.Connection

Sub DbConnection()

    Set cn = New ADODB.Connection
    Dim rs As ADODB.Recordset

    Dim strConn As String
    strConn = "Driver={SQL Server};Server=; Database=; UID=; PWD="

    cn.Open strConn

    Set rs = New ADODB.Recordset
    With rs
        .ActiveConnection = cn
        .Open "SELECT * FROM [MyTable]"
        Sheets(1).Range("A1").CopyFromRecordset rs
        .Close
    End With
    Set rs = Nothing

    cn.Close
    Set cn = Nothing
End Sub
于 2013-08-19T12:57:13.433 回答
0

完成后是否释放连接变量？IE

Set rec1 = Nothing

如果没有，连接将不会完全关闭。

于 2013-08-19T12:50:05.887 回答