0

我需要一个脚本的帮助，该脚本应该计算|特定字符串之前的数量。

信息.txt

text=jam|hello=123|result=ok|cow=cat|...

因此，在此示例中，如果您搜索 result=，答案应该是 2。这可能批量吗？

4

4 回答 4

2

尝试这个：

@ECHO OFF &SETLOCAL
SET "string=text=jam|hello=123|result=ok|cow=cat|..."
SET "stop=result=ok"
SET "char=|"

SET /a count=-1
SET "org=%string%"
:loop
FOR /f "tokens=1*delims=%char%" %%a IN ("%string%") DO SET "this=%%a"&SET "that=%%b"
IF DEFINED that (SET "string=%that%") ELSE (SET "string=%this%")
SET /a count+=1
IF NOT DEFINED string (ECHO NOT found: "%stop%" &GOTO :EOF)
IF NOT "%this%"=="%stop%" GOTO :loop
ECHO Number of "%char%" IN "%org%" until "%stop%": %count%
于 2013-07-26T07:04:47.923 回答
1

这使用了一个名为 repl.bat 的辅助批处理文件：来自 - http://www.dostips.com/forum/viewtopic.php?f=3&t=3855

如果您在下面调用此代码，searchstring.bat则可以像这样启动它

searchstring "result="

它要求每个文件只有一个匹配项，并且区分大小写。

@echo off
type "file.txt" | find "%~1" | repl "(.*).%~1.*" "$1" | repl "\x7c" "\r\n" x | find /c /v ""

下面的这个批处理文件将返回行号的计数和数字本身，当数字大于零时，每行file.txt

@echo off
if "%~1"=="" ( echo add a search term&pause&goto :EOF)
for /f "tokens=1,* delims=:" %%a in ('findstr /n "^" "file.txt" ') do (
for /f %%c in (' echo "%%b"^| find "%~1" ^| repl "(.*).%~1.*" "$1" ^| repl "\|" "\r\n" x ^| find /c /v "" ') do (
if %%c GTR 0 echo Line %%a: %%c
)
)
pause
于 2013-07-26T00:51:29.067 回答
0

如果你想要，例如，第三个字符串：

SET "text=jam|hello=123|result=ok|cow=cat|..."
FOR /F "TOKENS=3" %%t IN ("%text%") DO ECHO %%t

如果你想要，例如，第三个字符串和以下：

SET "text=jam|hello=123|result=ok|cow=cat|..."
FOR /F "TOKENS=2,*" %%t IN ("%text%") DO ECHO %%u
于 2013-07-26T11:02:32.960 回答
0

这是另一种方式（使用您的 info.txt 文件）。不区分大小写。处理文件中匹配字符串的多行。

@echo off
set "SpecificString=result=ok"
set /A cnt=0
for /F "tokens=*" %%A IN (info.txt) do (
   for /F "usebackq tokens=*" %%B IN (`echo."%%A" ^| find /I "%SpecificString%"`) do (
      call :Parse "%%~A"
      )
   )
pause
goto :eof

:Parse
for /F "usebackq tokens=1* delims=^|" %%B IN (`echo."%~1"`) do (
   if /I "%%~B"=="%SpecificString%" (
      echo.Cnt=%Cnt% in "%%A"
      echo.
      set /A Cnt=0
      goto :eof
      )
   set /A Cnt+=1
   call :Parse "%%~C
   )
goto :eof
于 2013-07-26T11:16:27.363 回答