在 Marpa 解析器中的无扫描接口(SLIF)的当前实现中，词法分析器似乎以下列方式进行最长标记匹配 (LTM)：
- 所有终端符号都尝试匹配输入中的当前位置。
- 除了最长的匹配项之外的所有匹配项都被丢弃。
- 这些最长的令牌被提供给解析器，解析器可能接受也可能不接受。
- 如果不接受任何标记，则解析失败。
当我的语法包含与最长子字符串匹配但不能出现在当前位置的标记时，这会产生令人沮丧的解析失败。考虑以下代码：
#!/usr/bin/env perl
use strict; use warnings; use feature qw/say/; use utf8;
use Marpa::R2;
use Data::Dump;
my @data = ('! key : value', '! key:value');
my $grammar = Marpa::R2::Scanless::G->new({
source => \<<'END_GRAMMAR',
:default ::= action => [values]
:start ::= record
:discard ~ ws
ws ~ [\s]+
record ::= ('!') key (':') value
key ~ [\w]+
value ~ [^\s]+
END_GRAMMAR
});
for my $data (@data) {
my $recce = Marpa::R2::Scanless::R->new({
grammar => $grammar,
trace_terminals => 0, # set this to "1" to see how the tokens are recognized
});
$recce->read(\$data);
my $val = $recce->value // die "no parse";
say ">> $data";
dd $$val;
}
这将产生输出：
>> ! key : value
["key", "value"]
Error in SLIF G1 read: No lexemes accepted at position 2
* Error was at end of input
* String before error: ! key:value
Marpa::R2 exception at marpa.pl line 33.
预期输出：
>> ! key : value
["key", "value"]
>> ! key:value
["key", "value"]
!被识别后，key必须跟随一个令牌。在此位置进行词法分析期间，value令牌匹配最长的子字符串key:value，尽管它不会出现在此位置。因此，解析失败。
问题：是否有可能在不编写手动词法分析器的情况下实现预期的输出？
（我知道词法分析器可以向识别器查询预期的标记，并且可以限制自己只匹配这些标记，但我不知道如何说服 SLIF 为我执行此操作。）
我在 perl5 v16.2 上运行 Marpa::R2 v2.064
编辑
按照 Jeffrey Kegler 的建议，我实现了一个规则，该规则将始终匹配比普通字符串更长的子字符串value，因此是首选。使用一个pause事件，我可以手动解析它，尽管我必须保留一个幻像规则以确保语义正确。
这是完整的更新代码，包括。事件处理和更新的测试用例：
#!/usr/bin/env perl
use strict; use warnings; use feature qw/say/; use utf8;
use Marpa::R2;
use Data::Dump;
my @data = ('! key : value', '! key:value', '! key :value', '! key: value');
my $grammar = Marpa::R2::Scanless::G->new({
source => \<<'END_GRAMMAR',
:default ::= action => [values]
:start ::= Record
:discard ~ ws
ws ~ [\s]+
Record ::=
('!') Key (<Op colon>) Value # not directly used
| ('!') KeyValue
Key ~ key
Value ~ value
KeyValue~ key <ws any> ':' <ws any> value
:lexeme ~ KeyValue pause => before event => 'before KeyValue'
<Op colon> ~ ':'
key ~ [\w]+
value ~ [^\s]+
<ws any>~ [\s]*
END_GRAMMAR
});
my %events = (
'before KeyValue' => sub {
my ($recce, $string, $start, $length) = @_;
my ($k, $o, $v) = split /(\s*:\s*)/, $string, 2;
say STDERR qq(k="$k" o="$o" v="$v");
my $pos = $start;
$recce->lexeme_read('Key' => $pos, length($k), $k);
$pos += length $k;
$recce->lexeme_read('Op colon' => $pos, length($o), $o);
$pos += length $o;
$recce->lexeme_read('Value' => $pos, length($v), $v);
},
);
for my $data (@data) {
my $recce = Marpa::R2::Scanless::R->new({
grammar => $grammar,
trace_terminals => 0,
});
my $length = length $data;
for (
my $pos = $recce->read(\$data);
$pos < $length;
$pos = $recce->resume()
) {
say STDERR "pause";
my ($start, $length) = $recce->pause_span();
my $str = substr $data, $start, $length;
for my $event_data (@{ $recce->events }) {
my ($name) = @$event_data;
my $code = $events{$name} // die "no code for event $name";
$recce->$code($str, $start, $length);
}
}
my $val = $recce->value // die "no parse";
say ">> $data";
dd $$val;
}
这产生
>> ! key : value
["key", "value"]
>> ! key:value
["key", "value"]
>> ! key :value
["key", "value"]
>> ! key: value
["key", "value"]
这是预期的行为。