0

我的要求是将文件和文件夹从 SFTP 远程位置传输到 unix 位置。我是 perl 和 shell 脚本的新手，这非常令人困惑。我尝试使用来自 sftp foreign 的 rget 命令，如下所示。但它不起作用，也没有被转移。从 sftp 服务器复制文件和文件夹后，如何删除它们？

use Net::SFTP::Foreign;

my $host       = "sftp.elsevier.com";
my $remote_dir = "sample/host";
my $localdir = "sample/local";
my $username   = "username";
my $password   = "password";
my $debug      = 0;

$sftp = Net::SFTP::Foreign->new($host, timeout => 240,user => $username, password => $password) or $newerr = 1;
push @ERRORS, "Can't sftp to $host: $!\n" if $newerr;
myerr() if $newerr;
print "Connected to $host\n";

$sftp->rget($remote_dir, $localdir) or $newerr = 1;
push @ERRORS, "Cant tranfer\n" if $newerr;
myerr() if $newerr;
$sftp->disconnect if $newerr;
print "Files are transferred successfully\n";

#Deleting files

$sftp->setcwd($remote_dir) or $newerr = 1;
push @ERRORS, "Can't cd $!\n" if $newerr;
myerr()    if $newerr;
$sftp->disconnect if $newerr;

my $files = $sftp->ls or $newerr = 1;
push @ERRORS, "Can't get file list $!\n" if $newerr;
myerr() if $newerr;

foreach (@$files){
$sftp->remove($_) or $newerr = 1;
push @ERRORS, "Cant delete\n" if $newerr;
myerr() if $newerr;

print "Deleted files successfully\n";

#}
$sftp->disconnect;

sub myerr {
    print "Error: \n";
    print @ERRORS;
    exit 0;
}

在 SFTP 位置 - sample/host 内，我有许多文件夹和文件都需要复制到本地 unix 服务器 - sample/local 并从远程位置删除。

4

1 回答 1

7

你需要一本好的 Perl 书，它可以帮助你学习如何以更现代的风格编写 Perl。我推荐学习 Perl。这应该教你一些编码技巧。

例如，始终使用use strict;and use warnings;。这两个模块将捕获大约 99% 的所有编码错误。

此外，进行错误检查的标准方法是使用or die样式语法。这是一种比设置变量，然后检查变量，如果有错误，则进入子程序更自然的方法：

$stfp->ls or die qq(Cannot access remote machine ) . HOST;

如果你也缩进也很好。使您的代码更容易。

Perl 有一个标准，变量应该全部小写，最新的标准是使用下划线来帮助分隔变量名。常量应该全部大写。

您还应该查看模块的完整文档。例如，autodie当您创建一个Net::SFTP::Foreign对象时，有一个选项sftp会在任何失败时终止您的会话。这简化了编码，因为您不必检查错误。

您还需要知道Net::SFTP::Foreign->ls返回对数组的引用。因此，您需要取消引用该数组。您还必须知道此数组引用中的每个条目实际上是对哈希的引用，并且文件名位于filename该哈希引用的键下。

该文件还提到了一个小事实：该程序使用 Unix/Linux 安装的ssh客户端。如果您没有安装该ssh客户端，这将无法正常工作。

您可能想查看 Perl Tutorial on References

我已经重写了您的程序以利用autodie和使用更现代的语法。通常，我会对此进行测试，但不幸的是，我没有安装 Net::SFTP::Foreign，也没有可用于测试的远程计算机：

#! /usr/bin/env perl
use strict;
use warnings;
use feature qw(say);
use autodie;

use Net::SFTP::Foreign;

use constant {
    HOST            => "sftp.elsvier.com",
    REMOTE_DIR      => "sample/host",
    LOCAL_DIR       => "sample/local",
    USER_NAME       => "username",
    PASSWORD        => "password",
    DEBUG           => "0",
};

my $sftp;
$sftp = Net::SFTP::Foreign->new (
    HOST,
    timeout         => 240,
    user            => USER_NAME,
    password        => PASSWORD,
    autodie         => 1,
);

#
# Fetch Files
#
$sftp->rget( REMOTE_DIR, LOCAL_DIR );

#
# Delete Files
#

$sftp->setcwd( REMOTE_DIR );
my @files = @{ $sftp->ls };  #Returns a reference to an array of hashes

for my $file ( @files ) {
    $sftp->remove( $file->{filename} ); #Reference to a hash
}

say "Deleted files successfully";

$sftp->disconnect;
于 2013-07-25T02:05:04.960 回答