xslt - 使用 xslt1.0 按字母顺序对节点数据进行排序

Question

我想按字母顺序显示州名和国家名。如果有任何与 state 关联的county1 节点，我需要显示所有带有国家名称的州。但是，如果没有以某个字母开头的州，例如“X”，那么它不应该显示为 empty 。我很确定 xslt 可以做到这一点，但不知道如何去做。所以你们那里的大师，pleeeeeeeease帮助我。我正在使用visaul stuido2010 xml编辑器和xslt1.0 ..我无法更改xslt版本..我在这里被击中..

My Input xml Looka like below : 
     <?xml version="1.0" encoding="utf-8" ?>
        <countries>
         <country>
            <state>Ontario</state>
            <country1>CANADA</country1>
          </country>
          <country>
            <state>Swindon</state>
          </country>
          <country>
            <state>CAMDEN</state>
          </country>
          <country>
            <state>NJ</state>
            <country1>America</country1>
          </country>
          <country>
           <state>NJ</state>
            <country1>America</country1>
           </country>
          <country>
            <state>NY</state>
            <country1>America</country1>
           </country>
          <country>
             <state>DE</state>
            <country1>America</country1>
          </country>
          <country>
            <state>Queenland</state>
            <country1>Australia</country1>
          </country>
          <country>
            <state>APstate</state>
          </country>
          <country>
            <state>ANstate</state>
          </country>
        </countries>

我的输出如下所示：

A
America
  - DE
  - NJ
  - NY
ANstate
APstate
Australia
  -Queenland
C
CAMDEN
CANADA
  -Ontario
S
Swindon

Answer 1

这为您提供了您要求的精确输出。

请注意，这是三级分组，在 XSLT 1.0 中最容易使用变量而不是使用 Muenchian 方法来完成。在 XSLT 2.0 中更容易。

t:\ftemp>type countries.xml 
<?xml version="1.0" encoding="utf-8" ?>
        <countries>
         <country>
            <state>Ontario</state>
            <country1>CANADA</country1>
          </country>
          <country>
            <state>Swindon</state>
          </country>
          <country>
            <state>CAMDEN</state>
          </country>
          <country>
            <state>NJ</state>
            <country1>America</country1>
          </country>
          <country>
           <state>NJ</state>
            <country1>America</country1>
           </country>
          <country>
            <state>NY</state>
            <country1>America</country1>
           </country>
          <country>
             <state>DE</state>
            <country1>America</country1>
          </country>
          <country>
            <state>Queenland</state>
            <country1>Australia</country1>
          </country>
          <country>
            <state>APstate</state>
          </country>
          <country>
            <state>ANstate</state>
          </country>
        </countries>
t:\ftemp>call xslt countries.xml countries.xsl 

A
America
  - DE
  - NJ
  - NY
ANstate
APstate
Australia
  - Queenland
C
CAMDEN
CANADA
  - Ontario
S
Swindon
t:\ftemp>type countries.xsl 
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">

<xsl:output method="text"/>

<xsl:template match="countries">
  <!--set the population to be all top-level sorted constructs-->
  <xsl:variable name="countries"
                select="country/country1 | country[not(country1)]/state"/>
  <xsl:for-each select="$countries">
    <xsl:sort select="."/>
    <xsl:if test="generate-id(.)=
                  generate-id($countries[substring(.,1,1) = 
                                         substring(current(),1,1)][1])">
      <!--at first of the letter-->
      <xsl:variable name="letters"
                    select="$countries[substring(.,1,1) = 
                                       substring(current(),1,1)]"/>
      <xsl:text>&#xa;</xsl:text>
      <xsl:value-of select="substring(.,1,1)"/>
      <xsl:for-each select="$letters">
        <xsl:sort select="."/>
        <xsl:if test="generate-id(.)=
                      generate-id($letters[. = current()][1])">
          <!--at first of a country-->
          <xsl:text>&#xa;</xsl:text>
          <xsl:value-of select="."/>
          <xsl:variable name="states"
                        select="$letters[. = current()]
                                          [self::country1]/../state"/>
          <xsl:for-each select="$states">
            <xsl:sort select="."/>
            <xsl:if test="generate-id(.)=
                          generate-id($states[.=current()][1])">
              <!--each of the states for a country-->
              <xsl:text>&#xa;  - </xsl:text>
              <xsl:value-of select="."/>
            </xsl:if>
          </xsl:for-each>
        </xsl:if>
      </xsl:for-each>
    </xsl:if>
  </xsl:for-each>
</xsl:template>

</xsl:stylesheet>
t:\ftemp>rem Done!