perl - 通过减法计算时间差

Question

有没有办法在不使用 perl 模块的情况下以以下格式减去时间以给出时差？

我期待这样的结果：

05:16:54:365  - 05:16:51:209 = 000003.156000

如果需要，这里可以使用什么 perl 模块？

Answer 1

有了一些相当大的保留，此代码可以完成您对给定数据所需的工作：

#!/usr/bin/env perl
use strict;
use warnings;

use Test::Simple tests => 1;

sub time_check
{
    my($tv, $hh, $mm, $ss, $ms) = @_;
    die "Hours ($hh) out of range 00..23 in $tv" if $hh < 0 || $hh > 23;
    die "Minutes ($mm) out of range 00..59 in $tv" if $mm < 0 || $mm > 59;
    die "Seconds $(ss) out of range 00..59 in $tv" if $ss < 0 || $ss > 59;
    die "Milliseconds ($ms) out of range 000..999 in $tv" if $ms < 0 || $ms > 999;
    return;
}

sub time_seconds
{
    my($tm) = @_;
    my($hh, $mm, $ss, $ms) = split /:/, $tm;
    time_check($tm, $hh, $mm, $ss, $ms);
    my $rv = ($hh * 60 + $mm) * 60 + $ss + ($ms / 1000.0);
    return $rv;
}

sub time_diff
{
    my($s1, $s2) = @_;
    my $t1 = time_seconds($s1);
    my $t2 = time_seconds($s2);
    my $rv = sprintf "%013.6f", $t1 - $t2;
    return $rv;
}

my $v1 = "05:16:54:365";
my $v2 = "05:16:51:209";
my $ev = "000003.156000";

ok(time_diff($v1, $v2) eq $ev, "time diff $v1 - $v2 = $ev");

更大的问题之一是，如果您没有为毫秒值指定所有三位数字，您将误解时间。也就是说，05:16:54:36将被视为05:16:54:036并且05:16:54:3将被视为05:16:54:003。从这对时间值中也不清楚您是否可以获得负面结果（颠倒两个值的顺序？），如果可以，所需的格式是什么。我假设这些值被限制为代表 24 小时制的时间，但我24:00:00:000在一天结束时拒绝为午夜（这可能很有用）。等等。这些是真正的日历模块将处理的细节。错误处理是可恶的；die不是长期可接受的解决方案。