1

我是 Haskell 的新手。我正在玩 QuickCheck 测试，尝试测试一个简单的功能calculateStrengthSingle（请参阅下面的 testee 的来源）

# Fighter.hs
module Fighter
( Quantity(Quantity)
, Fighter(TeamPlayer, LoneWolf, Polymorph)
, Strength(Strength)
, calculateStrengthSingle)
where

import System.Random

data Strength = Strength Double

instance Eq Strength where
    Strength s1 == Strength s2 =
        s1 == s2

instance Ord Strength where
    Strength s1 < Strength s2 =
        s1 < s2

data Quantity = Quantity Int deriving (Show)

instance Random Quantity where
    randomR (Quantity lo, Quantity hi) g =
        let rand = randomR (lo, hi) g
            (r, g1) = rand
        in (Quantity r, g1)
    random g =
        let rand = random g
            (r, g1) = rand
        in (Quantity r, g1)

data Fighter = TeamPlayer
             | LoneWolf
             | Polymorph
    deriving (Show)


calculateStrengthSingle :: Quantity -> Fighter -> Strength
calculateStrengthSingle (Quantity number) TeamPlayer =
    Strength(log (fromIntegral number))
calculateStrengthSingle _ _ = Strength 0.0

测试看起来像这样

# TestFighter.hs
import qualified Test.QuickCheck as QuickCheck
import Fighter

prop_StrengthPositive quantity fighter =
    Fighter.calculateStrengthSingle quantity fighter >= Strength 0.0

instance QuickCheck.Arbitrary Fighter.Fighter where
    arbitrary = QuickCheck.oneof([return Fighter.TeamPlayer, return Fighter.LoneWolf, return Fighter.Polymorph])

instance QuickCheck.Arbitrary Fighter.Quantity where
    arbitrary = QuickCheck.choose(Fighter.Quantity 1, Fighter.Quantity 10)

main :: IO()
main = do
    QuickCheck.quickCheck prop_StrengthPositive

当我这样做时runhaskell TestFighter.hs，有输出(1 test)（数字在变化，有时它0是4）并且 CPU 100% 加载。一分钟左右什么都没有发生。当我中断程序时Ctrl+C，它会吐出类似的东西

^C*** Failed! Exception: 'user interrupt' (after 1 test):  
Quantity 2
TeamPlayer

问题：

  1. 我哪里搞砸了？
  2. 如何调试无限计算的情况，比如这个？
4

2 回答 2

7

您尚未正确定义Ord实例Strength。您需要定义<=而不是<.

仅<定义函数<=进入无限循环，因为它是根据定义的，compare并且compare是根据定义的<=。最小定义需要定义compare或<=。

Ord例如，这是固定代码

instance Ord Strength where
    Strength s1 <= Strength s2 =
        s1 <= s2
于 2013-08-12T21:04:49.893 回答
1

您可以尝试使用-o 1作为参数运行测试，这会导致一秒钟后超时。然后它可以显示导致程序挂起的输入。它并不能准确地告诉你问题出在哪里，但它是一个好的开始。

编辑：这就是我使用 cabal 测试框架的方式

test-Suite runTests
   hs-source-dirs:      src, test
   type:                exitcode-stdio-1.0
   main-is:             RunTests.hs
   other-modules:
                       <...>

  build-depends:       base >= 3 && < 5,
                       HUnit,
                       test-framework,
                       test-framework-th,
                       test-framework-hunit,
                       test-framework-quickcheck2,
                       QuickCheck,

为了在我的描述中完整，我使用以下方法构建：

cabal-dev install --enable-tests
于 2013-08-12T21:45:25.593 回答