11

我必须比较 2 stringlist ，我想知道在第二个 stringlist 中搜索第一个 stringlist 是否是执行此问题的唯一或推荐版本

我的代码会这样

var
  aFirstStrList: TStringList ;
  aSecondStringList: TStringList; 
  MissingElement_firstElement_not_inside_second: TStringList;
  MissingElement_SecondElement_not_inside_First: TStringList;

...

for i := 0 to aFirstStrList.Count - 1 do
begin
  if aSecondStringList.IndexOf(aFirstStrList[i] < 0 ) then
  begin
    // react on not found elements 
    ....
    MissingElement_firstElement_not_inside_second.add(...);
  end;
end;
// and now same code just opposite search direction .... 
....
4

3 回答 3

12

不要使用IndexOf, 之前对两个列表进行排序，以防止在每个循环中搜索整个列表。此外，可以在一个循环中实现这一点。

假设您想要两个单独的字符串列表中的结果，请尝试以下操作：

procedure CompareStringLists(List1, List2: TStringList;
  Missing1, Missing2: TStrings);
var
  I: Integer;
  J: Integer;
begin
  List1.Sort;
  List2.Sort;
  I := 0;
  J := 0;
  while (I < List1.Count) and (J < List2.Count) do
  begin
    if List1[I] < List2[J] then
    begin
      Missing2.Add(List1[I]);
      Inc(I);
    end
    else if List1[I] > List2[J] then
    begin
      Missing1.Add(List2[J]);
      Inc(J);
    end
    else
    begin
      Inc(I);
      Inc(J);
    end;
  end;
  for I := I to List1.Count - 1 do
    Missing2.Add(List1[I]);
  for J := J to List2.Count - 1 do
    Missing1.Add(List2[J]);
end;

用法：

procedure TForm1.Button1Click(Sender: TObject);
var
  List1: TStringList;
  List2: TStringList;
begin
  List1 := TStringList.Create;
  List2 := TStringList.Create;
  try
    List1.CommaText := 'A, C, F, G, H, K, L, M, N, O, Q, R';
    List2.CommaText := 'C, D, E, F, J, P, Q, S, T, U, V, W';
    Memo1.Lines.Assign(List1);
    Memo2.Lines.Assign(List2);
    CompareStringLists(List1, List2, Memo3.Lines, Memo4.Lines);
  finally
    List2.Free;
    List1.Free;
  end;
end;
于 2013-07-27T08:05:15.520 回答
0

最佳性能：
对输入字符串列表进行排序
与类似于合并排序列表的算法进行比较（您会发现每个列表中缺少的内容）

更简单但更慢：将字符串列表
复制到结果
字符串列表 第一个字符串列表的一个循环（对此使用反向循环for Count-1 downto 0 do）
如果找到，则在第二个中搜索相同的字符串 - 从两个列表中删除
差异将保留在字符串列表中

于 2013-07-27T08:00:12.100 回答
0

您必须小心 CompareStringLists 的实现。默认情况下，TStringList 的 Sort 例程将不区分大小写，但使用的比较是区分大小写的，如果您的列表中有任何混合大小写，您将得到假定的不匹配的井喷。

要么需要将排序设置为区分大小写

List1.CaseSensative := true ;
List1.Sort ;
List2.CaseSensative := true ;
List2.Sort ;

或者

使比较不区分大小写

如果 UpperCase(List1[I]) < UpperCase(List2[J]) 那么

和

else if UpperCase(List1[I]) > UpperCase(List2[J]) then

分别。

于 2017-03-21T09:19:06.653 回答