0

我已经开始使用 XSL 并且遇到了唯一动态列数据的问题。我读过类似的问题，但这种情况似乎有很大不同，我看不到这些解决方案在这个问题上的应用。

我有以下示例数据集，这些数据集可以随着大量<ID>和<Date>值而增长或缩小：

<Report>
  <DataSets>
    <Data>
      <ID>1</ID>
      <Date>201211</Date>
    </Data>
    <Data>
      <ID>1</ID>
      <Date>201211</Date>
    </Data>
    <Data>
      <ID>1</ID>
      <Date>201210</Date>
    </Data>
    <Data>
      <ID>2</ID>
      <Date>201209</Date>
    </Data>
    <Data>
      <ID>1</ID>
      <Date>201208</Date>
    </Data>
    <Data>
      <ID>2</ID>
      <Date>201208</Date>
    </Data>
    <Data>
      <ID>3</ID>
      <Date>201208</Date>
    </Data>
    <Data>
      <ID>3</ID>
      <Date>201208</Date>
    </Data>
  </DataSets>
</Report>

我正在尝试获取 XSL 代码以生成下表：

ID  201208  201209  201210  201211
1     1       0       1       2 
2     1       1       0       0
3     2       0       0       0

列是动态的，列标题是<Date>元素的唯一值。这些行是唯一 ID 的集合，数据是<ID>每个ID 的计数<Date>。我正在努力的是动态创建<ID>for each的计数<Date>。

到目前为止，我使用生成表的键有以下 XSL 文件，但正如您所见，日期是硬编码的 atm。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                version="1.0" >

<xsl:template match ="/" >
<html>
  <body>
    <xsl:apply-templates select="Report/DataSets"/>
  </body>
</html>
</xsl:template>

<xsl:key name="Data_ID" match="Data" use="ID" />
<xsl:key name="Data_D" match="Data" use="Date"/>
<xsl:template match="Report/DataSets" >
<table>
  <tr>
    <th>ID</th>
    <xsl:for-each select="Data[generate-id(.) = generate-id(key('Data_D', Date)[1])]"> 
      <xsl:sort select="Date"/>
      <!-- Dynamically add headers for each Date Column -->
      <th><xsl:value-of select="Date"/></th>
    </xsl:for-each>
  </tr>
  <xsl:for-each select="Data[generate-id(.) = generate-id(key('Data_ID', ID)[1])]"> 
  <xsl:sort select="ID"/>
  <tr>
    <td><xsl:value-of select="ID"/></td>
    <!-- Dynamically count IDs for each Date Column -->
    <!-- How to do this step? -->
    <td><xsl:value-of select="count(key('Data_ID', ID)[Date='201208'])"/></td>
    <td><xsl:value-of select="count(key('Data_ID', ID)[Date='201209'])"/></td>
    <td><xsl:value-of select="count(key('Data_ID', ID)[Date='201210'])"/></td>
    <td><xsl:value-of select="count(key('Data_ID', ID)[Date='201211'])"/></td>
  </tr>
  </xsl:for-each>
</table>
</xsl:template>
</xsl:stylesheet>

替换这些硬编码条目需要什么

<td><xsl:value-of select="count(key('Data_ID', ID)[Date='201208'])"/></td>
<td><xsl:value-of select="count(key('Data_ID', ID)[Date='201209'])"/></td>
<td><xsl:value-of select="count(key('Data_ID', ID)[Date='201210'])"/></td>
<td><xsl:value-of select="count(key('Data_ID', ID)[Date='201211'])"/></td>

用动态代码？

4

1 回答 1

0

您可以使用与for-each标题相同的类型

  <!-- store the full set of Data in a variable - we will need it inside the for-eaches -->
  <xsl:variable name="allData" select="Data"/>
  <xsl:for-each select="$allData[generate-id(.) = generate-id(key('Data_ID', ID)[1])]"> 
  <xsl:sort select="ID"/>
  <xsl:variable name="currentId" select="ID" />
  <tr>
    <td><xsl:value-of select="$currentId"/></td>
    <!-- Dynamically count IDs for each Date Column -->
    <xsl:for-each select="$allData[generate-id(.) = generate-id(key('Data_D', Date)[1])]"> 
      <xsl:sort select="Date"/>
      <td>
        <xsl:value-of select="count(key('Data_ID', $currentId)[Date=current()/Date])"/>
      </td>
    </xsl:for-each>
  </tr>
  </xsl:for-each>

这里的技巧是将ID外部的 保存for-each在一个变量中，这样您就可以在内部时访问它for-each。

一个可能更有效的替代方法是在 ID 和 Date 上定义第三个键

<xsl:key name="Data_ID_D" match="Data" use="concat(ID, '|', Date)" />

这将简化count表达式

<xsl:for-each select="$allData[generate-id(.) = generate-id(key('Data_D', Date)[1])]"> 
  <xsl:sort select="Date"/>
  <td>
    <xsl:value-of select="count(key('Data_ID_D', concat($currentId, '|', Date)))"/>
  </td>
</xsl:for-each>
于 2013-07-30T17:48:18.830 回答