1

我想比较从这个样本数据中分离出来的两个数字：

'gi|112807938|emb|CU075707.1|_Xenopus_tropicalis_finished_cDNA,_clone_TNeu129d01  C1:TCONS_00039972(XLOC_025068),_12.9045:32.0354,_Change:1.3118,_p:0.00025,_q:0.50752  C2:TCONS_00045925(XLOC_029835),_10.3694:43.8379,_Change:2.07985,_p:0.0004,_q:0.333824',
'gi|115528274|gb|BC124894.1|_Xenopus_laevis_islet-1,_mRNA_(cDNA_clone_MGC:154537_IMAGE:8320777),_complete_cds C1:TCONS_00080221(XLOC_049570),_17.9027:40.8136,_Change:1.18887,_p:0.00535,_q:0.998852  C2:TCONS_00092192(XLOC_059015),_17.8995:35.5534,_Change:0.990066,_p:0.0355,_q:0.998513',
'gi|118404233|ref|NM_001078963.1|_Xenopus_(Silurana)_tropicalis_pancreatic_lipase-related_protein_2_(pnliprp2),_mRNA  C1:TCONS_00031955(XLOC_019851),_0.944706:5.88717,_Change:2.63964,_p:0.01915,_q:0.998852 C2:TCONS_00036655(XLOC_023660),_2.31819:11.556,_Change:2.31757,_p:0.0358,_q:0.998513',

使用以下正则表达式： 

#!/usr/bin/perl -w
use strict; 
use File::Slurp;
use Data::Dumper;
$Data::Dumper::Sortkeys = 1;

my (@log_change, @largest_change);
        foreach (@intersect) {
            chomp;
            my @condition1_match = ($_ =~ /C1:.*?Change:(-?\d+\.\d+)|C1:.*?Change:(-?inf)/); # Sometimes the value is 'inf' or '-inf'. This allows either a numerical or inf value to be captured.
            my @condition2_match = ($_ =~ /C2:.*?Change:(-?\d+\.\d+)|C2:.*?Change:(-?inf)/);
            push @log_change, "@condition1_match\t@condition2_match";   
        }

    print Dumper (\@log_change);

这给出了这个输出：

          '1.3118   2.07985 ',
          '1.18887  0.990066 ',
          '2.63964  2.31757 ',

理想情况下，在同一个循环中，我现在想对保存的值进行比较，@condition1_match以便@condition2_match将较大的值推送到新数组中，除非与非数字“inf”进行比较，在这种情况下推送数值。

像这样的东西：

my (@log_change, @largest_change);
        foreach (@intersect) {
            chomp;
            my @condition1_match = ($_ =~ /C1:.*?Change:(-?\d+\.\d+)|C1:.*?Change:(-?inf)/);
            my @condition2_match = ($_ =~ /C2:.*?Change:(-?\d+\.\d+)|C2:.*?Change:(-?inf)/);
            push @log_change, "@condition1_match\t@condition2_match";
                unless ($_ =~ /Change:-?inf/) {
                    if (@condition1_match > @condition2_match) {
                        push @largest_change, @condition1_match;
                    }
                    else {
                        push @largest_change, @condition2_match;
                    }

                }

        }

    print Dumper (\@largest_change);

这使：

          '2.07985',
          undef,
          '0.990066',
          undef,
          '2.31757',
          undef,

以及很多这样的错误信息：

Use of uninitialized value $condition2_match[1] in join or string at intersect.11.8.pl line 114.

我不确定错误消息的确切含义，以及为什么我在我的@largest_change

4

1 回答 1

2

当您编写代码时，@condition_match1将@condition_match2使用 2 个元素创建 - 对应于正则表达式中的 2 个捕获组 - 每次匹配时。但是这些元素之一总是必然是undef，导致uninitialized ...警告。

|在这种情况下，您可以通过将捕获组放入其中来修复此程序：

my ($condition1_match) = ($_ =~ /C1:.*?Change:(-?\d+\.\d+|-?inf)/);
my ($condition2_match) = ($_ =~ /C2:.*?Change:(-?\d+\.\d+|-?inf)/);

这样就只有一个捕获组，并且匹配操作会生成一个包含单个已定义元素的列表。

此外，比较

if (@condition1_match > @condition2_match) {

可能没有做你认为它正在做的事情。在 Perl 中，两个数组之间的数值比较是数组长度的比较。您显然要做的是比较每个数组中定义的值，因此您需要做一些更麻烦的事情，例如：

my $condition1_match = $condition1_match[0] // $condition1_match[1];
my $condition2_match = $condition2_match[0] // $condition2_match[1];
if ($condition1_match > $condition2_match) {
    push @largest_change, $condition1_match;
} else {
    push @largest_change, $condition2_match;
}
于 2013-08-12T17:49:42.030 回答