0

我在 Flash 中有这个功能：

public function checkFile(file:String):Boolean{
                var b:Boolean;
                var responder:Responder = new Responder(function(reply:Boolean):void{
                    b=reply;
                    msg("vid_"+file+".flv "+ "exists? " + reply);
                    setState("ready");
                    status = "ready";
                },
                    function(res:Object):void{
                        trace("checkFile call failed");
                    });
                mync.call("checkFile",responder,"vid_"+file);
                return b;
            }

我可以确认该reply变量为真，但return b最终为假：

这是我用来调用 flash 函数的 javascript：

function checkFile(){
   alert(thisMovie("vidRecorder").checkFile(currentVid));           
}

这会打开一个消息框说false，而闪存文件显示true

这是怎么回事？如何修复它以便我的函数返回与 相同的值reply？

4

1 回答 1

1

发生这种情况是因为您的响应程序中的匿名函数是异步执行的。

当你的checkFile()函数返回的值b仍然是false。最终，您的匿名函数被执行并b设置为true... 但在这种情况下为时已晚，因为您的checkFile()函数已经返回false。

要解决此问题，您可以考虑以稍微不同的方式执行此操作：

当你的匿名函数被执行时，让它通过异步响应调用 javascript。像这样的东西：

public function checkFile(file:String):void {
    var responder:Responder = new Responder(function(reply:Boolean):void{
        msg("vid_"+file+".flv "+ "exists? " + reply);
        setState("ready");
        status = "ready";
        ExternalInterface.call('someJavascriptFunction', reply);
    },
    function(res:Object):void{
        trace("checkFile call failed");
    });
    mync.call("checkFile",responder,"vid_"+file);
    // note we no longer return a value here
}

在上面的代码中，我们调用了一个新的 Javascript 函数并将异步操作的结果提供给它。

于 2013-07-25T20:04:10.293 回答