2

我从另一个线程得到的答案复制了这个。我正在尝试将 ~300 个 .xls 和 .xlsx 文件转换为制表符分隔。它们都在同一个文件夹中。如果有人知道更好的方法，请告诉我。

property type_list : {"XLS6", "XLS7", "XLS8", "XLSX"}
property extension_list : {"xls", "xlsx"}


on open these_workbooks
repeat with k from 1 to the count of these_workbooks
    set this_item to item k of these_workbooks
    set the item_info to info for this_item

    --this if statement tests to make sure the items you're converting are Excel spreadsheets and not folders or aliases
    if (folder of the item_info is false) and (alias of the item_info is false) and ((the file type of the item_info is in the type_list) or the name extension of the item_info is in the extension_list) then

        tell application "Finder" to open this_item

        tell application "Microsoft Excel"
            --this just tacks on ".txt" to your file name
            set workbookName to (name of active workbook & ".txt")
            --save the current open workbook as a tab-delimited text file
            tell active workbook to save workbook as filename workbookName file format text Mac file format
            close active workbook saving no
        end tell
    end if
end repeat
end open

on run
    display dialog "Drop Excel files onto this icon."
end run

所有这一切都是打开一个对话框，什么都不做。即使它是一个液滴，当我将文件拖到它时也没有任何反应。

4

1 回答 1

4

在 Applescript 中，run处理程序在脚本或应用程序正常运行时运行。同时，open VarName当一些文件或文件被拖放到应用程序的图标上并且文件被设置为变量时，处理程序就会运行VarName。您发布的脚本巧妙地将其放置display dialog在on run处理程序中，以帮助您理解这种用法​​。相反，将脚本保存为应用程序，然后将文件拖放到它上面。

编辑：

在终于拥有 Excel 2011 的 Mountain Lion 机器上进行了快速测试后（我没有意识到我有多么复杂）：

property type_list : {"XLS6", "XLS7", "XLS8", "XLSX"}
property extension_list : {"xls", "xlsx"}


on open these_workbooks
    repeat with k from 1 to the count of these_workbooks
        set this_item to item k of these_workbooks
        set the item_info to info for this_item

        --this if statement tests to make sure the items you're converting are Excel spreadsheets and not folders or aliases
        if (folder of the item_info is false) and (alias of the item_info is false) and ((the file type of the item_info is in the type_list) or the name extension of the item_info is in the extension_list) then

            tell application "Finder" to open this_item

            tell application "Microsoft Excel"
                --this just tacks on ".txt" to your file name
                set workbookName to (path to desktop as string) & "After:" & (name of active workbook & ".txt")
                display dialog workbookName
                --save the current open workbook as a tab-delimited text file
                tell active workbook to save workbook as filename workbookName file format text Mac file format
                close active workbook saving no
            end tell
        end if
    end repeat
end open

on run
    display dialog "Drop Excel files onto this icon."
end run
于 2013-08-15T19:00:47.913 回答