c++ - CMake 和 MsVS-NuGet

Question

我目前正在开发一个桌面应用程序，使用 C++ REST SDK（代号 Casablanca）、Qt5 和其他一些库。

对于项目设置，我使用 CMake。

如何让 CMake 安装 NuGet 包？

如果我重新运行 CMake，我现在每次都必须手动安装它，这不是一个真正的选择。

Answer 1

NuGet 的命令行参考位于http://docs.nuget.org/docs/reference/command-line-reference

nuget install您可以使用ornuget restore命令安装软件包。nuget update更新已安装的软件包（restore必须预先运行）。

您可以使用以下命令指示 cmake 在每次构建之前运行 NuGet：

add_custom_command(TARGET ${PROJECT_NAME}
    PRE_BUILD
    COMMAND nuget restore ${CMAKE_BINARY_DIR}\yourSolution.sln
)

或在配置时使用execute_process.

configure_file您可以使用或直接使用适当的nuget install命令来准备 nuget 配置文件。

Answer 2

编辑：从 CMake 3.15 开始，CMake 支持使用VS_PACKAGE_REFERENCES. 现在，这是一个比下面前面提出的解决方法更清洁的解决方案。要将 Nuget 包引用添加到 CMake 目标，请使用由_下划线分隔的包名称和包版本。这是BouncyCastle版本的示例1.8.5：

set_property(TARGET MyApplication
    PROPERTY VS_PACKAGE_REFERENCES "BouncyCastle_1.8.5"
)

该文档显示了如何通过分号分隔包来添加多个Nuget;包。

---

对于早于 3.15 的 CMake 版本，这是一种潜在的解决方法：

感谢@Markus Mayer 的出色回答。我接受了这个建议，但发现nuget如果您从头开始生成 VS 项目/解决方案文件，则使用命令行不会成立。具体来说，命令nuget行不会更新项目文件（.csproj以下步骤概述了我如何为一个具有一个 Nuget 包依赖项的简单项目解决此问题：

1. 在 Visual Studio 中使用 Nuget 包管理器安装了 Nuget 包依赖项。
2. 复制生成的packages.config文件（与受影响的文件在同一目录中生成.csproj）。将副本放入源目录，并将其重命名为packages.config.in. 现在，我们可以告诉 CMake 在配置阶段将此文件复制回 CMake 二进制目录，使用configure_file. 如果缺少依赖项，Nuget 将使用它来安装/恢复依赖项。
3. 记下 Nuget 为该软件包安装 DLL 的位置。在我的机器上，这是在 CMake 二进制目录中的一个packages目录中。

我们可以使用这个路径告诉 CMake 我们的参考包的位置：

set_property(TARGET MyApplication PROPERTY VS_DOTNET_REFERENCE_MyReferenceLib
    ${CMAKE_BINARY_DIR}/packages/path/to/lib/MyReferenceLib.dll)

我们还可以查看此依赖项在.csproj文件中的安装位置，以验证我们获得了正确的路径（请参阅 参考资料HintPath），并且没有遗漏任何其他依赖项：

<Reference Include="MyReferenceLib, Version=2.5.0, Culture=neutral, PublicKeyToken=1234567891234567, processorArchitecture=MSIL">
  <HintPath>packages\path\to\lib\MyReferenceLib.dll</HintPath>
</Reference>

4. 卸载 Nuget 包，因为现在我们拥有让 CMake 完成所有繁重工作所需的所有信息。

放在一起，CMake 命令如下所示：

# Find Nuget (install the latest CLI here: https://www.nuget.org/downloads).
find_program(NUGET nuget)
if(NOT NUGET)
    message(FATAL "CMake could not find the nuget command line tool. Please install it!")
else()
    # Copy the Nuget config file from source location to the CMake build directory.
    configure_file(packages.config.in packages.config COPYONLY)
    # Run Nuget using the .config file to install any missing dependencies to the build directory.
    execute_process(COMMAND 
        ${NUGET} restore packages.config -SolutionDirectory ${CMAKE_BINARY_DIR}
        WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
    )
endif()
# Provide the path to the Nuget-installed references, in case this is a fresh project build.
set_property(TARGET MyApplication PROPERTY 
    VS_DOTNET_REFERENCE_MyReferenceLib
    ${CMAKE_BINARY_DIR}/packages/path/to/lib/MyReferenceLib.dll)

