3

我得到了关于 OCaml 中函子的以下代码：

type comparison = Less | Equal | Greater;;

module type ORDERED_TYPE =
    sig
        type t
        val compare: t -> t -> comparison
    end
;;

module Set =
    functor (Elt: ORDERED_TYPE) ->
        struct
            type element = Elt.t
            type set = element list
            let empty = []
            let rec add x s =
                match s with
                | [] -> [x]
                | hd :: tl ->
                    match Elt.compare x hd with
                    | Equal -> s
                    | Less -> x :: s
                    | Greater -> hd :: add x tl
            let rec member x s =
                match s with
                | [] -> false
                | hd :: tl ->
                    match Elt.compare x hd with
                    | Equal -> true
                    | Less -> false
                    | Greater -> member x tl
    end
;;

module OrderedString : ORDERED_TYPE = 
    struct
        type t = string
        let compare x y =
            if x = y then Equal
            else if x < y then Less
            else Greater
    end
;;

module StringSet = Set(OrderedString);;

let out = StringSet.member "foo" (StringSet.add "foo" StringSet.empty);; (*compile error, where "foo" is expected OrderedString.t but actually is string*)

上面的错误可以通过消除: ORDERED_TYPEin来避免module OrderedString : ORDERED_TYPE =

就是不明白为什么。

类似地，如果模块中有任何类型，例如

module A = struct type t = string end;;

如何将字符串值指定为类型A.t而不是实际值string

谢谢。

4

2 回答 2

5

您可以在标准库中查看它是如何完成的：set.mli。函子的签名是

module Make (Ord : OrderedType) : S with type elt = Ord.t

该with type elt = Ord.t部分表示该elt类型不是抽象的。

于 2013-07-22T15:42:36.453 回答
2

正如 Tomash 所提到的，您缺少类型约束，但不是在函子签名中（实际上在您的代码中没有），而是在您提供给它的参数中。基本上，当你写

module OrderedString : ORDERED_TYPE = struct ... end

tin类型的定义OrderedString将被抽象掉，因为它是签名t中的抽象类型。ORDERED_TYPE您在这里想说的是，这OrderedString确实是 的实现ORDERED_TYPE，但具有已知类型t。这正是你会得到的

module OrderedString: ORDERED_TYPE with type t = string = struct ... end
于 2013-07-25T09:04:32.103 回答