4

我在OPTIONAL使用 Fortran 95 的函数和子例程中的语句存在问题。目前我正在使用 Silverfrost 的 Plato 和他们的 FTN95 编译器（在“发布 Win32”模式下）。在尝试在我正在编写的更复杂的程序中实现 OPTIONAL 语句之后，我创建了一个非常简单的程序来测试它。这是代码：

program TEST

implicit none
integer :: a=1, b=2

call Z(a,b)
call Z(a)
call Z(b)

end program TEST

subroutine Z(x,y)
implicit none
integer :: x
integer, optional :: y

if (present(y)) then
  write(*,*) x, y
  else
    write(*,*) x
endif

end subroutine Z

我预计屏幕上会显示以下结果：

1 2
1
2

好吧，代码可以编译，尽管我收到警告 (673) “SUBROUTINE Z has been called with too little arguments”。执行后，我进入我的屏幕：

1 2

然后是“访问冲突”错误消息。有人能理解这里有什么问题吗？

非常感谢！吉尔伯托

4

2 回答 2

9

尝试将子例程放入模块中，如下所示：

module testoptional
contains
    subroutine Z(x,y)
    implicit none
    integer :: x
    integer, optional :: y

    if (present(y)) then
      write(*,*) x, y
      else
        write(*,*) x
    endif

    end subroutine Z
end module testoptional

program TEST
    use testoptional
    implicit none
    integer :: a=1, b=2

    call Z(a,b)
    call Z(a)
    call Z(b)

end program TEST

然后使用 gfortran 和 ifort 编译和运行会给出预期的结果。

问题在于主程序如何知道（或猜测）Z(x,y). 在您提供的代码中，虽然主程序和子程序在同一个文件中，但没有明确告诉主程序的接口 - 调用序列，包括参数计数、类型等 - Z。第一个调用是 to Z(a,b)，因此它推断出某处有一个子例程，它接受两个参数；然后它尝试使用一个参数调用它，但失败了。

将子程序放入模块中，然后使用该模块（您也可以contains用于包含的子程序，或使用interface块显式/手动为主程序提供接口）然后为主程序提供有关调用序列所需的信息 - 例如，有一个可选的参数 - 并且事情正常。

于 2013-08-18T15:18:33.277 回答
3

带有可选参数的过程必须有明确的接口，所以试着给Z. （例如，只需使用短模块中的子程序。）

我手头没有这个特定的编译器，但是在像这样的情况下使用 Cray 编译器时出现错误。

于 2013-08-18T15:18:47.390 回答