2 
 TYPE ref_cur IS REF CURSOR;
 ref_cur_name    ref_cur;
 TYPE tmptbl IS  TABLE OF ref_cur_name%ROWTYPE;
 n_tmptbl        tmptbl;

我试过这段代码，但无法通过编译器得到它。有没有办法将 ref cursor 的结果存储到表中？

注意-我需要一个表格，因为我需要访问 ref cursor 的列。用于访问refdbms_sql游标的记录对我来说有点困难。

更新 ：

/* Formatted on 8/1/2013 4:09:08 PM (QP5 v5.115.810.9015) */
CREATE OR REPLACE PROCEDURE proc_deduplicate (p_tblname   IN VARCHAR2,
                                               p_cname     IN VARCHAR2,
                                               p_cvalue    IN VARCHAR2)
IS
   v_cnt          NUMBER;

   TYPE ref_cur IS REF CURSOR;
   ref_cur_name   ref_cur;


   v_str1         VARCHAR2 (4000);
   v_str2         VARCHAR2 (4000);
   v_str3         VARCHAR2 (4000);
BEGIN
   v_str1 :=
         'SELECT ROWID v_rowid FROM '
      || p_tblname
      || ' WHERE '
      || p_cname
      || '='''
      || p_cvalue
      || '''';


   BEGIN
      v_str2 :=
            'SELECT   COUNT ( * )

         FROM  '
         || p_tblname
         || ' WHERE  '
         || p_cname
         || ' = '''
         || p_cvalue
         || '''';
      logerrors ('proc_deduplicate',
                 'count exception',
                 SQLCODE,
                 v_str2 || SQLERRM,
                 'e');

      EXECUTE IMMEDIATE v_str2 INTO   v_cnt;
   EXCEPTION
      WHEN OTHERS
      THEN
         logerrors ('proc_deduplicate',
                    'count exception',
                    SQLCODE,
                    SQLERRM,
                    'e');
   END;

   IF v_cnt IS NOT NULL
   THEN
     OPEN ref_cur_name FOR v_str1;

      LOOP
         IF v_cnt = 1
         THEN
            EXIT;
         ELSE
            BEGIN
               v_str3 :=
                     'DELETE FROM '
                  || p_tblname
                  || ' WHERE   ROWID = v_rowid '; 
 -- THIS IS THE PROBLEM . i just created an alias above for rowid keyword but i guess, DBMS sql will have to be used  after all . 


               EXECUTE IMMEDIATE v_str3;
            EXCEPTION
               WHEN OTHERS
               THEN
                  logerrors (
                     '                                                            proc_deduplicate
      ',
                     '                                                            delete exception
      ',
                     SQLCODE,
                     SQLERRM,
                     '                                                            e
      '
                  );
            END;
         END IF;

         v_cnt := v_cnt - 1;
      END LOOP;
   END IF;
EXCEPTION
   WHEN OTHERS
   THEN
      logerrors (
         '                                    proc_deduplicate',
         '                                    final exception
      ',
         SQLCODE,
         SQLERRM,
         '                                    e'
      );
END;
/
4

4 回答 4

3

通过发出TYPE ref_cur IS REF CURSOR您声明一个弱游标。弱游标不返回指定类型。这意味着您不能声明属于 的变量weak_cursor%rowtype，仅仅因为弱游标不返回任何类型。

declare
  type  t_rf  is ref cursor;
  l_rf  t_rf;
  type  t_trf is table of l_rf%rowtype;
  l_trf t_trf;
begin
  null;
end;

ORA-06550: line 4, column 27:
PLS-00320: the declaration of the type of this expression is incomplete or malformed
ORA-06550: line 4, column 3:
PL/SQL: Item ignored

如果你为你的引用游标指定返回类型，使它变得强大，你的 PL/SQL 块将成功编译：

 SQL> declare                            -- strong cursor
  2    type  t_rf  is ref cursor return [table_name%rowtype][structure]; 
  3    l_rf  t_rf;                                         
  4    type  t_trf is table of l_rf%rowtype;
  5    l_trf t_trf;
  6  begin
  7    null;
  8  end;
  9  /

PL/SQL procedure successfully completed
于 2013-08-01T10:03:52.223 回答
2

据我了解你在做什么，你只需要参数化删除：

...
   v_str3         VARCHAR2 (4000);
   v_rowid        ROWID;
BEGIN
...
     OPEN ref_cur_name FOR v_str1;

      LOOP
         FETCH ref_cur_name INTO v_rowid;
         EXIT WHEN ref_cur_name%NOTFOUND;
         IF v_cnt = 1
         THEN
            EXIT;
         ELSE
            BEGIN
               v_str3 :=
                     'DELETE FROM '
                  || p_tblname
                  || ' WHERE   ROWID = :v_rowid '; 

               EXECUTE IMMEDIATE v_str3 USING v_rowid;
...

您需要将 获取ref_cur_name到一个需要明确声明的变量中，然后将其用作删除中的绑定变量值。

p_cvalue您也应该对其他动态 SQL 中的引用执行相同的操作。您可以在单个动态语句中使用单个删除且没有显式计数使这变得更简单：

CREATE OR REPLACE PROCEDURE proc_deduplicate (p_tblname   IN VARCHAR2,
                                               p_cname     IN VARCHAR2,
                                               p_cvalue    IN VARCHAR2)
IS
BEGIN
   execute immediate 'delete from ' || p_tblname
      || ' where ' || p_cname || ' = :cvalue'
      || ' and rowid != (select min(rowid) from ' || p_tblname
          || ' where ' || p_cname || ' = :cvalue)'
      using p_cvalue, p_cvalue;
END proc_deduplicate;
/

SQL 小提琴。

SQL%ROWCOUNT如果您想知道或报告删除了多少行，可以参考execute immediate.

于 2013-08-01T11:11:17.060 回答
2

强引用游标返回定义的值，但弱是任何东西，完全动态的。

但是我们不能rowtype在弱参考 cur 上定义变量，例如

declare 
 refcur sys_refcursor;
 emprec refcur%rowtype; --it'll yield error

尽管

declare
 type empref is ref cursor returns employees%rowtype;
 empcur empref;
 emprec empcur%rowtype; --it'll work fine.

这非常有用，现在我们可以在它们上定义集合和许多其他优点，如果你实际谈论的话。

于 2016-09-16T07:32:38.480 回答
1

不。无论如何，您都在尝试针对游标的实例声明类型，因此您会更接近：

TYPE tmptbl IS TABLE OF ref_cur%ROWTYPE;

但你仍然不能这样做，你会得到PLS-00310: with %ROWTYPE attribute, 'REF_CUR' must name a table, cursor or cursor-variable.

引用游标是弱类型的，因此编译器不知道记录会是什么样子。您可以根据块中的逻辑或动态查询为不同的结果打开 ref 游标，编译器将无法提前知道会发生什么。

可应用于显式游标、强游标变量或表或视图的PL/SQL 文档状态。这比较了强游标变量和弱游标变量。%rowtype

如果您知道您的查询将是什么，您可以record使用这些字段声明一个类型，或者%rowtype如果您正在查询单个表，则可以针对一个表。既然你正在使用dbms_sql我猜你不会知道。也许如果您使用有关您实际尝试做的更多信息来更新您的问题，那么您可以尝试其他一些方法。

于 2013-08-01T10:04:18.600 回答