1

我想打印 的数据Cursor_pkg.c1.row_emp，例如：在之后的过程中将Cursor_pkg.c1.row_emp.last_name存在的数据将起作用。我该怎么做？Cursor_pkg.row_empCursor_pkg_func.Print_Cur

  1. 我用 cursor 和 rec 创建 PACKAGE
  2. 我使用在 rec 中获取游标数据的过程创建 PACKAGE
  3. 我想输出获取的数据。如何？

有两个问题：我想从包emp_rec（行）输出数据，我想直接从PACKAGECursor_pkg_func过程输出它PS主要思想是存储数据和用于获取和选择数据的过程/函数

 CREATE OR REPLACE PACKAGE Cursor_pkg AUTHID DEFINER IS
        CURSOR C1 IS
            SELECT last_name, job_id FROM employees
            WHERE job_id LIKE '%CLERK%' AND manager_id > 120
            ORDER BY last_name;
        row_emp C1%ROWTYPE;     
    END Cursor_pkg;
    /

CREATE OR REPLACE PACKAGE Cursor_pkg_func IS
PROCEDURE Print_Cur;
END Cursor_pkg_func;
/

CREATE OR REPLACE PACKAGE BODY Cursor_pkg_func IS
    PROCEDURE Print_Cur IS
    BEGIN
        OPEN Cursor_pkg.C1;
        LOOP
            FETCH Cursor_pkg.C1 INTO Cursor_pkg.row_emp;
            EXIT when Cursor_pkg.C1%NOTFOUND;
            DBMS_OUTPUT.put_line(Cursor_pkg.row_emp.last_name);
        END LOOP;
        CLOSE Cursor_pkg.C1;
     END;
END;
/

BEGIN 
Cursor_pkg_func.Print_Cur;
END;

但是我想在没有创建函数的情况下从 Cursor_pkg.row_emp PACKAGE 中选择和打印。以及如何不仅打印 last_name 还打印所有行？错误开始于：最后三个语句有什么问题？

CREATE OR REPLACE PACKAGE Cursor_pkg_func IS
TYPE outrec_typ IS RECORD (
    var_char2  VARCHAR2(30)
  );
  TYPE outrecset IS TABLE OF outrec_typ;
  FUNCTION f_trans (p in number ) RETURN outrecset PIPELINED;
END Cursor_pkg_func;
/

CREATE OR REPLACE PACKAGE BODY Cursor_pkg_func IS
    FUNCTION f_trans (p in number) RETURN outrecset PIPELINED IS
    out_rec outrec_typ;
    BEGIN
        OPEN Cursor_pkg.C1;
        LOOP
            FETCH Cursor_pkg.C1 INTO Cursor_pkg.row_emp;
            EXIT when Cursor_pkg.C1%NOTFOUND;
        END LOOP;
        LOOP
        out_rec.var_char2 := Cursor_pkg.row_emp.last_name;
        PIPE ROW(out_rec);
        DBMS_OUTPUT.put_line(out_rec.var_char2);
        END LOOP;
        CLOSE Cursor_pkg.C1;
     RETURN;
     END f_trans;
END Cursor_pkg_func;
/

begin
Cursor_pkg_func.f_trans(5);
end;
/
4

1 回答 1

3

您已经定义了一个流水线函数，这不是调用它的方法：

SQL> begin
  2  Cursor_pkg_func.f_trans(5);
  3  end;
  4  /
Cursor_pkg_func.f_trans(5);
*
ERROR at line 2:
ORA-06550: line 2, column 1:
PLS-00221: 'F_TRANS' is not a procedure or is undefined
ORA-06550: line 2, column 1:
PL/SQL: Statement ignored


SQL>

您需要使用 TABLE() 函数。尽管那时您会发现代码中的错误：

SQL>  select * from table(Cursor_pkg_func.f_trans(5))
  2   /

SMITH
SMITH
SMITH
''''
SMITH
SMITH
SMITH
SMITH
ERROR:
ORA-00028: your session has been killed



273660 rows selected.

SQL>

请注意，我必须从另一个会话中终止该会话，否则它仍然会运行。所以让我们简化函数并摆脱那个毫无意义的第二个循环......

CREATE OR REPLACE PACKAGE BODY Cursor_pkg_func IS
    FUNCTION f_trans (p in number) RETURN outrecset PIPELINED IS
    out_rec outrec_typ;
    BEGIN
        OPEN Cursor_pkg.C1;
        LOOP
            FETCH Cursor_pkg.C1 INTO Cursor_pkg.row_emp;
            EXIT when Cursor_pkg.C1%NOTFOUND;
            out_rec.var_char2 := Cursor_pkg.row_emp.last_name;
            PIPE ROW(out_rec);
        END LOOP;
        CLOSE Cursor_pkg.C1;
     RETURN;
     END f_trans;
END Cursor_pkg_func;
/

....然后看！

SQL> select * from table(Cursor_pkg_func.f_trans(5))
  2  /

VAR_CHAR2
------------------------------
ADAMS
JAMES
MILLER
SMITH

SQL>

“当我添加开始和结束时；选择不起作用”

您已经创建了一个流水线函数。你为什么这么做？你应该这样做的原因是你想要一个可以在 SELECT 语句的 FROM 子句中使用的 PL/SQL 函数。这就是流水线函数的用例。因此，将调用放入匿名 PL/SQL 块中确实没有意义。

但不管怎么说。

请阅读文档。它非常全面，在线且免费。PL/SQL Reference 中的相关部分是关于静态 SQL 的章节。很清楚，PL/SQL 中的 SELECT 语句必须始终将记录提取到某种描述的变量中。在这方面，匿名 PL/SQL 块与存储过程相同。 了解更多。

于 2013-08-04T11:20:43.147 回答