2

我有一排数据如下：

            header1      header2      header3      header4      header5
row key     datavalue1   datavalue2   datavalue3   datavalue4   datavalue5....

所以基本上，我有一个非规范化的数据集，其中数据值可能逐行为空，也可能不为空。我需要使它们正常化。

IE

12345678    NULL         10           3            NULL         14

会成为：

12345678   header2   10
12345678   header3   3
12345678   header5   14

我可以通过使用粘贴特殊转换来做到这一点，但我有数千行，我需要确保为每个行获得正确的行键。此外，每一行都有一堆与之相关的描述，我需要将这些描述与每个数据值一起复制。

转换每一行列的最简单方法是什么，以便我有单列的多行，其中包含所有非空数据值以及关联的数据值引用？我需要能够旋转数据集。

4

5 回答 5

3

如果您有五个“标题”列，请输入这些公式

H1: =OFFSET($A$1,INT((ROW()-1)/5)+1,0)
I1: =OFFSET($A$1,0,IF(MOD(ROW(),5)=0,5,MOD(ROW(),5)))
J1: =INDEX($A$1:$F$9,MATCH(H1,$A$1:$A$9,FALSE),MATCH(I1,$A$1:$F$1,FALSE))

复制 H1:J?? 并在顶部粘贴特殊值。对列 J 进行排序并删除任何为零的内容。如果您在数据中有合法的零，那么您首先需要用一些唯一的字符串替换空白单元格，然后您可以稍后将其删除。

如果您有更多列，请将上述所有公式中的“5”替换为您拥有的任何数字。

于 2009-11-23T19:58:51.077 回答
1

在我看来，您正在尝试做的部分工作是“取消透视”数据透视表。当我不得不做类似的任务时，我发现这个技巧是一个巨大的帮助：http: //spreadsheetpage.com/index.php/tip/creating_a_database_table_from_a_summary_table/

请注意，在 Excel 2007 中，您可以使用按键 Alt+D、P 进入旧的 Excel 2003 数据透视表向导。

于 2010-06-10T13:07:07.853 回答
1

Excel 具有转置功能，可以满足您的需求。它非常隐蔽且有点笨拙，但可能比深入研究 VBA 更容易。以下是 Excel 2007 帮助的摘录：

Blockquote 切换（转置）列和行 Show AllHide All 如果数据以列或行的形式输入，但您想将该数据重新排列为行或列，则可以快速将数据从一个转置到另一个。

例如，按列组织的区域销售数据在数据转置后出现在行中，如下图所示。

1.在工作表上，执行以下操作： 要将数据从列重新排列到行，请选择包含数据的列中的单元格。要将数据从行重新排列到列，请选择包含数据的行中的单元格。2.在主页选项卡的剪贴板组中，单击复制。

键盘快捷方式 要复制选定的数据，您也可以按 CTRL+C。

注意您只能使用复制命令重新排列数据。要成功完成此过程，请不要使用剪切命令。

3.在工作表上，选择要重新排列复制数据的目标行或列的第一个单元格。注意复制区域（复制区域：当您要将数据粘贴到另一个位置时复制的单元格。复制单元格后，它们周围会出现一个移动边框，表示它们已被复制。）和粘贴区域（粘贴区域：使用 Office 剪贴板剪切或复制的数据的目标位置。）不能重叠。确保您在粘贴区域中选择了一个单元格，该单元格位于您从中复制数据的区域之外。

4.在主页选项卡的剪贴板组中，单击粘贴下方的箭头，然后单击转置。5.数据转置成功后，可以删除复制区的数据。提示 如果您转置的单元格包含公式，则会转置公式，并且会自动调整对转置单元格中数据的单元格引用。要确保公式继续正确引用非转置单元格中的数据，请在转置它们之前在公式中使用绝对引用。

有关详细信息，请参阅在相对引用、绝对引用和混合引用之间切换。

块引用

于 2011-10-24T21:53:17.673 回答
0

我将创建一个循环遍历每一行并将数据输出到另一个页面的 VBA 宏。这将允许您在数据输出后在新页面中创建数据透视表。

不确定您对 VBA 的熟悉程度，但这可以很容易地通过将数据加载到数组（或对象集合，如果您真的想正确执行）并将其写回来完成。

这是一个好的 VBA 文档的链接。

http://social.msdn.microsoft.com/Forums/en/isvvba/thread/d712dbdd-c876-4fe2-86d2-7d6323b4262c

编辑

请注意，这并不是一个完全有效的解决方案，而是一个真正的通用框架，可以帮助您朝着正确的方向前进。

作为一个通用示例，它做了很多你需要做的事情（不是最好的方法，但对于初学者来说可能是最简单的），这样的事情应该让你开始，虽然很难说没有看到更多的工作表.

