1

我是 excel 宏和 vba 的新手。我有一个 excel 文件，第一张表中有大约 300000 行，其中第一列中有项目标识符（它们可能是几个具有相同值的），第二张表中有大约 1000 行（第一列也包含项目标识符，但它们是唯一的这里）。我需要编写一个宏，根据第二张表隐藏第一张表中的行。我的意思是我需要循环抛出第一张表中的所有行，如果第一个单元格值与第二张表第一列的任何单元格不匹配，则隐藏该行。

我知道它会很慢，因为每次我需要将 cellvalue 与另外 1000 个单元格值进行比较，并且我有 300 000 行。我该怎么做？你能建议最快的方法吗？任何帮助将不胜感激，在此先感谢。

经过大量搜索后编辑我制作了自己的宏 

Sub hide()    
Dim MyCell, Rng As Range, Rn2 As Range
Dim MyCell2
Dim id(1 To 1392) As String
Set Rng = Sheets("Sheet0").Range("C162403:C339579")
Set Rng2 = Sheets("IT stuff").Range("A1:A22031")
i = 1
For Each MyCell2 In Rng2
    If Not MyCell2.EntireRow.Hidden Then
        id(i) = MyCell2.Value
        i = i + 1
    End If
Next MyCell2
j = 0
For Each MyCell In Rng
    For A = 1 To 1392
        If MyCell = id(A) Then
        j = 1
        End If
    Next A
    If j = 0 Then
        MyCell.EntireRow.Hidden = True
    ElseIf j = 1 Then
        j = 0
    End If
Next MyCell
End Sub

它现在正在处理我的 excel 文件，但是速度很慢......我该如何改进它？

4

3 回答 3

1

为什么选择 VBA？而不是Excel Formula(Vlookup)+Autofilter

假设您的工作表 1 看起来像这样

在此处输入图像描述

表 2 看起来像这样

在此处输入图像描述

只需添加一个列，如下所示并输入公式，然后使用自动过滤器隐藏相关行。

在此处输入图像描述

中使用的公式I2是

=IF(ISERROR(VLOOKUP(A2,Sheet2!A:A,1,0)),"","True")
于 2013-08-07T11:40:27.347 回答
0

调用 Excel 对象模型会大大降低速度，因此最好将要检查的值加载到字典或数组中并引用它。您还可以在另一个字典中加载您正在检查的行的行号和值，并交叉引用这两个数据结构，同时记下您需要隐藏的行。以这种方式工作会占用相当多的内存，但肯定会比直接交叉引用工作表更快......

hth

于 2013-08-07T10:04:46.720 回答
0

以下代码对您的问题采取了一些不同的方法。您会注意到，它假定 Sheet1 在 A 列中有一组值加上未指定数量的数据列，并且 Sheet2 在 A 列中只有一组值，Sheet1 列 A 值与之匹配。

该代码执行以下操作：

  • 在工作表 1 中最后一个数据列右侧的列中创建匹配值（1 = 不匹配，0 = 匹配）
  • 在工作表 1 数据范围上设置自动过滤器，匹配列上的标准值为 1（即过滤器以仅显示不匹配项）
  • 将过滤后的行分配给范围变量
  • 删除过滤器并清除匹配列
  • 批量隐藏范围变量中标识的行

我使用 Sheet1 数据集测试了该过程，该数据集包含 A 列中的 300,000 行代码值以及 B 和 C 列中的随机数字数据，Sheet2 中只有 1,000 多个匹配值。构造随机生成的 10 个字符的代码和匹配值，以便 Sheet1 列 A 值的 20% 不匹配。

针对这些数据的运行时间平均不到两分钟。

Sub MatchFilterAndHide2()

    Dim calc As Variant
    Dim ws1 As Worksheet, ws2 As Worksheet
    Dim ws1Name As String, ws2Name As String
    Dim rng1 As Range, rng2 As Range
    Dim hideRng As Range
    Dim lastRow1 As Long, lastRow2 As Long
    Dim lastCol1 As Long

    Application.ScreenUpdating = False
    calc = Application.Calculation
    Application.Calculation = xlCalculationManual

    ws1Name = "Sheet1"
    Set ws1 = Worksheets(ws1Name)
    With ws1
        lastRow1 = .Range("A" & .Rows.Count).End(xlUp).Row
        lastCol1 = .Cells(1, ws1.Columns.Count).End(xlToLeft).Column + 1
        Set rng1 = .Range(.Cells(1, 1), .Cells(lastRow1, lastCol1))
    End With

    ws2Name = "Sheet2"
    Set ws2 = Worksheets(ws2Name)
    With ws2
        lastRow2 = .Range("A" & .Rows.Count).End(xlUp).Row
        Set rng2 = .Range("A2:A" & lastRow2)
    End With

    'add column of match values one column to the right of last data column
    '1 = no-match, 0 = match
    With ws1.Range(ws1.Cells(2, lastCol1), ws1.Cells(lastRow1, lastCol1))
        .FormulaArray = "=N(ISNA(MATCH(" & ws1Name & "!" & rng1.Address & _
            "," & ws2Name & "!" & rng2.Address & ",0)))"
        .Value = .Value
    End With

    'set autofilter on rng1 and filter to show the no-matches
    With ws1.Range(ws1.Cells(1, 1), ws1.Cells(1, lastCol1))
        .AutoFilter
        .AutoFilter field:=lastCol1, Criteria1:=1
    End With

    With ws1
        'assign no-matches to range object
        Set hideRng = .Range("A2:A" & lastRow1).SpecialCells(xlCellTypeVisible)

        'turn off autofilter, clear match column, and hide no-matches
        .AutoFilterMode = False
        .Cells(1, lastCol1).EntireColumn.Clear
        hideRng.EntireRow.Hidden = True
        .Cells(1, 1).Select
    End With

    Application.Calculation = calc
    Application.ScreenUpdating = True
End Sub
于 2013-08-09T16:39:33.630 回答