4

如何以尽可能类型安全的方式将 Haskell 函数降低为嵌入式语言。特别是，假设我有一个像

data Type t where
  Num  :: Type Int
  Bool :: Type Bool

data Ty = TNum | TBool deriving Eq

data Tagged t = Tagged (Type t) t deriving Typeable
data Dynamic  = forall t . Typeable t => Dynamic (Tagged t) deriving Typeable

forget :: Typeable t => Tagged t -> Dynamic
forget = Dynamic

remember :: Typeable b => Dynamic -> Maybe b
remember (Dynamic c) = cast c

我想将一个函数转换(isSucc :: Int -> Int -> Bool)为它的动态形式和一些类型信息的产品，像这样

data SplitFun = SF { dynamic    :: [Dynamic] -> Dynamic 
                   , inputTypes :: [Ty] 
                   , outputType :: Ty
                   }

这样对于某些apply功能

(\(a:b:_) -> isSucc a b) == apply (makeDynamicFn isSucc)

如果动态类型实际上不匹配，可能会引发一些可能的异常。或者，更明确地说，我想找到makeDynamicFn :: FunType -> SplitFun. 显然，这不是一个合适的 Haskell 类型，而且不太可能有一种方法可以从isSucc自身中提取类型，所以它可能更像是

anInt . anInt . retBool $ isSucc :: SplitFun

whereanInt和retBoolhave printf-style 类型。

这样的事情可能吗？有没有办法模拟它？

4

1 回答 1

2

为了实现 type 的函数FunType -> SplitFun，我们将使用标准类型类机制来解构函数类型。

现在，直接实现这个功能变得相当困难。要从递归案例中获取inputTypes和outputType退出，您必须应用您的函数；但是您只能在dynamic字段内应用该函数，这使您无法填充其他字段。相反，我们将任务分成两部分：一个函数将向我们提供Ty信息，另一个将构造[Dynamic] -> Dynamic函数。

data Proxy a = Proxy

class Split r where
    dynFun :: r -> [Dynamic] -> Dynamic
    tyInfo :: Proxy r -> ([Ty], Ty)

    split :: r -> SplitFun
    split f = let (i, o) = tyInfo (Proxy :: Proxy r)
              in  SF (dynFun f) i o

现在，tyInfo实际上不需要函数，我们Proxy只是用来传递类型信息而不需要undefined到处使用。请注意，我们需要ScopedTypeVariables能够r从实例声明中引用类型变量。巧妙地使用asTypeOf可能也有效。

我们有两个基本情况：Bool和Int：

instance Split Int where
    dynFun i _ = forget (Tagged Num i)
    tyInfo _ = ([], TNum)

instance Split Bool where
    dynFun b _ = forget (Tagged Bool b)
    tyInfo _ = ([], TBool)

没有输入类型，因为我们已经有了一个值，所以我们不需要请求更多的Dynamic值，我们只需返回Dynamic那个特定的值。

接下来，我们有两个递归案例：Bool -> r和Int -> r

instance (Split r) => Split (Int -> r) where
    dynFun f (d:ds) = case remember d :: Maybe (Tagged Int) of
        Just (Tagged _ i) -> dynFun (f i) ds
        Nothing           -> error "dynFun: wrong dynamic type"
    dynFun f []     = error "dynFun: not enough arguments"

    tyInfo _ = case tyInfo (Proxy :: Proxy r) of
         (i, o) -> (TNum:i, o)

instance (Split r) => Split (Bool -> r) where
    dynFun f (d:ds) = case remember d :: Maybe (Tagged Bool) of
        Just (Tagged _ b) -> dynFun (f b) ds
        Nothing           -> error "dynFun: wrong dynamic type"
    dynFun f []     = error "dynFun: not enough arguments"

    tyInfo _ = case tyInfo (Proxy :: Proxy r) of
         (i, o) -> (TBool:i, o)

这两个需要FlexibleInstances。dynFun检查第一个Dynamic参数，如果没问题，我们可以安全地将函数f应用于它并从那里继续。我们也可以做dynFun :: r -> [Dynamic] -> Maybe Dynamic，但这是相当微不足道的改变。

现在，有一些重复。我们可以引入另一个类，例如：

class Concrete r where
    getTy   :: Proxy r -> Ty
    getType :: Proxy r -> Type r

然后写：

instance (Typeable r, Concrete r) => Split r where
    dynFun r _ = forget (Tagged (getType (Proxy :: Proxy r)) r)
    tyInfo _ = ([], getTy (Proxy :: Proxy r))

instance (Typeable r, Concrete r, Split s) => Split (r -> s) where
    dynFun f (d:ds) = case remember d :: Maybe (Tagged r) of
        Just (Tagged _ v) -> dynFun (f v) ds
        -- ...

    tyInfo _ = case tyInfo (Proxy :: Proxy s) of
        (i, o) -> (getTy (Proxy :: Proxy r):i, o)

但这需要OverlappingInstances和UndecidableInstances。

于 2013-08-10T18:11:17.577 回答