1

我使用的是 xslt 1.0，我需要两个变量的联合，这意味着我必须使用节点集函数。

下面的测试用例创建了单个节点与包含该节点的集合的联合。由于 A 包含 B，联合操作应该返回 B。但是我得到了一个带有重复 A 的新集合。

如果我直接使用 xpath，则 union 会按预期运行。如果我使用变量和节点集函数，我会遇到意想不到的情况。我的场景要求我使用节点集。我已经尽可能地简化了测试用例。

这是xml内容：

<?xml version="1.0" encoding="utf-8" ?>
<root>
  <event>
    <id>3</id>
    <eventType>TYPE1</eventType>
  </event>
  <event>
    <id>2</id>
    <eventType>TYPE2</eventType>
    <parent>3</parent>
  </event>
  <event>
    <id>1</id>
    <eventType>TYPE2</eventType>
    <parent>3</parent>
  </event>
</root>

这是xslt：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" 
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:msxsl="urn:schemas-microsoft-com:xslt" 
                xmlns:ext="http://exslt.org/common"
                exclude-result-prefixes="msxsl"
>
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="/">      

      <xsl:variable name="t2-events">
        <xsl:copy-of 
          select="root/event
                  [eventType = 'TYPE2' and parent = '3']"/>
      </xsl:variable>

      <xsl:variable name="specific-t2">
          <xsl:copy-of 
            select="root/event
                    [eventType = 'TYPE2' and id = '2']"/>        
      </xsl:variable>

      <DEBUG>        

          <results>            
            <xsl:variable name="dummy" 
                          select="root/event
                                  [eventType = 'TYPE2'] 
                                  | 
                                  root/event[id = '2']"/>
            <xsl:variable name="dummy2" 
                          select="ext:node-set($t2-events)
                                | ext:node-set($specific-t2) "/>

            <xsl:comment>Works as expected</xsl:comment>
            <dummy>              
                <xsl:copy-of select="$dummy"/>
            </dummy>
            <dummy2>
              <xsl:comment>There are 3 elements here, where we should have 2</xsl:comment>
                <xsl:copy-of select="$dummy2"/>
             </dummy2>            
          </results>

      </DEBUG>            
    </xsl:template>  
</xsl:stylesheet>

如何在两个 node-set() 调用上应用联合？

4

1 回答 1

0

我不认为 node-set() 是这里的罪魁祸首。

您已经定义了变量t2-events并specific-t2使用了 xsl:copy-of。因此，您的变量应该（并且确实）包含由 xsl:copy-of 上的选择表达式选择的节点的新副本（新元素节点）。因此，event这两个变量中的任何event元素都与输入中的任何元素都不相同，并且类似地，在两个变量中生成的事件 2 的两个副本是两个副本，而不是对单个副本的两个引用。

请注意，当我们在调试代码中添加更多变量时（顺便说一句，很好地减少了示例！），无论我们是否使用 node-set()，联合都会按我们的预期发生。（至少在 xsltproc 中。）

在您最初的两个变量之后，我又添加了两个：

<xsl:variable name="T2-EVENTS" 
              select="root/event
                      [eventType = 'TYPE2' and parent = '3']"/>
<xsl:variable name="SPECIFIC-T2" 
              select="root/event
                      [eventType = 'TYPE2' and id = '2']"/>

然后在您的 DEBUG 元素中，我添加了：

<xsl:variable name="dummy3" 
              select="$T2-EVENTS | $SPECIFIC-T2 "/>
<xsl:variable name="dummy4" 
              select="ext:node-set($T2-EVENTS) 
                    | ext:node-set($SPECIFIC-T2) "/>

和

<dummy3>
  <xsl:comment>How many here?</xsl:comment>
  <xsl:copy-of select="$dummy3"/>
</dummy3>
<dummy4>
  <xsl:comment>How many here?</xsl:comment>
  <xsl:copy-of select="$dummy4"/>
</dummy4>

当我使用 xsltproc 运行生成的样式表时，我得到两个元素 indummy3和两个 in dummy4; 对 node-set() 的调用没有任何区别。

（也就是说，我在 EXSLT 站点上的 node-set() 函数的描述中看不到任何关于 node-set() 保留节点身份或不保留它的内容。所以我对依赖它持谨慎态度方法。）

于 2013-08-15T16:13:30.607 回答