2

我正在使用 xslt 创建动态表（网格），

XSLT：

<xsl:stylesheet version="1.0"
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
     <xsl:output omit-xml-declaration="yes" indent="yes"/>

     <xsl:key name="RowAttribsByName" match="Row/@*"

      use="concat(generate-id(..), '|', name())"/>

 <xsl:variable name="vColNames" select=
  "/*/Columns/*[not(@Hidden = 'true')]/@Name"/>

 <xsl:template match="/*">
  <table border="1">
    <tr>
     <xsl:apply-templates select="Columns/*"/>
    </tr>
    <xsl:apply-templates select="Rows/Row"/>
  </table>
 </xsl:template>

 <xsl:template match="Column[not(@Hidden = 'true')]">
  <td><xsl:value-of select="@Caption"/></td>
 </xsl:template>

 <xsl:template match="Row">
  <tr>
   <xsl:apply-templates select="$vColNames">
     <xsl:with-param name="pRowId"
          select="generate-id()"/>
   </xsl:apply-templates>
  </tr>
 </xsl:template>

 <xsl:template match="Column/@*">
  <xsl:param name="pRowId"/>

  <td width="50%">
    <xsl:value-of select=
      "key('RowAttribsByName',
           concat($pRowId, '|', .)
           )
    "/>
  </td>
 </xsl:template>
</xsl:stylesheet>

XML 数据：

<TableData>
    <Columns>
        <Column Name="ID" Hidden="true" />
        <Column Name="Name" Caption="Item Name" Link="Yes" Sort="Yes"/>
        <Column Name="Desc" Caption="Item Description" />
    </Columns>
    <Rows>
        <Row ID="0" Name="A" />
        <Row ID="1" Name="B" Desc="Some description"/>
        <Row ID="3" Name="C" />
    </Rows>
</TableData>

预期输出：

<table border="1">
    <tbody>
        <tr>
            <td>
                <a onclick="javascript:SortColumn('Item Name')">Item Name</a>
            </td>
            <td>
                <a onclick="javascript:SortColumn('Item Description')">Item Name</a></td>
        </tr>
        <tr>
            <td width="50%">
                <a onclick="javascript:OpenDifferentPage('A','0')">A</a>
            </td>
            <td width="50%"></td>
        </tr>
        <tr>
            <td width="50%">B</td>
            <td width="50%">Some description</td>
        </tr>
        <tr>
            <td width="50%">C</td>
            <td width="50%"></td>
        </tr>
    </tbody>
</table>

我是 XSLT 的初学者，

我想在这里检查如果列具有“链接”属性=“是”，那么我需要在锚标记（名称）之间显示数据。

我在这个专栏上创建了许多复杂的功能。所以在这里我可以为特定列制作模板（列是 15，但它取决于用户选择，如果用户选择 8 列进行显示，并且它必须保持列的顺序）

最好是如果我可以为所有列创建新模板，并根据传递的列数据维护列顺序。

谢谢你的期待

4

2 回答 2

2

对于 XSLT 的初学者，您已经有了一个很好的开始，尤其是在使用xsl:key时。

要回答您的直接问题，您可以做什么，而不是像目前一​​样拥有与Column元素的属性匹配的单个模板......

<xsl:template match="Column/@*">

设置Link属性时，您可以使用显式模板匹配它

<xsl:template match="Column[@Link='Yes']/@*">

在此模板中，您可以添加额外的代码来输出链接。请注意，如果您将实际的Row作为参数传递，而不是为Row 传递generate-id的值，它可能会稍微简单一些，因为这会使获取ID属性的过程稍微不那么冗长。

 <xsl:template match="Column[@Link='Yes']/@*">
  <xsl:param name="pRow"/>
  <xsl:variable name="pRowId" select="generate-id($pRow)"/>
  <xsl:variable name="pValue" select="key('RowAttribsByName', concat($pRowId, '|', .))" />
  <td width="50%">
     <a onclick="javascript:OpenDifferentPage('{$pValue}','{$pRow/@ID}')">
        <xsl:value-of select="$pValue"/>
     </a>
  </td>
 </xsl:template>

请注意此处在创建onclick属性时使用属性值模板。花括号表示要计算的表达式，而不是字面输出。

但是，要使此模板正常工作，您还需要修改另一个模板以显式匹配链接属性未设置为“是”的属性