虽然现在这也将为新的 CMake 构建提供 VS 项目的包路径，但有一个警告。如果要升级正在使用的 Nuget 安装包的版本，则必须重新执行上述手动步骤。

TL;DR：这是CMakeLists.txt我用 Nuget 安装的 SQLite 试用的完整文件：

cmake_minimum_required(VERSION 3.8)

# Project name
project(MyProject LANGUAGES CSharp)

# Include CMake utilities for CSharp, for WinForm and WPF application support.
include(CSharpUtilities)

set(MyProject_SOURCES 
    Form1.cs
    Form1.Designer.cs
    Form1.resx
    Program.cs
    Properties/AssemblyInfo.cs
    Properties/Resources.Designer.cs
    Properties/Resources.resx
    Properties/Settings.Designer.cs
    Properties/Settings.settings
)

# Define the executable, including any .cs files. 
# The .resx and other Properties files are optional here, but including them makes them visible in the VS solution for easy editing. 
add_executable(MyWinFormApp ${MyProject_SOURCES})

# Set the source file properties for Windows Forms use.
csharp_set_windows_forms_properties(${MyProject_SOURCES})

# Find Nuget (install the latest CLI here: https://www.nuget.org/downloads).
find_program(NUGET nuget)
if(NOT NUGET)
    message(FATAL "CMake could not find the nuget command line tool. Please install it!")
else()
    # Copy the Nuget config file from source location to the CMake build directory.
    configure_file(packages.config.in packages.config COPYONLY)
    # Run Nuget using the .config file to installing any missing dependencies to the build directory.
    execute_process(COMMAND 
        ${NUGET} restore packages.config -SolutionDirectory ${CMAKE_BINARY_DIR}
        WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
    )
endif()

# Set the .NET Framework version for the executable.
set_property(TARGET MyWinFormApp PROPERTY VS_DOTNET_TARGET_FRAMEWORK_VERSION "v4.6.1")

# Provide the path to the Nuget-installed references, in case this is a fresh project build.
set_property(TARGET MyWinFormApp PROPERTY 
    VS_DOTNET_REFERENCE_EntityFramework 
    ${CMAKE_BINARY_DIR}/packages/EntityFramework.6.2.0/lib/net45/EntityFramework.dll)
set_property(TARGET MyWinFormApp PROPERTY 
    VS_DOTNET_REFERENCE_EntityFramework.SqlServer 
    ${CMAKE_BINARY_DIR}/packages/EntityFramework.6.2.0/lib/net45/EntityFramework.SqlServer.dll)
set_property(TARGET MyWinFormApp PROPERTY 
    VS_DOTNET_REFERENCE_System.Data.SQLite
    ${CMAKE_BINARY_DIR}/packages/System.Data.SQLite.Core.1.0.110.0/lib/net46/System.Data.SQLite.dll)
set_property(TARGET MyWinFormApp PROPERTY 
    VS_DOTNET_REFERENCE_System.Data.SQLite.EF6 
    ${CMAKE_BINARY_DIR}/packages/System.Data.SQLite.EF6.1.0.110.0/lib/net46/System.Data.SQLite.EF6.dll)
set_property(TARGET MyWinFormApp PROPERTY 
    VS_DOTNET_REFERENCE_System.Data.SQLite.Linq
    ${CMAKE_BINARY_DIR}/packages/System.Data.SQLite.Linq.1.0.110.0/lib/net46/System.Data.SQLite.Linq.dll)

# Add in the .NET reference libraries.
set_property(TARGET MyWinFormApp PROPERTY VS_DOTNET_REFERENCES
    "System"
    "System.Core"
    "System.Data"
    "System.Windows.Forms"
)

Answer 3

根据https://github.com/clarkezone/flutter_win_webview/commit/ce603ec8c96bed50e4443c49a150ce4d3d352896

find_program(NUGET_EXE NAMES nuget)
exec_program(${NUGET_EXE}
    ARGS install "Microsoft.Web.WebView2" -Version 0.9.579 -ExcludeVersion -OutputDirectory ${CMAKE_BINARY_DIR}/packages)
target_link_libraries(${PLUGIN_NAME} PRIVATE ${CMAKE_BINARY_DIR}/packages/Microsoft.Web.WebView2/build/native/Microsoft.Web.WebView2.targets)