16

我创建了这个小程序，它创建了一个长时间运行的 thunk，最终由于异常而失败。然后，多个线程尝试评估它。

import Control.Monad
import Control.Concurrent
import Control.Concurrent.MVar

main = do
    let thunk = let p = product [1..10^4]
                 in if p `mod` 2 == 0 then error "exception"
                                      else ()
    children <- replicateM 2000 (myForkIO (print thunk))
    mapM_ takeMVar children

-- | Spawn a thread and return a MVar which can be used to wait for it.
myForkIO :: IO () -> IO (MVar ())
myForkIO io = do
     mvar <- newEmptyMVar
     forkFinally io (\_ -> putMVar mvar ())
     return mvar

增加线程数显然对计算没有影响，这表明失败的 thunk 会保留异常作为结果。这是真的吗？这种行为是否在某处记录/指定？

更新：forkFinally将行更改为

forkFinally io (\e -> print e >> putMVar mvar ())

确认每个线程都因异常而失败。

4

1 回答 1

12

让我通过使用库展示 GHC 是如何实际做到这一点来回答这个问题的ghc-heap-view。您可能可以复制它ghc-vis并获得漂亮的图片。

我首先在某处创建具有异常值的数据结构：

Prelude> :script /home/jojo/.cabal/share/ghc-heap-view-0.5.1/ghci 
Prelude> let x = map ((1::Int) `div`) [1,0]

起初它纯粹是一个 thunk（似乎涉及各种类型的类）：

Prelude> :printHeap x
let f1 = _fun
in (_bco [] (_bco (D:Integral (D:Real (D:Num _fun _fun _fun _fun _fun _fun _fun) (D:Ord (D:Eq _fun _fun) _fun _fun _fun _fun _fun _fun _fun) _fun) (D:Enum _fun _fun f1 f1 _fun _fun _fun _fun) _fun _fun _fun _fun _fun _fun _fun) _fun) _fun)()

现在我评估非异常抛出部分：

Prelude> (head x, length x)
(1,2)
Prelude> System.Mem.performGC
Prelude> :printHeap x
[I# 1,_thunk (_fun (I# 1)) (I# 0)]

列表的第二个元素仍然只是一个“正常”的重击。现在我评估一下，得到一个异常，然后再看一遍：

Prelude> last x
*** Exception: divide by zero
Prelude> System.Mem.performGC
Prelude> :printHeap x
[I# 1,_thunk (SomeException (D:Exception _fun (D:Show _fun _fun _fun) _fun _fun) DivideByZero())]

您可以看到它现在是一个引用SomeException对象的 thunk。SomeException数据构造函数有类型forall e . Exception e => e -> SomeException，所以构造函数的第二个参数是异常的构造DivideByZero函数，ArithException第一个参数是对应Exception类型的类实例。

这个 thunk 可以像任何其他 Haskell 值一样被传递，并且如果评估，将再次引发异常。而且，就像任何其他值一样，可以共享异常：

Prelude> let y = (last x, last x)
Prelude> y
(*** Exception: divide by zero
Prelude> snd y
*** Exception: divide by zero
Prelude> System.Mem.performGC
Prelude> :printHeap y
let x1 = SomeException (D:Exception _fun (D:Show _fun _fun _fun) _fun _fun) DivideByZero()
in (_thunk x1,_thunk x1)

线程和 MVar 也会发生同样的事情，没什么特别的。

于 2013-08-03T21:08:11.640 回答