<xsl:template match="Column[not(@Link='Yes')]/@*">

这是因为否则原始模板将匹配Link为“是”的情况，与新模板具有相同的优先级，这是不允许的。

试试这个 XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output omit-xml-declaration="yes" indent="yes"/>
   <xsl:key name="RowAttribsByName" match="Row/@*" use="concat(generate-id(..), '|', name())"/>
   <xsl:variable name="vColNames" select="/*/Columns/*[not(@Hidden = 'true')]/@Name"/>

   <xsl:template match="/*">
      <table border="1">
         <tr>
            <xsl:apply-templates select="Columns/*"/>
         </tr>
         <xsl:apply-templates select="Rows/Row"/>
      </table>
   </xsl:template>

   <xsl:template match="Column[not(@Hidden = 'true')]">
      <td>
         <xsl:value-of select="@Caption"/>
      </td>
   </xsl:template>

   <xsl:template match="Row">
      <tr>
         <xsl:apply-templates select="$vColNames">
            <xsl:with-param name="pRow" select="."/>
         </xsl:apply-templates>
      </tr>
   </xsl:template>

   <xsl:template match="Column[not(@Link='Yes')]/@*">
      <xsl:param name="pRow"/>
      <xsl:variable name="pRowId" select="generate-id($pRow)"/>
      <xsl:variable name="pValue" select="key('RowAttribsByName', concat($pRowId, '|', .))"/>
      <td width="50%">
         <xsl:value-of select="$pValue"/>
      </td>
   </xsl:template>

   <xsl:template match="Column[@Link='Yes']/@*">
      <xsl:param name="pRow"/>
      <xsl:variable name="pRowId" select="generate-id($pRow)"/>
      <xsl:variable name="pValue" select="key('RowAttribsByName', concat($pRowId, '|', .))"/>
      <td width="50%">
         <a onclick="javascript:OpenDifferentPage('{$pValue}','{$pRow/@ID}')">
            <xsl:value-of select="$pValue"/>
         </a>
      </td>
   </xsl:template>
</xsl:stylesheet>

这种方法有几个缺点。有一些重复的代码，如果您在Column元素上有其他影响列输出的属性，那么管理起来也将更加困难。

这是 XSLT 的另一个版本，它利用mode元素重复匹配 Column 属性，允许您在需要时输出更多元素

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output omit-xml-declaration="yes" indent="yes"/>
   <xsl:key name="RowAttribsByName" match="Row/@*" use="concat(generate-id(..), '|', name())"/>
   <xsl:variable name="vColNames" select="/*/Columns/*[not(@Hidden = 'true')]/@Name"/>

   <xsl:template match="/*">
      <table border="1">
         <tr>
            <xsl:apply-templates select="Columns/*"/>
         </tr>
         <xsl:apply-templates select="Rows/Row"/>
      </table>
   </xsl:template>

   <xsl:template match="Column[not(@Hidden = 'true')]">
      <td>
         <xsl:value-of select="@Caption"/>
      </td>
   </xsl:template>

   <xsl:template match="Row">
      <tr>
         <xsl:apply-templates select="$vColNames">
            <xsl:with-param name="pRow" select="."/>
         </xsl:apply-templates>
      </tr>
   </xsl:template>

   <xsl:template match="Column/@Name">
      <xsl:param name="pRow"/>
      <xsl:variable name="pRowId" select="generate-id($pRow)"/>
      <xsl:variable name="pValue" select="key('RowAttribsByName', concat($pRowId, '|', .))"/>
      <td width="50%">
         <xsl:apply-templates select=".." mode="link">
            <xsl:with-param name="pRow" select="$pRow"/>
            <xsl:with-param name="pValue" select="$pValue"/>
         </xsl:apply-templates>
      </td>
   </xsl:template>

   <xsl:template match="Column[@Link='Yes']" mode="link">
      <xsl:param name="pRow"/>
      <xsl:param name="pValue"/>
      <a onclick="javascript:OpenDifferentPage('{$pValue}','{$pRow/@ID}')">
         <xsl:apply-templates select="self::*" mode="value">
            <xsl:with-param name="pRow" select="$pRow"/>
            <xsl:with-param name="pValue" select="$pValue"/>
         </xsl:apply-templates>
      </a>
   </xsl:template>

   <xsl:template match="Column" mode="link">
      <xsl:param name="pRow"/>
      <xsl:param name="pValue"/>
      <xsl:apply-templates select="self::*" mode="value">
         <xsl:with-param name="pRow" select="$pRow"/>
         <xsl:with-param name="pValue" select="$pValue"/>
      </xsl:apply-templates>
   </xsl:template>

   <xsl:template match="Column" mode="value">
      <xsl:param name="pRow"/>
      <xsl:param name="pValue"/>
      <xsl:value-of select="$pValue"/>
   </xsl:template>
