6

我正在使用 TIdHTTPServer 组件，到目前为止工作正常，但是当我使用此代码添加 SSL 支持时

  SSLHandler:= TIdServerIOHandlerSSLOpenSSL.Create(nil);
  SSLHandler.SSLOptions.CertFile := 'foo.pem';
  SSLHandler.SSLOptions.KeyFile := 'foo.pem';
  SSLHandler.SSLOptions.RootCertFile := 'foo.pem';
  SSLHandler.SSLOptions.Method := sslvSSLv23;
  SSLHandler.SSLOptions.Mode := sslmServer;

  SSLHandler.SSLOptions.VerifyDepth := 1;
  SSLHandler.SSLOptions.VerifyMode := [sslvrfPeer,sslvrfFailIfNoPeerCert,sslvrfClientOnce];

  idHttpServer1.IOHandler := SSLHandler;
  IdHTTPServer1.Bindings.Add.Port := 80;  
  IdHTTPServer1.Bindings.Add.Port := 443;       
  IdHTTPServer1.Active := True;

服务器仅处理 https 请求，如果我发送 http 请求，则会引发此异常

Error accepting connection with SSL. error:1407609C:SSL routines:SSL23_GET_CLIENT_HELLO:http request

问题是：我可以使用单个 TIdHTTPServer 组件来处理 http 和 https 请求吗？如果答案是肯定的，如何做到这一点？如果答案是否定的，我必须创建两个 TIdHTTPServer 实例，一个用于 http，另一个用于 https？

4

1 回答 1

7

是的，您可以将单个TIdHTTPServer用于 HTTP 和 HTTPS。

如果您使用的是 Indy 9，那么它有一个错误，即所有客户端连接在连接到服务器时默认启用SSL。要解决这个问题，如果连接不在端口 443 上，请使用服务器的OnConnect事件手动关闭SSL，例如：

procedure TForm1.IdHTTPServer1Connect(AThread: TIdPeerThread);
begin
  if AThread.Connection.Socket.Binding.Port <> 443 then
    TIdSSLIOHandlerSocket(AThread.Connection.Socket).PassThrough := True;
end;

如果您使用的是 Indy 10，则该错误已修复，因此默认情况下所有客户端连接都将禁用SSL ，因此您可以：

  1. 如果连接在端口 443 上，则使用该OnConnect事件打开SSL ，例如：

    procedure TForm1.IdHTTPServer1Connect(AContext: TIdContext);
begin
  if AContext.Connection.Socket.Binding.Port = 443 then
    TIdSSLIOHandlerSocketBase(AContext.Connection.Socket).PassThrough := False;
end;

  2. （首选）使用新TIdHTTPServer.OnQuerySSLPort事件告诉服务器哪个端口应该使用 SSL，例如：

    procedure TForm1.IdHTTPServer1QuerySSLPort(APort: TIdPort; var VUseSSL: Boolean);
begin
  VUseSSL := (APort = 443);
end;
于 2013-07-22T23:05:21.077 回答