xslt - 使用 exslt:node-set() 在 xslt-1.0 中将 XML 转换为 csv

Question

我希望在 xslt-1.0 的帮助下将我的输入 xml 转换为 csv 输出。下面是我输入的 xml格式。

     <input>
     <add add-value="First Name">
        <value type="string">New</value>
      </add>
       <add add-value="Surname">
        <value  type="string">user1</value>
      </add>
      <add add-value="Title">
        <value type="string">engineer</value>
     </add>
     <add add-value="Description">
        <value type="string">New joinee.</value>
      </add>
<add .....
</add>
    </input>

输出 csv 由我通过 xslt 中的变量提供的固定数量的列组成。

下面是我的xslt：

     <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:ext="http://exslt.org/common" >   
        <xsl:variable name="delimiter" select="','"/>   
        <xsl:template match="input/add">
            <xsl:variable name="SplitWordsSet">
                <xsl:call-template name="split">
                    <xsl:with-param name="pText" select="'First name,Surname,Phone number,Description,Title'"/>
                </xsl:call-template>
            </xsl:variable>
            <xsl:variable name="vSplitWords" select="ext:node-set($SplitWordsSet)/*"/>

            <xsl:call-template name="counter">
                <xsl:with-param name="split-words" select="$vSplitWords"/>
                <xsl:with-param name="count"select="1"/>
            </xsl:call-template>
        </xsl:template> 
<!-- Below templtate splits the pText values -->
        <xsl:template name="split">
            <xsl:param name="pText"/>
            <xsl:param name="pElemName" select="'word'"/>
            <xsl:variable name="first" select="substring-before(concat($pText,','),',')"/>
            <xsl:variable name="remaining" select="substring-after($pText,',')"/>
            <xsl:element name="{$pElemName}">
                <xsl:value-of select="$first"/>
            </xsl:element>
            <xsl:choose>
                <xsl:when test="$remaining">
                    <xsl:call-template name="split">
                        <xsl:with-param name="pText" select="$remaining"/>
                        <xsl:with-param name="pElemName" select="$pElemName"/>
                    </xsl:call-template>
                </xsl:when>
            </xsl:choose>
        </xsl:template> 
<!-- below is recursive template to maintain count of columns values -->
        <xsl:template name="counter">
            <xsl:param name="count" select="1"/>
            <xsl:param name="split-words"/>
            <xsl:variable name="split-word" select="$split-words[$count]"/>
            <xsl:if test="$count &lt; 6">
                <xsl:call-template name="output-csv">
                    <xsl:with-param name="field-value" select="*[(@add-value = '$split-word')]/value"/>
                </xsl:call-template>
                <xsl:value-of select="$delimiter"/>
                <xsl:call-template name="counter">
                    <xsl:with-param name="count" select="$count + 1"/>
                </xsl:call-template>
            </xsl:if>
        </xsl:template>     
        <xsl:template name="output-csv">
            <xsl:param name="field-value"/>
        <xsl:value-of select="$field-value"/>
        </xsl:template>
    </xsl:stylesheet>

我感兴趣的附加值属性作为参数传递。pText这些值是我在输出 csv 中的列。

我的预期输出：

First name,Surname,Phone number,Description,Title
New,User1,,New joinee,engineer

但我无法获得所需的输出。我只得到逗号,,,,, 请有人指出我哪里出错了。

Answer 1

您的 XSLT 中有几个问题。首先，在您的初始模板匹配中，您正在匹配添加元素，但由于它是代表 CSV 文件中的一行的输入元素，您可能希望在该元素上进行匹配

<xsl:template match="input">

然后，当您调用output-csv模板时，您应该寻找具有当前单词的正确add-value属性的add元素。

<xsl:call-template name="output-csv">
   <xsl:with-param name="field-value" select="add[@add-value = $split-word]/value"/>
</xsl:call-template>

不过，您的主要问题是如何递归调用计数器模板。您没有在此处重新设置split-words属性，因此在第二次调用时，参数将为空。

 <xsl:call-template name="counter">
    <xsl:with-param name="count" select="$count + 1"/>
 </xsl:call-template>

（可能还值得指出的是，在您的 XML 中，您的第一个属性是“名字”，但在 XSLT 中的列名列表中，它是“名字”。XSLT 中的字符串比较区分大小写）。

您可以只在此处设置参数，但将拆分词列表设为全局变量可能会更好（当然更有效），而不是为每个输入元素拆分它们。

