0

我有以下项目结构：

MyProject
   --src
   --test
      --acceptance
         --java
         --resources
      --unit

和以下 build.gradle

apply plugin: 'java'
apply plugin: 'idea'

version = '0.1'

repositories {
    mavenCentral()
}

sourceSets {
    main {
        java {
            srcDir 'src'
        }
    }
    unit {
        java {
            srcDir 'test/unit'
        }
        compileClasspath += sourceSets.main.runtimeClasspath
    }
    acceptance {
        java {
            srcDir 'test/acceptance/java'
        }
        resources {
            srcDir 'test/acceptance/resources'
        }
        compileClasspath += sourceSets.main.runtimeClasspath
    }
}

dependencies {
    compile fileTree(dir: 'lib', include: '*.jar')

    unitCompile group: 'junit', name: 'junit', version: '4.11'

    acceptanceCompile group: 'junit', name: 'junit', version: '4.11'
    acceptanceCompile group: 'info.cukes', name: 'cucumber-junit', version: '1.1.3'
    acceptanceCompile group: 'info.cukes', name: 'cucumber-java', version: '1.1.3'
}


task unitTest(type: Test) {
    description = "Runs Unit Tests"
    classpath += sourceSets.unit.runtimeClasspath
    testClassesDir = sourceSets.unit.output.classesDir
}


task acceptanceTest(type: Test) {
    description = "Runs Acceptance Tests"
    classpath += sourceSets.acceptance.runtimeClasspath
    testClassesDir = sourceSets.acceptance.output.classesDir
}

但是运行“gradle acceptTest”会导致编译问题，因为看起来在类路径中找不到依赖项。

4

2 回答 2

1

看起来在 1.1.3 版本中，Cucumber 类在包中

cucumber.api.junit

而不是

cucumber.junit

更改导入语句似乎至少解决了类路径问题。

但是，通过 gradle 运行 Cucumber JUnit 测试存在问题。此处提供了更多信息和使用 javaexec 任务的解决方法：https ://github.com/yatskevich/cucumber-jvm-gradle-javaexec 。总而言之，完成以下任务：

  task cucumber() {
    dependsOn assemble, compileAcceptanceJava
    doLast {
        javaexec {
            main = "cucumber.api.cli.Main"
            classpath = configurations.cucumberRuntime + sourceSets.main.output +
                    sourceSets.acceptance.output + sourceSets.unit.runtimeClasspath +
                    sourceSets.acceptance.runtimeClasspath

            args = ['-f', 'junit:build/reports/test-results/cucumber.xml',
                    '-f', 'html:build/reports/test/cucumber-tests.html',
                    '--glue', 'com.paragon', 'test/acceptance/features']
        }
    }
}

我们现在可以运行

gradle cucumber

并生成 JUnit 报告。

于 2013-08-10T13:20:30.790 回答
0

the syntax

srcDir 'path/to/src/dir'

is adding an additionally directory instead of replacing the default locations.

instead use

srcDrs = ['path/to/src/dir']

this should do the trick

cheers, rene

于 2013-08-09T23:01:18.910 回答