如何使用 dir 命令从最大到最小显示文件夹的子目录？
我试过使用dir /O:-S命令，虽然它对文件进行了很好的排序，但它似乎没有对子目录进行排序。
理想情况下，命令应该能够下几个级别；其中一些子文件夹有自己的文件夹。例如：
D:/
|-- Folder 1
|-- Subfolder 1
+-- Subfolder 2
|--Another folder
+-- Folder 2
假设文件夹 1（包括其子文件夹中的所有文件）的总大小为 10GB，文件夹 2 的总大小为 15GB，我将如何输出按总内容大小排序的顺序？
IE
94932485 Folder 2
6453445 Folder 1
提前致谢！
如果您追求的是支持高达 999 TB 的单行解决方案：
cmd /v /c "set zeropad=000,000,000,000,000,&for /f "delims=" %a in ('dir /ad /b') do @set bytes=!zeropad!000&(for /f "tokens=3" %b in ('dir /s "%a" 2^>NUL ^| find "File(s)"') do @set bytes=%b)& @for /f "tokens=1* delims=," %c in ('echo !bytes!') do @(set bytes=%c&@set bytes=000!bytes!&@set bytes=!bytes:~-3!& @set bytes=!zeropad!!bytes!&if "%d" NEQ "" set bytes=!bytes!,%d) & @echo !bytes:~-23! %a" | sort /R
如果您想要文件和目录，还有一个额外的单行解决方案
cmd /v /c "set zeropad=000,000,000,000,000,&for /f "tokens=4* delims= " %a in ('dir ^| find "/" ^| findstr /E /V /R "DIR^>[ ][ ]*\.\.$ DIR^>[ ][ ]*\.$"') do @set bytes=!zeropad!000&(if "%a" EQU "^<DIR^>" (for /f "tokens=3" %c in ('dir /s "%b" 2^>NUL ^| find "File(s)"') do @set bytes=%c)) & (if "%a" NEQ "^<DIR^>" (set bytes=%a)) & (for /f "tokens=1* delims=," %d in ('echo !bytes!') do @set bytes=%d&@set bytes=000!bytes!&@set bytes=!bytes:~-3!& @set bytes=!zeropad!!bytes!&if "%e" NEQ "" set bytes=!bytes!,%e)& echo !bytes:~-23! %b" | sort /R
这似乎适用于更改后的要求：更改c:\folder为您要查询的文件夹级别。
@echo off
pushd "c:\folder"
for /f "delims=" %%a in (' dir /ad /b ') do call :size "%%~fa"
sort /r < "%temp%\dirsize.tmp"
del "%temp%\dirsize.tmp"
popd
pause
goto :eof
:size
for /f "tokens=3" %%b in ('dir /s "%~1" 2^>nul ^|find " File(s) "') do set "n=%%b"
set dirsize=%n%
REM set dirsize=%dirsize:,=%
set dirsize= %dirsize%
set dirsize=%dirsize:~-18%
>>"%temp%\dirsize.tmp" echo %dirsize% "%~1"
已编辑：显示最大到最小的文件夹
看看这是不是你需要的。 d:\files是这里的目标树。
@echo off
for /f "delims=" %%a in (' dir "d:\files" /ad /b /s ') do call :size "%%a"
sort /r < "dirsize.tmp"
del "dirsize.tmp"
popd
pause
goto :eof
:size
for /f "tokens=3" %%b in ('dir "%~1" 2^>nul ^|find " File(s) "') do (
for /f "tokens=1-4 delims=," %%c in ("%%b") do (
set dirsize=%%c%%d%%e%%f
)
)
set dirsize= %dirsize%
set dirsize=%dirsize:~-20%
>>"dirsize.tmp" echo %dirsize% "%~1"
这是我从中得到的样本：
27982878 "d:\images\+ Funny and Odd pictures"
22595308 "d:\images\+ Mostly Cats\20120917"
16723196 "d:\images\+ Mostly Cats\20130215"
10212204 "d:\images\+ Mostly Cats\20121104"
9177080 "d:\images\+ Mostly Cats\20130506"
8992465 "d:\images\+ Mostly Cats\20130814"
8488502 "d:\images\Misc\Good Ideas"
6985671 "d:\images\Misc\50 Life Hacks"
5515548 "d:\images\Misc\Photos That Will Make Your Stomach Drop"
2541431 "d:\images\Misc\Sci Fi"
2113294 "d:\images\+ Mostly Cats\20130524"
384100 "d:\images\Astronomy pics\3D"
0 "d:\images\Misc"
0 "d:\images\Astronomy pics"
0 "d:\images\+ Mostly Cats"
这是一个很老的问题，但我不知道为什么我所有的朋友都回答说没有这样的命令。这是命令：
目录 /o:s
我看到评论说它不适用于文件夹，出于同样的原因，我正在编辑我的答案。该命令也支持文件夹。
d:\Moody>dir /o:s
Volume in drive D is Data
Volume Serial Number is CE51-A3E6
Directory of d:\Moody
28-Jun-2016 11:22 AM <DIR> .
28-Jun-2016 11:22 AM <DIR> ..
01-Jun-2016 05:37 PM <DIR> binding
05-May-2016 06:29 PM <DIR> WMQ 8 JARS
27-Jun-2016 06:51 PM <DIR> codebase
27-Jun-2016 05:34 PM <DIR> docs
21-Jun-2016 11:12 AM <DIR> WMQ 7.5 JARS
18-May-2016 12:56 PM <DIR> TestValidation
17-Jun-2016 02:35 PM <DIR> java-doc-jms
17-May-2016 04:20 PM <DIR> sample-log
20-May-2016 03:28 PM <DIR> jms
26-May-2016 12:01 PM <DIR> repository
24-Jun-2016 12:09 PM <DIR> New folder
05-Apr-2016 04:55 PM <DIR> zips
04-May-2016 12:20 PM <DIR> PocJms
20-Apr-2016 12:58 PM 901 TestValidation.zip
22-Jun-2016 04:22 PM 7,739 team.xlsx
13-May-2016 09:19 PM 8,700 sample-log.zip
04-Jun-2016 03:06 PM 43,410 Sequence diagrams.mdj
28-Jun-2016 11:22 AM 59,392 FW Binding file for DEV QM.msg
02-May-2016 08:04 PM 81,568 PocJms.zip
21-Mar-2013 01:33 PM 99,926 fscontext-4.2.jar--
22-Jun-2016 02:31 PM 236,631 java-doc-jms.zip
05-May-2016 05:19 PM 7,673,675 WMQ 7.5 JARS.zip
05-May-2016 05:19 PM 12,442,322 WMQ 8 JARS.zip
15 File(s) 21,028,409 bytes
19 Dir(s) 73,162,878,976 bytes free
除了显示大小的文件外，我的文件夹也被安排了。在检查装订的尺寸的时候；将近 18 KB；最后一个文件夹存储库将近 1 GB。所以它也适用于文件夹。
如果您不需要日期和其他信息，您可以使用：
dir /b /a-d /o:s