试试这个 XSLT

 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:ext="urn:schemas-microsoft-com:xslt" >   
    <xsl:variable name="delimiter" select="','"/>
   <xsl:variable name="SplitWordsSet">
     <xsl:call-template name="split">
       <xsl:with-param name="pText" select="'First name,Surname,Phone number,Description,Title'"/>
     </xsl:call-template>
   </xsl:variable>
   <xsl:variable name="vSplitWords" select="ext:node-set($SplitWordsSet)/*"/>

    <xsl:template match="input">
        <xsl:call-template name="counter">
            <xsl:with-param name="count" select="1"/>
        </xsl:call-template>
    </xsl:template> 

  <!-- Below templtate splits the pText values -->
    <xsl:template name="split">
        <xsl:param name="pText"/>
        <xsl:param name="pElemName" select="'word'"/>
        <xsl:variable name="first" select="substring-before(concat($pText,','),',')"/>
        <xsl:variable name="remaining" select="substring-after($pText,',')"/>
        <xsl:element name="{$pElemName}">
            <xsl:value-of select="$first"/>
        </xsl:element>
        <xsl:choose>
            <xsl:when test="$remaining">
                <xsl:call-template name="split">
                    <xsl:with-param name="pText" select="$remaining"/>
                    <xsl:with-param name="pElemName" select="$pElemName"/>
                </xsl:call-template>
            </xsl:when>
        </xsl:choose>
    </xsl:template>

 <!-- below is recursive template to maintain count of columns values -->
    <xsl:template name="counter">
        <xsl:param name="count" select="1"/>
        <xsl:param name="split-words"/>

        <xsl:variable name="split-word" select="$vSplitWords[$count]"/>
        <xsl:call-template name="output-csv">
          <xsl:with-param name="field-value" select="add[@add-value = $split-word]/value"/>
        </xsl:call-template>
        <xsl:if test="$count &lt; 5">
            <xsl:value-of select="$delimiter"/>
            <xsl:call-template name="counter">
                <xsl:with-param name="count" select="$count + 1"/>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>     
    <xsl:template name="output-csv">
        <xsl:param name="field-value"/>
    <xsl:value-of select="$field-value"/>
    </xsl:template>
</xsl:stylesheet>

这应该给你输出

 New,user1,,New joinee.,engineer

但是，您可以采取另一种方法，而无需使用递归模板。有一个与您的拆分词元素匹配的模板，将当前输入作为参数传递

   <xsl:template match="word">
     <xsl:param name="input" />
     <xsl:if test="position() > 1">
       <xsl:value-of select="$delimiter"/>
     </xsl:if>
     <xsl:value-of select="$input/add[@add-value = current()]/value" />
   </xsl:template>

然后，每一行都可以像这样输出

      <xsl:apply-templates select="$vSplitWords">
        <xsl:with-param name="input" select="." />
      </xsl:apply-templates>

也试试这个 XSLT

 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:ext="urn:schemas-microsoft-com:xslt" >   
    <xsl:variable name="delimiter" select="','"/>

   <xsl:variable name="SplitWordsSet">
     <xsl:call-template name="split">
       <xsl:with-param name="pText" select="'First name,Surname,Phone number,Description,Title'"/>
     </xsl:call-template>
   </xsl:variable>
   <xsl:variable name="vSplitWords" select="ext:node-set($SplitWordsSet)/*"/>

    <xsl:template match="input">
      <xsl:apply-templates select="$vSplitWords">
        <xsl:with-param name="input" select="." />
      </xsl:apply-templates>
    </xsl:template> 

 <!-- Below templtate splits the pText values -->
    <xsl:template name="split">
        <xsl:param name="pText"/>
        <xsl:param name="pElemName" select="'word'"/>
        <xsl:variable name="first" select="substring-before(concat($pText,','),',')"/>
        <xsl:variable name="remaining" select="substring-after($pText,',')"/>
        <xsl:element name="{$pElemName}">
            <xsl:value-of select="$first"/>
        </xsl:element>
        <xsl:choose>
            <xsl:when test="$remaining">
                <xsl:call-template name="split">
                    <xsl:with-param name="pText" select="$remaining"/>
                    <xsl:with-param name="pElemName" select="$pElemName"/>
                </xsl:call-template>
            </xsl:when>
        </xsl:choose>
    </xsl:template>

   <xsl:template match="word">
     <xsl:param name="input" />
     <xsl:if test="position() > 1">
       <xsl:value-of select="$delimiter"/>
     </xsl:if>
     <xsl:value-of select="$input/add[@add-value = current()]/value" />
   </xsl:template>

</xsl:stylesheet>