0

我正在使用 oracle 数据库。我习惯使用 SQL 服务器，但不熟悉 Oracle 数据库的 PL/SQL。如何设置一个变量来返回包含该变量值的所有行：我迷路了，我试图理解，但这对我来说没有意义。这是我最近对此所做的尝试。

DECLARE date1 varchar(40);
Begin
Select '''07/31/2013_09%''' into :date1 from dual;
End;
/
print date1


Begin
Select * from TABLE1 where start_time LIKE date1;
End;
/

我应该得到所有从这里返回的行。谢谢您的帮助。

4

3 回答 3

1

这可能会帮助您入门：

create table table1 (
  start_time varchar2(10),
  foo        number
);

insert into table1 values ('xyz', 1);
insert into table1 values ('wxy', 2);
insert into table1 values ('abc', 3);

create type table1_obj as object (
  start_time varchar2(10),
  foo        number
);
/

create type table1_tab as table of table1_obj;
/


declare
  v table1_tab;
begin

  select table1_obj(start_time, foo) bulk collect into v
   from table1 where start_time like '%x%';
end;
/
于 2013-08-01T21:41:45.033 回答
0

您必须创建一个参数化游标并将该日期作为参数传递给该游标，如下所示。

   CREATE or REPLACE procedure proc1(p_date date)
   as
        CURSOR C1 (date1 date)is
              SELECT * from TABLE1 where start_time LIKE date1;
  BEGIN
      FOR i in c1(p_dat)
      LOOP
        .......
      END LOOP;
      END;
于 2013-08-01T21:28:16.193 回答
0

看起来您缺少对几个基本构建块的理解：

  • 您需要一个 PL/SQL 数据结构，您将在其中保存从数据库表查询的数据集：PL/SQL Collections and Records。尤其参见嵌套表和记录变量。
  • 您使用PL/SQL 静态 SQL查询数据库。参见特别SELECT INTO声明。在这种情况下，不需要动态 SQL。
  • 但是当然，从数据库中获取一组行比只获取一行要困难一些。这里的关键字是：SELECT INTO Statement with BULK COLLECT Clause。请注意，根据您的查询和表大小，批量收集可能会耗尽服务器的内存（通过加载数百万行）。

这是一个可以让您快速入门的示例：

create table so26 (
  day date,
  event varchar(10)
);

insert all
into so26 values(trunc(sysdate - 1), 'foo1')
into so26 values(trunc(sysdate - 1), 'foo2')
into so26 values(trunc(sysdate - 1), 'foo3')
into so26 values(trunc(sysdate    ), 'bar')
into so26 values(trunc(sysdate + 1), 'zoo')
select 1 from dual;

select * from so26;

declare
  type event_list_t is table of so26%rowtype;
  v_events event_list_t := event_list_t();

  function get_events(p_day in date default sysdate) return event_list_t as
    v_events event_list_t := event_list_t();
  begin
    select *
      bulk collect into v_events
      from so26
     where day = trunc(p_day);

    return v_events;  
  end;
begin
  v_events := get_events(sysdate + 1);

  if v_events.first is null then
    dbms_output.put_line('no events on that day');
    return;
  end if;

  for i in v_events.first .. v_events.last loop
    dbms_output.put_line(i || ': event = ' || v_events(i).event);
  end loop;
end;
/

示例输出时get_events(sysdate - 1)：

1: event = foo1
2: event = foo2
3: event = foo3
于 2013-08-02T06:09:31.193 回答