2

如果我使用GetIP('server-name')或GetIP('google.com')在我的 Delphi 2006 中，我有这个功能可以检索 IP 地址。

但现在我正在尝试它Delphi-XE3不起作用。有任何想法吗？

function GetIP(const HostName: string): string;
var
  WSAData: TWSAData;
  R: PHostEnt;
  A: TInAddr;
begin
  Result := IPNULL; // '0.0.0.0'
  WSAStartup($101, WSAData);
  R := Winsock.GetHostByName(PAnsiChar(HostName));
  if Assigned(R) then
  begin
    A := PInAddr(r^.h_Addr_List^)^;
    Result := string(WinSock.inet_ntoa(A));
  end;
end;

似乎R没有被分配，因为结果总是'0.0.0.0'

4

2 回答 2

11

这两个版本的 Delphi 之间的最大区别在于，现代 Delphi 原生使用宽 UTF-16 编码字符串，而旧版本使用 ANSI 编码字符串。

许多 API 函数同时具有宽版本和 ANSI 版本。但是您在 Winsock 中调用的函数始终只有 8 位。

您可以通过显式使用 8 位文本编码使您的代码像以前一样工作。

function GetIP(const HostName: string): string; 
var 
  WSAData: TWSAData;
  R: PHostEnt; 
  A: TInAddr; 
begin 
  Result := IPNULL; // '0.0.0.0' 
  WSAStartup($101, WSAData); 
  R := Winsock.GetHostByName(PAnsiChar(AnsiString(HostName))); 
  if Assigned(R) then 
  begin 
    A := PInAddr(r^.h_Addr_List^)^; 
    Result := WinSock.inet_ntoa(A); 
  end; 
end;

现在，细心的读者会说：

如果主机名包含非 ASCII 字符怎么办？受到这些相当微弱的固定长度 8 位编码的限制不是很可惜吗？

好吧，如今将主机名转换为地址的推荐函数是 Unicode 函数GetAddrInfoW。

于 2013-08-15T20:30:05.370 回答
1

这是我使用 winsocks2 和 unicode 支持解析 XE3-XE7 上的 IP 地址的自包含示例。

它不是高性能的，因为套接字支持在每次调用时都会被初始化和取消初始化，但重构是微不足道的。

另外，请注意，它不是为了便于维护而特意优化的。

uses
  Winapi.Winsock2;

type
  PAddrInfo = ^TAddrInfo;
  TAddrInfo = packed record
    ai_flags: integer;
    ai_family: integer;
    ai_socktype: integer;
    ai_protocol: integer;
    ai_addrlen: NativeInt;
    ai_canonname: PCHAR;
    ai_addr: PSOCKADDR;
    ai_next: PAddrInfo;
  end;

function GetAddrInfo(const nodeName: PCHAR; const serviceName : PChar; const hints: PAddrInfo; var result: PAddrInfo): integer; stdcall; external 'ws2_32.dll' name 'GetAddrInfoW';
procedure FreeAddrInfo(const addrInfo: PAddrInfo); stdcall; external 'ws2_32.dll' name 'FreeAddrInfoW';

function ResolveIpAddress(const hostName: string; const ipv6: boolean): string;
const
  BUFFER_SIZE = 32768;
var
  data: TWSAData;
  error: integer;
  requestError: integer;
  r: PAddrInfo;
  s: string;
  hints: TAddrInfo;
  buffer: TArray<byte>;
  length: DWORD;
begin
  error:= WSAStartup(MAKEWORD(2, 2), data);
  try
    if (error = 0)  then
    begin
      r:= nil;
      try
        ZeroMemory(@hints, sizeof(TAddrInfo));
        if (ipv6) then
          hints.ai_family:= AF_INET6
        else
          hints.ai_family:= AF_INET;

        requestError:= GetAddrInfo(PCHAR(hostName), nil, @hints, r);
        if (requestError = 0) then
        begin
          length:= BUFFER_SIZE;
          SetLength(buffer, BUFFER_SIZE);
          if (WSAAddressToString(r.ai_addr^, r.ai_addrlen, nil, @buffer[0], length) = 0) then
          begin
            setLength(buffer, length * 2);
            s:= TUnicodeEncoding.Unicode.GetString(@buffer[0]);
            exit(s);
          end
          else
            exit('0.0.0.0');
        end
        else
          exit('0.0.0.0');

      finally
        FreeAddrInfo(r);
      end;
    end
  finally
    if (error = 0) then
      WSACleanup();
  end;
end;
于 2018-03-06T16:19:37.233 回答