0

我对奇怪的 Grails 行为变得疯狂。

我得到一个域类用户：

class User {

    String firstName
    String token
    List roles = [] as List

    static constraints = {
    }
}

我像这样修改我的 BootStrap.groovy 以填充 5 个用户实例：

class BootStrap {

    def init = { servletContext ->
        switch (Environment.getCurrent()) {
            case 'DEVELOPMENT':
                def user1 = new User(
                    id: 1,
                    firstName: 'Enricot',
                    token: 'L\'abricot'
                )
                user1.roles.add('ROLE_USER')
                user1.save(failOnError: true)
                def user2 = new User(
                    id: 2,
                    firstName: 'Arnaud',
                    token: 'Dauphin')
                user2.roles.add('ROLE_USER')
                user2.roles.add('PERM_WRITE')
                user2.save(failOnError: true)
                def user3 = new User(
                    id: 3,
                    firstName: 'Magalie',
                    token: 'La banane')
                user3.roles.add('ROLE_USER')
                user3.roles.add('PERM_READ')
                user3.save(failOnError: true)
                def user4 = new User(
                    id: 4,
                    firstName: 'Jeremy',
                    token: 'Wistiti')
                user4.roles.add('ROLE_USER')
                user4.roles.add('ROLE_ADMIN')
                user4.save(failOnError: true)
                def user5 = new User(
                    id: 5,
                    firstName: 'Jimini',
                    token: 'Criquet')
                user5.roles.add('ROLE_USER')
                user5.roles.add('ROLE_INTERACTIONS')
                user5.save(failOnError: true)
                break
            case "test":
                DataBuilder.init()
                break
        }
    }
    def destroy = {
    }
}

在我的控制器中，当我获得一个用户时，所有字段都是正确的，除了列表。

如果我做 ：

def user = User.get(1)
println user.firstName // Output is "Enricot"
println user.token // Output is "L'abricot"
println user.roles // Output is "[]" and not "[ROLE_USER]"

尝试像这样填充对象并没有解决我的问题：

def user1 = new User(
        id: 1,
        firstName: 'Enricot',
        token: 'L\'abricot',
        roles: ['ROLE_USER']).save(failOnError: true)

我尝试过双引号，简单引号。

最有趣的部分是当我将“user.roles”制作成 BootStrap.groovy 时，我得到了正确的列表。

这对我来说毫无意义，欢迎任何帮助，

4

2 回答 2

6

这不是奇怪的行为，你做错了:)

当您添加一个想要持久化的字段时，您需要向 Grails 提供有关如何存储它的信息。仅仅一个简单List的信息是不够的。如果它是其他域类的列表，它将创建一个外键并存储 id。如果它是一个字符串列表，它会将它们存储为 varchars。如文档所示，您需要执行以下操作：

class User {
   String firstName
   String token
   static hasMany = [roles: String]
}

这会将支持集合更改为 a Set，但这对于角色可能是正确的，因为您不关心排序并且想要唯一性。如果您确实需要排序，请添加一个未初始化的List字段以向 Grails 发出您不想要的信号Set：

class User {
   String firstName
   String token
   List roles
   static hasMany = [roles: String]
}

这会改变您填充数据的方式。不要直接添加到集合中，而是使用addToRoles为您添加的动态方法：

class BootStrap {
   def init = { ctx ->
      environments {
         development {
            def user1 = new User(firstName: 'Enricot', token: 'L\'abricot')
            user1.addToRoles('ROLE_USER')
            user1.save(failOnError: true)
            def user2 = new User(firstName: 'Arnaud', token: 'Dauphin')
            user2.addToRoles('ROLE_USER')
            user2.addToRoles('PERM_WRITE')
            user2.save(failOnError: true)
            def user3 = new User(firstName: 'Magalie', token: 'La banane')
            user3.addToRoles('ROLE_USER')
            user3.addToRoles('PERM_READ')
            user3.save(failOnError: true)
            def user4 = new User(firstName: 'Jeremy', token: 'Wistiti')
            user4.addToRoles('ROLE_USER')
            user4.addToRoles('ROLE_ADMIN')
            user4.save(failOnError: true)
            def user5 = new User(firstName: 'Jimini', token: 'Criquet')
            user5.addToRoles('ROLE_USER')
            user5.addToRoles('ROLE_INTERACTIONS')
            user5.save(failOnError: true)
         }
         test {
            DataBuilder.init()
         }
      }
   }
}

有关BootStrap.groovy 中环境块支持的信息，请参见http://grails.org/doc/latest/guide/conf.html#environments 。

另请注意，我删除了您的显式 id 值，因为您没有使用分配的 id，因此这些值被忽略。

最后，看起来您正在滚动自己的安全性。不要这样做。使用经过验证的框架。Spring Security Core和Shiro功能强大且易于上手。

于 2013-07-25T18:32:22.873 回答
3

这是 grails 的正常行为。下面的代码只是将项目添加到当前对象的列表中（重要！不是数据库引用）：

user1.roles.add('ROLE_USER')

要将数据库映射添加到角色，请使用如下动态方法：

user1.addToRoles('ROLE_USER')

假设：您的意思是您的域

List<Strings> roles 
static hasMany = [roles:String]
于 2013-07-25T18:21:37.093 回答