25

是否可以在 groovy 中使用默认值命名参数？我的计划是创建一种对象工厂，可以在没有任何参数的情况下调用它，以获得具有默认值的对象。此外，我需要为对象显式设置任何参数的功能。例如，我相信这可以通过 Python 关键字参数实现。

我现在正在尝试的代码如下所示

// Factory method
def createFoo( name='John Doe', age=51, address='High Street 11') {
  return new Foo( name, age, address )
}

// Calls
Foo foo1 = createFoo()  // Create Foo with default values
Foo foo2 = createFoo( age:21 )  // Create Foo where age param differs from defaut
Foo foo3 = createFoo( name:'Jane', address:'Low Street 11' )  // You get the picture
// + any other combination available

我正在开发的真实应用程序将有更多的参数，因此需要更多的组合。

谢谢

更新：

我计划的工厂方法是用于测试目的。不能真正触及实际的 Foo 类，尤其是它的默认值。

下面的@dmahapatro 和@codelarks answere 很好地使用了 Map 作为参数，这让我对可能的解决方案有了一个想法。我可以使用所需的默认值创建一个映射并覆盖所需的值，然后将其传递给工厂方法。这可能会完成这项工作，除非我得到更好方法的提示，否则我会继续这样做。

我目前的方法如下

defaults = [ name:'john', age:61, address:'High Street']

@ToString(includeFields = true, includeNames = true)
class Foo {
  // Can't touch this :)
  def name = ''
  def age = 0
  def address = ''
}

def createFoo( Map params ) {
  return new Foo( params )
}

println createFoo( defaults )
println createFoo( defaults << [age:21] )
println createFoo( defaults << [ name:'Jane', address:'Low Street'] )

注意： leftShift 操作 ( << ) 会修改原始地图，因此在上面的示例中，最后一次方法调用中的年龄也是 21。就我而言，这不是问题，因为每次在 setup 方法中都可以重新创建默认映射。

4

1 回答 1

38

Groovy 默认为您执行此操作（映射构造函数）。您不需要工厂方法。这是一个例子

import groovy.transform.ToString

@ToString(includeFields = true, includeNames = true)
class Foo{
    String name = "Default Name"
    int age = 25
    String address = "Default Address" 
}

println new Foo()
println new Foo(name: "John Doe")
println new Foo(name: "Max Payne", age: 30)
println new Foo(name: "John Miller", age: 40, address: "Omaha Beach")

//Prints
Foo(name:Default Name, age:25, address:Default Address)
Foo(name:John Doe, age:25, address:Default Address)
Foo(name:Max Payne, age:30, address:Default Address)
Foo(name:John Miller, age:40, address:Omaha Beach)

更新
@codelark 的占星术:)。如果无法访问该类以设置默认值，您可以这样做

@ToString(includeFields = true, includeNames = true)
class Bar{
    String name
    int age
    String address
}

def createBar(Map map = [:]){
    def defaultMap = [name:'John Doe',age:51,address:'High Street 11']
    new Bar(defaultMap << map)
}

println createBar()
println createBar(name: "Ethan Hunt")
println createBar(name: "Max Payne", age: 30)
println createBar(name: "John Miller", age: 40, address: "Omaha Beach")


//Prints
Bar(name:John Doe, age:51, address:High Street 11)
Bar(name:Ethan Hunt, age:51, address:High Street 11)
Bar(name:Max Payne, age:30, address:High Street 11)
Bar(name:John Miller, age:40, address:Omaha Beach)
于 2013-08-01T18:59:02.667 回答