16

我正在尝试将Cayenne 中的一个示例翻译成 Idris - 一种具有依赖类型的语言 论文。

这是我到目前为止所拥有的：

PrintfType : (List Char) -> Type
PrintfType Nil                = String
PrintfType ('%' :: 'd' :: cs) = Int -> PrintfType cs
PrintfType ('%' :: 's' :: cs) = String -> PrintfType cs
PrintfType ('%' ::  _  :: cs) = PrintfType cs
PrintfType ( _  :: cs)        = PrintfType cs

printf : (fmt: List Char) -> PrintfType fmt
printf fmt = rec fmt "" where
  rec : (f: List Char) -> String -> PrintfType f
  rec Nil acc = acc
  rec ('%' :: 'd' :: cs) acc = \i => rec cs (acc ++ (show i))
  rec ('%' :: 's' :: cs) acc = \s => rec cs (acc ++ s) 
  rec ('%' ::  _  :: cs) acc = rec cs acc  -- this is line 49
  rec ( c  :: cs)        acc = rec cs (acc ++ (pack [c]))

我使用而List Char不是格式参数来促进模式匹配，因为我很快就遇到了模式匹配的复杂性。StringString

不幸的是，我收到一条我无法理解的错误消息：

Type checking ./sprintf.idr
sprintf.idr:49:Can't unify PrintfType (Prelude.List.:: '%' (Prelude.List.:: t cs)) with PrintfType cs

Specifically:
    Can't convert PrintfType (Prelude.List.:: '%' (Prelude.List.:: t cs)) with PrintfType cs

如果我在and中注释掉所有带有 3 个元素（带有'%' :: ...）的模式匹配案例，那么代码就会编译（但显然没有做任何有趣的事情）。PrintfTypeprintf

如何修复我的代码以使其printf "the %s is %d" "answer" 42正常工作？

4

1 回答 1

15

在定义模式重叠的函数时，idris中似乎存在一些当前限制（例如'%' :: 'd'与 重叠c :: cs。经过多次尝试，我终于找到了解决方法：

data Format = End | FInt Format | FString Format | FChar Char Format
fromList : List Char -> Format
fromList Nil                = End
fromList ('%' :: 'd' :: cs) = FInt    (fromList cs)
fromList ('%' :: 's' :: cs) = FString (fromList cs)
fromList (c :: cs)          = FChar c (fromList cs)

PrintfType : Format -> Type
PrintfType End            = String
PrintfType (FInt rest)    = Int -> PrintfType rest
PrintfType (FString rest) = String -> PrintfType rest
PrintfType (FChar c rest) = PrintfType rest

printf : (fmt: String) -> PrintfType (fromList $ unpack fmt)
printf fmt = printFormat (fromList $ unpack fmt) where
  printFormat : (fmt: Format) -> PrintfType fmt
  printFormat fmt = rec fmt "" where
    rec : (f: Format) -> String -> PrintfType f
    rec End acc            = acc
    rec (FInt rest) acc    = \i: Int => rec rest (acc ++ (show i))
    rec (FString rest) acc = \s: String => rec rest (acc ++ s)
    rec (FChar c rest) acc = rec rest (acc ++ (pack [c]))

Format是表示格式字符串的递归数据类型。FInt是一个 int 占位符，FString是一个字符串占位符，FChar是一个 char 文字。使用Format我可以定义PrintfType和实现printFormat. 从那里，我可以顺利地扩展以获取字符串而不是 aList Char或Format值。最终结果是：

*sprintf> printf "the %s is %d" "answer" 42
"the answer is 42" : String
于 2013-08-01T07:40:07.713 回答