Sub RowsToColumns ()
  Application.ScreenUpdating = False
  Dim srcWrkSheet As Worksheet
  Dim destWrkSheet As Worksheet
  Dim excelData as pExcelData
  Dim srcRowNumber As Long
  Dim srcRolNumber As Long
  Dim destRowNumber As Long
  Dim destColNumber As Long

  SET srcWrkSheet = Sheets("YourSourceWorkSheetName")
  SET destWrkSheet = Sheets("YourDestinationWorkSheetName")

  srcRowNumber = 1
  srcColNumber = 1
  destRowNumber = 1
  destColNumber = 1

  'Loop until blank row is encountered in column 1
  Do
    destWrkSheet.Cells(destRowNumber ,1).Value = "Header 1 " & srcWrkSheet.Cells(srcRowNumber,srcColNumber )
    destWrkSheet.Cells(destRowNumber ,1).Value = "Header 2 " & srcWrkSheet.Cells(srcRowNumber ,srcColNumber)

    srcRowNumber = srcRowNumber + 1
    srcColNumber = srcColNumber + 1
    destRowNumber = destRowNumber  + 1
  Loop Until srcWrkSheet .Cells(rowNumber, 1).value = ""

End Sub
于 2009-11-23T17:12:48.977 回答
0

让我们看一下 VBA 中可能的解决方案。我认为这真的会有所帮助。关于我的代码，您应该了解以下几点。

  • 您需要将此代码放在 VBA 中的代码模块中（与宏所在的位置相同）
  • 看看我给这些表起什么名字：Original 和 Normalized。您要么想要更改工作表名称或代码
  • 我正在检查字符串字段的值NULL。如果单元格为空，您将需要检查If IsEmpty(rngCurrent.Value) Then。

'

Sub NormalizeSheet()
Dim wsOriginal As Worksheet
Dim wsNormalized As Worksheet
Dim strKey As String
Dim clnHeader As Collection
Dim lngColumnCounter As Long
Dim lngRowCounterOriginal As Long
Dim lngRowCounterNormalized As Long
Dim rngCurrent As Range
Dim varColumn As Variant

Set wsOriginal = ThisWorkbook.Worksheets("Original")     'This is the name of your original worksheet'
Set wsNormalized = ThisWorkbook.Worksheets("Normalized") 'This is the name of the new worksheet'
Set clnHeader = New Collection

wsNormalized.Cells.ClearContents        'This deletes the contents of the destination worksheet'

lngColumnCounter = 2
lngRowCounterOriginal = 1
Set rngCurrent = wsOriginal.Cells(lngRowCounterOriginal, lngColumnCounter)

' We'll loop through just the headers to get a collection of header names'
Do Until IsEmpty(rngCurrent.Value)
    clnHeader.Add rngCurrent.Value, CStr(lngColumnCounter)
    lngColumnCounter = lngColumnCounter + 1
    Set rngCurrent = wsOriginal.Cells(lngRowCounterOriginal, lngColumnCounter)
Loop

'Here we'll reset our Row Counter and loop through the entire data set'
lngRowCounterOriginal = 2
lngRowCounterNormalized = 1
lngColumnCounter = 1

Do While Not IsEmpty(wsOriginal.Cells(lngRowCounterOriginal, lngColumnCounter))

    Set rngCurrent = wsOriginal.Cells(lngRowCounterOriginal, lngColumnCounter)
    strKey = rngCurrent.Value ' Get the key value from the current cell'
    lngColumnCounter = 2

    'This next loop parses the denormalized values for each row'
    Do While Not IsEmpty(wsOriginal.Cells(lngRowCounterOriginal, lngColumnCounter))
        Set rngCurrent = wsOriginal.Cells(lngRowCounterOriginal, lngColumnCounter)

        'We're going to check to see if the current value'
        'is equal to NULL. If it is, we won't add it to'
        'the Normalized Table.'
        If rngCurrent.Value = "NULL" Then
            'Skip it'
        Else
            'Add this item to the normalized sheet'
            wsNormalized.Range("A" & lngRowCounterNormalized).Value = strKey
            wsNormalized.Range("B" & lngRowCounterNormalized).Value = clnHeader(CStr(lngColumnCounter))
            wsNormalized.Range("C" & lngRowCounterNormalized).Value = rngCurrent.Value
            lngRowCounterNormalized = lngRowCounterNormalized + 1
        End If

        lngColumnCounter = lngColumnCounter + 1
    Loop
    lngRowCounterOriginal = lngRowCounterOriginal + 1
    lngColumnCounter = 1    'We reset the column counter here because we're on a new row'
Loop



End Sub
于 2009-11-23T20:06:26.053 回答