loops - 您如何遍历 AppleScript 中的菜单？

Question

具体来说，当我在 iOS 中调试 Web 内容时，我可以通过单击 Safari 菜单栏中的以下菜单项来启动 Safari Web Inspectors：

• 开发->iPad模拟器->Safari->我的网页标题
• 开发->iPad名称（我的叫Summer）->Safari->我的网页标题

我想遍历 Safari 菜单并激活“开发”菜单中包含我在网页标题中使用的公共子字符串的任何项目。

Answer 1

这是一个例子。假设我想单击 Safari 中“开发”菜单下的“显示 Web 检查器”菜单项。我将首先在“开发”菜单中获取所有 UIElement，然后遍历它们以查找具有正确名称的 UIElement。一旦找到我可以点击它。

请注意，这样做的秘诀是获取某些 UIElement 的“全部内容”，在本例中是“开发”菜单。这给了我菜单中每个 UIElement 的列表，以便我可以遍历它们并找到我想要的任何东西。

另请注意，我在 if 语句周围有一个 try 块。那是因为一些 UIElements 没有名称并且它错误，所以这只是忽略了这些错误。

tell application "Safari" to activate

tell application "System Events"
    tell process "Safari"
        set developMenu to menu bar item "Develop" of menu bar 1
        set allUIElements to entire contents of developMenu
        repeat with anElement in allUIElements
            try
                if name of anElement is "Show Web Inspector" then
                    click anElement
                    exit repeat
                end if
            end try
        end repeat
    end tell
end tell

Answer 2

tell application "System Events" to tell process "Finder"
    set frontmost to true
    tell menu 1 of menu item "Arrange by" of menu 1 of menu bar item "View" of menu bar 1
        click (menu items where its name contains "a")
    end tell
end tell

tell application "System Events" to tell process "Finder"
    set frontmost to true
    repeat with m in (get menu 1 of menu items of menu 1 of menu bar item "View" of menu bar 1)
        set m to contents of m
        if m is not missing value then
            click (menu items of m where name contains "a")
        end if
    end repeat
end tell