</xsl:stylesheet>

请注意，在此示例中，链接有两个模板

<xsl:template match="Column[@Link='Yes']" mode="link">

<xsl:template match="Column" mode="link">

在这种情况下，第二个不需要检查Link属性。如果模板只匹配明确的元素名称，它的优先级将低于已使用 xpath 表达式限定的模板。因此，第二个模板永远不会匹配Link为 Yes 的情况。

于 2013-08-03T10:49:42.093 回答
1

这个 XSLT 1.0 样式表...

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="html" doctype-system="about:legacy-compat" encoding="UTF-8" indent="yes" />
<xsl:strip-space elements="*" />

<xsl:key name="linked-cols" match="Column[@Link='Yes']" use="@Name" />

<xsl:template match="TableData">
  <table border="1">
    <tbody>
      <xsl:variable name="cols" select="count(Columns/Column[not(@Hidden='true')])" />
      <xsl:apply-templates>
        <xsl:with-param name="col-width" select="concat(100 div $cols,'%')" />
      </xsl:apply-templates> 
    </tbody>
  </table>
</xsl:template>

<xsl:template match="Columns">
  <tr>
     <xsl:apply-templates /> 
  </tr>
</xsl:template>

<xsl:template match="Column[@Hidden='true']" />

<xsl:template match="Column[@Sort='Yes']">
  <td>
    <a onclick="javascript:SortColumn('{@Caption}')"><xsl:value-of select="@Caption" /></a>
  </td>
</xsl:template>

<xsl:template match="Column">
  <td><xsl:value-of select="@Caption" /></td>
</xsl:template>

<xsl:template match="Rows">
  <xsl:param name="col-width" />
  <xsl:apply-templates>
    <xsl:with-param name="col-width" select="$col-width" />
  </xsl:apply-templates>
</xsl:template>

<xsl:template match="Row">
  <xsl:param name="col-width" />
  <tr>
    <xsl:variable name="Row" select="." />
    <xsl:for-each select="../../Columns/Column[not(@Hidden='true')]">
      <td width="{$col-width}">
        <xsl:variable name="col-name" select="@Name" />
        <xsl:apply-templates select="$Row/@*[local-name() = $col-name]" />
      </td>  
    </xsl:for-each>
  </tr>
</xsl:template>

<xsl:template match="Row/@*">
  <xsl:value-of select="." />
</xsl:template>

<xsl:template match="Row/@*[key('linked-cols',local-name())]">
  <a onclick="javascript:OpenDifferentPage('{.}','{../@ID}')"><xsl:value-of select="." /></a>
</xsl:template>

</xsl:stylesheet>

...当应用于本文档时...

<TableData>
    <Columns>
        <Column Name="ID" Hidden="true" />
        <Column Name="Name" Caption="Item Name" Link="Yes" Sort="Yes"/>
        <Column Name="Desc" Caption="Item Description" />
    </Columns>
    <Rows>
        <Row ID="0" Name="A" />
        <Row ID="1" Name="B" Desc="Some description"/>
        <Row ID="3" Name="C" />
    </Rows>
</TableData>

...将产生...

<!DOCTYPE html SYSTEM "about:legacy-compat">
<table border="1">
  <tbody>
    <tr>
      <td><a onclick="javascript:SortColumn('Item Name')">Item Name</a></td>
      <td>Item Description</td>
    </tr>
    <tr>
      <td width="50%"><a onclick="javascript:OpenDifferentPage('A','0')">A</a></td>
      <td width="50%"></td>
    </tr>
    <tr>
      <td width="50%"><a onclick="javascript:OpenDifferentPage('B','1')">B</a></td>
      <td width="50%">Some description</td>
    </tr>
    <tr>
      <td width="50%"><a onclick="javascript:OpenDifferentPage('C','3')">C</a></td>
      <td width="50%"></td>
    </tr>
  </tbody>
</table>
于 2013-08-04T08:19:18.990 回答