12

我正在尝试使用 Groovy MarkupBuilder 生成 XML。

所需的 XML 采用这种形式（简化）：

<Order>
  <StoreID />
  <City />
  <Items>
    <Item>
      <ItemCode />
      <UnitPrice />
      <Quantity />
    </Item>
  </Items>
</Order>

数据存储在 Excel 文件中，易于访问。我的 Groovy 脚本解析 Excel 并生成 XML。

例如

import groovy.xml.*
def writer = new StringWriter()
def xml = new MarkupBuilder(writer)

xml.Order{
  StoreID("Store1")
  City("New York")
  Items(){
    Item(){
      ItemCode("LED_TV")
      UnitPrice("800.00")
      Quantity("2")
    }
  }
}

“项目”内可以有多个“项目”容器。

我的问题是：假设我们要生成具有 10 个项目的 Order XML。有没有办法在“项目”容器中编写类似 for 循环的东西？这样，我们就不需要为 10 个不同的项目编写 MarkupBuilder 代码。

有一个类似的问题将动态元素和属性添加到 groovy MarkupBuilder 或 StreamingMarkupBuilder。但它没有讨论循环。

4

2 回答 2

23

是的，有一种使用循环的方法。在此处扩展您的示例：

import groovy.xml.*
def writer = new StringWriter()
def xml = new MarkupBuilder(writer)

//List of items represented as a map
def items = [[itemCode: "A", unitPrice: 10, quantity: 2], 
             [itemCode: "B", unitPrice: 20, quantity: 3], 
             [itemCode: "C", unitPrice: 30, quantity: 4], 
             [itemCode: "D", unitPrice: 40, quantity: 6], 
             [itemCode: "E", unitPrice: 50, quantity: 5]]

xml.Order{
  StoreID("Store1")
  City("New York")
  Items{
    //Loop through the list.
    //make sure you are using a variable name instead of using "it"
    items.each{item->
      Item{
        ItemCode(item.itemCode)
        UnitPrice(item.unitPrice)
        Quantity(item.quantity)
      }
    }
  }
}

println writer

应该给你你所期望的。

于 2013-08-02T06:56:32.503 回答
2

这个贡献帮助我解决了一个类似的问题：我想在 MarkupBuilder 块中调用函数，就像addElement()我的示例中的函数一样。

我想将代码分成不同的功能。

在 MarkupBuilder 块中调用函数的示例：

static void addElement(Map<String,String> elements, MarkupBuilder mb) {
    mb."${elements.tag}"(elements.content)
}

static void example() {
    def writer = new StringWriter()
    def htmlBuilder = new MarkupBuilder(writer)

    String tag = "a"
    Map<String, String> attributes1 = new HashMap<>()
    attributes1.put("href","http://address")
    String content1 = "this is a link"

    Map<String, String> element1 = new HashMap<>()
    element1.put("tag","b")
    element1.put("content","bold content 1")

    Map<String, String> element2 = new HashMap<>()
    element2.put("tag","b")
    element2.put("content","bold content 2")

    List<Map<String, String>> elements = new ArrayList<>()
    elements.add(element1)
    elements.add(element2)

    htmlBuilder."html" {
        "${tag}"( attributes1, content1 )
        elements.each { contentIterator ->
            addElement(contentIterator, htmlBuilder)
        }
    }

    println writer
 }

它产生这个输出：

<html>
  <a href='http://address'>this is a link</a>
  <b>bold content 1</b>
  <b>bold content 2</b>
</html>
于 2018-07-14T10:22:22.387 回答