4

我不知道该怎么做sb-ext:muffle-conditions。我想做这样的事情：

(declaim #+sbcl(sb-ext:muffle-conditions sb-kernel:redefinition-warning))

当然，除了我想消除“未定义变量”警告而不是重新定义。

如果有人知道这是什么参数或有文档/各种选项的链接sb-ext:muffle-conditions，请分享:)谢谢

4

1 回答 1

4

我不确定您是否能够专门消除这种类型的警告，至少通过类名。通过跟踪warn，我们可以了解 SBCL 在做什么。例如，看看在重新定义的情况下会发生什么：

* (trace warn)

(WARN)
* (defun foo () nil)

FOO
* (defun foo () nil)
  0: (WARN SB-KERNEL:REDEFINITION-WITH-DEFUN :NAME FOO :NEW-FUNCTION
           #<FUNCTION FOO {10041FA989}> :NEW-LOCATION
           #S(SB-C:DEFINITION-SOURCE-LOCATION
              :NAMESTRING NIL
              :TOPLEVEL-FORM-NUMBER NIL
              :PLIST NIL))
STYLE-WARNING: redefining COMMON-LISP-USER::FOO in DEFUN
  0: WARN returned NIL
FOO

warn使用类sb-kernel:redefinition-with-defun和参数作为类指示符调用，因此发出的警告具有某种特定的类类型。能够基于特定的类类型进行消音使消音更容易。

现在，看看在未定义变量的情况下会发生什么：

* (defun foo2 () x)
  0: (WARN "undefined ~(~A~): ~S" :VARIABLE X)

; in: DEFUN FOO2
;     (BLOCK FOO2 X)
; 
; caught WARNING:
;   undefined variable: X
  0: WARN returned NIL
; 
; compilation unit finished
;   Undefined variable:
;     X
;   caught 1 WARNING condition
FOO2

warn正在使用格式字符串和一些参数调用，因此发出的警告只是一个simple-warning. 现在，你仍然可以做一些事情来消音它，但它有点复杂。

根据 SBCL 手册部分，3.1.1 Controlling Verbosity，sb-ext:muffle-conditions只是使用muffle-warning重新启动。因为未定义变量 warning 只是 a simple-warning，而且我们可能不想屏蔽所有 simple-warnings，所以我们需要有点偷偷摸摸地使用 handler bind 指定的处理程序检查条件。由于我们已经看到了warn被调用的参数，我们可以非常具体地了解我们捕获的内容。我们可以通过以下方式识别这些警告undefined-variable-warning-p：

(defun undefined-variable-warning-p (w)
  (let ((control (simple-condition-format-control w))
        (arguments (simple-condition-format-arguments w)))
    (and (= 2 (length arguments))
         (eq :variable (first arguments))
         (string= control "undefined ~(~A~): ~S"))))

现在我们可以将编译表单包装在适当的handler-bind. 例如，让我们看看(compile nil (lambda () x))有无处理程序：

CL-USER> (compile nil '(lambda () x))
; 
; caught WARNING:
;   undefined variable: X
; 
; compilation unit finished
;   Undefined variable:
;     X
;   caught 1 WARNING condition
#<FUNCTION (LAMBDA ()) {1003AA4F89}>
T
T

CL-USER> (handler-bind
             ((simple-warning 
               #'(lambda (w) 
                   (when (undefined-variable-warning-p w)
                     (invoke-restart 'muffle-warning)))))
           (compile nil '(lambda () x)))
#<FUNCTION (LAMBDA ()) {1003B737E9}>
NIL
NIL

我们已经成功地编译了函数并将未定义的变量警告静音。但是，请注意，您不能简单地将defuns 包装在其中。例如，

CL-USER> (handler-bind
             ((simple-warning 
               #'(lambda (w) 
                   (when (undefined-variable-warning-p w)
                     (invoke-restart 'muffle-warning)))))
           (defun some-function () x))

; in: DEFUN SOME-FUNCTION
;     (DEFUN SOME-FUNCTION () X)
; --> PROGN EVAL-WHEN SB-IMPL::%DEFUN SB-INT:NAMED-LAMBDA FUNCTION 
; ==>
;   (BLOCK SOME-FUNCTION X)
; 
; caught WARNING:
;   undefined variable: X
; 
; compilation unit finished
;   Undefined variable:
;     X
;   caught 1 WARNING condition
SOME-FUNCTION

但是，如果您也eval一样defun（但我并不是说您应该这样做），则警告会被掩盖：

CL-USER> (handler-bind
             ((simple-warning 
               #'(lambda (w) 
                   (when (undefined-variable-warning-p w)
                     (invoke-restart 'muffle-warning)))))
           (eval '(defun some-other-function () x)))
SOME-OTHER-FUNCTION

我不确定这是为什么，但我希望有人能够在评论中详细说明。我怀疑这来自 SBCL 编译 REPL 上的表单，这意味着defun在整个表单运行之前编译的主体，因此编译是在处理程序到位之前发生的。

于 2013-08-10T15:33:34.307 回答