2

我正在尝试从另一个模板“xsl:template match="KTheme"' 模板向 'xsl:element name="div"' 元素添加一个属性，但是我收到一个 XSLT 错误，没有关于什么的错误信息失败或失败的原因。有没有办法做到这一点？

基本上，当从 'xsl:template name="DisplayFrame"' 模板执行 'xsl:apply-templates/' 行时，它会匹配 'KTheme' 元素并应将“style”属性添加到“div”元素：

<xsl:template match="Frame">
    <xsl:call-template name="DisplayFrame">
        <xsl:with-param name="FrameId" select="'frameHeader'" /> 
    </xsl:call-template>
</xsl:template>

<xsl:template name="DisplayFrame">
    <xsl:param name="FrameId" />

    <xsl:element name="div">
        <xsl:attribute name="id">
            <xsl:value-of select="$FrameId" />
        </xsl:attribute>
        <xsl:apply-templates/>
    </xsl:element>
</xsl:template>

下面的模板是将“style”属性添加到“div”元素的地方。这个模板给了我一个错误，因为一旦我删除了“xsl:attribute”元素，XSLT 就会成功编译。

<xsl:template match="KTheme">
    <xsl:attribute name="style">
        <xsl:value-of select="." />
    </xsl:attribute>
</xsl:template>

一个示例 XML 文件：

<Document>
    <Frame>
        <KTheme>background-color: red;</KTheme>
    </Frame>
</Document>

实际上，“KTheme”元素是动态创建的，因此必须按照我的理论建议，通过添加来自另一个模板的属性来完成，但显然它是不正确的。这可以做到吗？感谢您的时间。

4

2 回答 2

2

这里发生的情况是，在 之前和之后有空白文本节点KTheme，而在它之前的那个节点被添加到属性之前的输出中。在向父元素添加非属性节点后尝试向父元素添加属性是错误的。

为了玩得更安全，我建议直接定位KTheme元素，然后处理其他任何内容。这应该可以解决您的问题：

  <xsl:template name="DisplayFrame">
    <xsl:param name="FrameId" />

    <div id="{$FrameId}">
      <xsl:apply-templates select="KTheme" />
      <xsl:apply-templates select="node()[not(self::KTheme)]" />
    </div>
  </xsl:template>

我还使用 id 属性的属性值模板使它更简洁一些，但这不是必需的。

作为旁注，添加<xsl:strip-space elements="*"/>到 XSLT 的顶部以去除空白文本节点也可以防止此错误，但我仍然认为在处理其他任何内容之前主动定位可能产生属性的任何内容更为明智。在错误的时间意外添加属性会导致整个 XSLT 失败。

于 2013-08-10T05:15:32.340 回答
1

...或使用 AVT 用于@style...

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
<xsl:output method="html" doctype-system="about:legacy-compat" encoding="UTF-8" indent="yes" />
<xsl:strip-space elements="*" />

<xsl:template match="@*|node()" name="ident">
 <xsl:copy>
   <xsl:apply-templates select="@*|node()" />
 </xsl:copy> 
</xsl:template>  

<xsl:template match="Frame">
  <div id="frameHeader" style="{KTheme}">
   <xsl:apply-templates select="node()[not(self::KTheme)]" />
  </div>  
</xsl:template>  

</xsl:stylesheet>
于 2013-08-10T10:19:11.070 回答