delphi - Delphi：检测鼠标滚轮按钮按下

Question

关于 TMemo 组件，我找不到检测用户何时释放鼠标上的 WHEEL 按钮的方法。标准 OnMouseUp 事件不响应鼠标滚轮按钮。

Answer 1

那个带有上下箭头的小圆圈是 VCL 的平移窗口，它在按下中间按钮时提供滚动功能。

默认平移窗口 ，TPanningWindow在其方法中捕获鼠标StartPanning以便能够跟随鼠标移动，并且在平移停止之前不会释放它 - 这是由于再次单击。这就是为什么备忘录永远不会收到中间按钮向上消息，因此OnMouseUp不会触发事件。

OnMessage您可以在“应用程序”的处理程序中检测按钮向上消息，然后将其发送到平移窗口。下面的示例代码在组件的OnMessage事件处理程序中TApplicationEvents，测试当平移窗口平移“Memo1”时是否检索到消息。

uses
  imouse;

procedure TForm1.ApplicationEvents1Message(var Msg: tagMSG;
  var Handled: Boolean);
begin
  if (Msg.message = WM_MBUTTONUP) and Assigned(Mouse.PanningWindow) and
    (Mouse.PanningWindow.HandleAllocated) and
    (Msg.hwnd = Mouse.PanningWindow.Handle) and
    (Mouse.PanningWindow is TPanningWindow) and
    (TPanningWindow(Mouse.PanningWindow).PanControl = Memo1) then

  // perform what's required

end;

---

或者，您可以注册自己的平移窗口类，Mouse.PanningWindowClass它可以通知它对某些消息的平移控件。这是一个例子：

uses
  imouse;

type
  TMyPanningWindow = class(TPanningWindow)
  protected
    procedure WndProc(var Msg: TMessage); override;
  end;

{ TMyPanningWindow }

procedure TMyPanningWindow.WndProc(var Msg: TMessage);
begin
  inherited;
  if (Msg.Msg = WM_MBUTTONUP) and (Assigned(PanControl)) then
    PanControl.Perform(Msg.Msg, Msg.WParam, Msg.LParam);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Mouse.PanningWindowClass := TMyPanningWindow;
end;