如果我想像这样删除数据库中的所有表，它会处理外键约束吗？如果没有，我该如何处理？
GO
IF OBJECT_ID('dbo.[Course]','U') IS NOT NULL
DROP TABLE dbo.[Course]
GO
IF OBJECT_ID('dbo.[Student]','U') IS NOT NULL
DROP TABLE dbo.[Student]
user188229
问问题
394506 次
16 回答
367
不，如果确实有外键引用它，这不会删除您的表。
要获取引用您的表的所有外键关系，您可以使用此 SQL（如果您使用的是 SQL Server 2005 及更高版本）：
SELECT *
FROM sys.foreign_keys
WHERE referenced_object_id = object_id('Student')
如果有的话，使用这里的语句，您可以创建 SQL 语句来实际删除这些 FK 关系：
SELECT
'ALTER TABLE [' + OBJECT_SCHEMA_NAME(parent_object_id) +
'].[' + OBJECT_NAME(parent_object_id) +
'] DROP CONSTRAINT [' + name + ']'
FROM sys.foreign_keys
WHERE referenced_object_id = object_id('Student')
于 2009-11-21T17:24:51.273 回答
52
在 SQL Server Management Studio 2008 (R2) 和更新版本中，您可以右键单击
DB -> 任务 -> 生成脚本
选择要删除的表。
选择“保存到新的查询窗口”。
单击高级按钮。
将 Script DROP 和 CREATE 设置为 Script DROP。
将脚本外键设置为 True。
单击确定。
单击下一步 -> 下一步 -> 完成。
查看脚本，然后执行。
于 2013-09-11T14:23:21.160 回答
26
如果您首先删除“子”表，则外键也将被删除。如果您首先尝试删除“父”表，您将收到“无法删除对象 'a'，因为它被 FOREIGN KEY 约束引用”。错误。
于 2009-11-21T17:24:20.883 回答
20
这是使用sp_MSdropconstraints过程正确删除所有表的另一种方法。我能想到的最短代码：
exec sp_MSforeachtable "declare @name nvarchar(max); set @name = parsename('?', 1); exec sp_MSdropconstraints @name";
exec sp_MSforeachtable "drop table ?";
于 2014-10-13T20:04:55.810 回答
2
如果是 SQL Server，则必须先删除约束，然后才能删除表。
于 2009-11-21T17:23:18.093 回答
2
@mark_s 发布的内容稍微更通用的版本，这对我有帮助
SELECT
'ALTER TABLE ' + OBJECT_SCHEMA_NAME(k.parent_object_id) +
'.[' + OBJECT_NAME(k.parent_object_id) +
'] DROP CONSTRAINT ' + k.name
FROM sys.foreign_keys k
WHERE referenced_object_id = object_id('your table')
只需插入您的表名，然后执行它的结果。
于 2015-06-09T13:03:38.863 回答
1
这是删除表本身后面的所有约束的另一种方法，它使用串联技巧FOR XML PATH('')，允许将多个输入行合并到单个输出行中。应该适用于任何 SQL 2005 及更高版本。
为了安全起见，我已将 EXECUTE 命令注释掉。
DECLARE @SQL NVARCHAR(max)
;WITH fkeys AS (
SELECT quotename(s.name) + '.' + quotename(o.name) tablename, quotename(fk.name) constraintname
FROM sys.foreign_keys fk
JOIN sys.objects o ON fk.parent_object_id = o.object_id
JOIN sys.schemas s ON o.schema_id = s.schema_id
)
SELECT @SQL = STUFF((SELECT '; ALTER TABLE ' + tablename + ' DROP CONSTRAINT ' + constraintname
FROM fkeys
FOR XML PATH('')),1,2,'')
-- EXECUTE(@sql)
SELECT @SQL = STUFF((SELECT '; DROP TABLE ' + quotename(TABLE_SCHEMA) + '.' + quotename(TABLE_NAME)
FROM INFORMATION_SCHEMA.TABLES
FOR XML PATH('')),1,2,'')
-- EXECUTE(@sql)
于 2013-12-12T21:57:52.780 回答
1
这是实现解决方案的完整脚本：
create Procedure [dev].DeleteTablesFromSchema
(
@schemaName varchar(500)
)
As
begin
declare @constraintSchemaName nvarchar(128), @constraintTableName nvarchar(128), @constraintName nvarchar(128)
declare @sql nvarchar(max)
-- delete FK first
declare cur1 cursor for
select distinct
CASE WHEN t2.[object_id] is NOT NULL THEN s2.name ELSE s.name END as SchemaName,
CASE WHEN t2.[object_id] is NOT NULL THEN t2.name ELSE t.name END as TableName,
CASE WHEN t2.[object_id] is NOT NULL THEN OBJECT_NAME(d2.constraint_object_id) ELSE OBJECT_NAME(d.constraint_object_id) END as ConstraintName
from sys.objects t
inner join sys.schemas s
on t.[schema_id] = s.[schema_id]
left join sys.foreign_key_columns d
on d.parent_object_id = t.[object_id]
left join sys.foreign_key_columns d2
on d2.referenced_object_id = t.[object_id]
inner join sys.objects t2
on d2.parent_object_id = t2.[object_id]
inner join sys.schemas s2
on t2.[schema_id] = s2.[schema_id]
WHERE t.[type]='U'
AND t2.[type]='U'
AND t.is_ms_shipped = 0
AND t2.is_ms_shipped = 0
AND s.Name=@schemaName
open cur1
fetch next from cur1 into @constraintSchemaName, @constraintTableName, @constraintName
while @@fetch_status = 0
BEGIN
set @sql ='ALTER TABLE ' + @constraintSchemaName + '.' + @constraintTableName+' DROP CONSTRAINT '+@constraintName+';'
exec(@sql)
fetch next from cur1 into @constraintSchemaName, @constraintTableName, @constraintName
END
close cur1
deallocate cur1
DECLARE @tableName nvarchar(128)
declare cur2 cursor for
select s.Name, p.Name
from sys.objects p
INNER JOIN sys.schemas s ON p.[schema_id] = s.[schema_id]
WHERE p.[type]='U' and is_ms_shipped = 0
AND s.Name=@schemaName
ORDER BY s.Name, p.Name
open cur2
fetch next from cur2 into @schemaName,@tableName
while @@fetch_status = 0
begin
set @sql ='DROP TABLE ' + @schemaName + '.' + @tableName
exec(@sql)
fetch next from cur2 into @schemaName,@tableName
end
close cur2
deallocate cur2
end
go
于 2013-12-27T10:06:50.110 回答
1
Removing Referenced FOREIGN KEY Constraints
Assuming there is a parent and child table Relationship in SQL Server:
--First find the name of the Foreign Key Constraint:
SELECT *
FROM sys.foreign_keys
WHERE referenced_object_id = object_id('States')
--Then Find foreign keys referencing to dbo.Parent(States) table:
SELECT name AS 'Foreign Key Constraint Name',
OBJECT_SCHEMA_NAME(parent_object_id) + '.' + OBJECT_NAME(parent_object_id) AS 'Child Table'
FROM sys.foreign_keys
WHERE OBJECT_SCHEMA_NAME(referenced_object_id) = 'dbo' AND
OBJECT_NAME(referenced_object_id) = 'dbo.State'
-- Drop the foreign key constraint by its name
ALTER TABLE dbo.cities DROP CONSTRAINT FK__cities__state__6442E2C9;
-- You can also use the following T-SQL script to automatically find
--and drop all foreign key constraints referencing to the specified parent
-- table:
BEGIN
DECLARE @stmt VARCHAR(300);
-- Cursor to generate ALTER TABLE DROP CONSTRAINT statements
DECLARE cur CURSOR FOR
SELECT 'ALTER TABLE ' + OBJECT_SCHEMA_NAME(parent_object_id) + '.' +
OBJECT_NAME(parent_object_id) +
' DROP CONSTRAINT ' + name
FROM sys.foreign_keys
WHERE OBJECT_SCHEMA_NAME(referenced_object_id) = 'dbo' AND
OBJECT_NAME(referenced_object_id) = 'states';
OPEN cur;
FETCH cur INTO @stmt;
-- Drop each found foreign key constraint
WHILE @@FETCH_STATUS = 0
BEGIN
EXEC (@stmt);
FETCH cur INTO @stmt;
END
CLOSE cur;
DEALLOCATE cur;
END
GO
--Now you can drop the parent table:
DROP TABLE states;
--# Command(s) completed successfully.
于 2017-10-23T05:28:28.233 回答
1
一切都简单得多。有一个配置可以关闭检查并打开它。
例如，如果你使用 MySQL，那么要关闭它，你必须写 SET foreign_key_checks = 0;
然后删除或清表，重新启用检查 SET foreign_key_checks = 1;
于 2021-11-12T17:04:31.810 回答
0
使用 SQL Server 管理器，您可以从 UI 中删除外键约束。如果您想删除该表Diary但 User 表有一个DiaryId指向该Diary表的外键，您可以展开（使用加号）该User表，然后展开该Foreign Keys部分。右键单击指向日记表的外键，然后选择Delete。然后，您可以展开该Columns部分，右键单击并删除该列DiaryId。然后你可以运行：
drop table Diary
我知道您的实际问题是关于删除所有表，所以这对于这种情况可能没有用。但是，如果您只想删除几个表，我相信这很有用（标题没有明确提到删除所有表）。
于 2018-11-08T12:25:40.680 回答
0
执行以下代码以获取阻止您放置的外键约束名称。例如，我拿roles桌子。
SELECT *
FROM sys.foreign_keys
WHERE referenced_object_id = object_id('roles');
SELECT name AS 'Foreign Key Constraint Name',
OBJECT_SCHEMA_NAME(parent_object_id) + '.' + OBJECT_NAME(parent_object_id)
AS 'Child Table' FROM sys.foreign_keys
WHERE OBJECT_SCHEMA_NAME(referenced_object_id) = 'dbo'
AND OBJECT_NAME(referenced_object_id) = 'dbo.roles'
您将获得 FK 名称，如下所示：FK__Table1__roleId__1X1H55C1
现在运行下面的代码来删除从上面得到的 FK 引用。
ALTER TABLE dbo.users drop CONSTRAINT FK__Table1__roleId__1X1H55C1;
完毕！
于 2020-05-07T08:24:44.820 回答
0
找到所有外键.. 编写它们
SELECT * FROM sys.foreign_keys
WHERE referenced_object_id = object_id('Student')
然后从子表中删除外键。现在您可以删除父表。
如果您想重新创建父表，请确保运行您之前创建的脚本。
于 2022-02-02T12:13:11.063 回答
-1
如果您使用的是my sql 服务器（不是 MS SQL）并且不介意丢失表，则可以使用简单的查询一次删除多个表：
SET foreign_key_checks = 0;
DROP TABLE IF EXISTS table_a,table_b,table_c,table_etc;
SET foreign_key_checks = 1;
这样，您在查询中使用表的顺序无关紧要。
如果有人要说如果您有一个包含许多表的数据库，这不是一个好的解决方案这一事实：我同意！
于 2016-07-19T16:07:00.703 回答
-5
如果您想要DROP一个已被其他表使用外键引用的表，请使用
DROP TABLE *table_name* CASCADE CONSTRAINTS;
我认为它应该对你有用。
于 2015-12-04T06:36:22.557 回答
-9
如果我想删除数据库中的所有表
然后删除整个数据库要容易得多：
DROP DATABASE WorkerPensions
于 2009-11-21T18:03:20.570 回答