9

我正在尝试学习 GHC 泛型。在查看了几个示例之后，我想尝试创建一个通用Functor实例（忽略 GHC 可以为我自动派生它们）。但是，我意识到我不知道如何使用泛型处理参数化数据类型，我看到的所有示例都是类似的*。这是可能的，如果是的话，怎么做？（我也对其他类似的框架感兴趣，比如 SYB。）

4

2 回答 2

9

使用 GHC 泛型查找大量示例函数的最佳位置是generic-derivingpackage。那里有一个类的通用定义Functor。从以下位置复制（稍微简化）Generics.Deriving.Functor：

class GFunctor' f where
  gmap' :: (a -> b) -> f a -> f b

instance GFunctor' U1 where
  gmap' _ U1 = U1

instance GFunctor' Par1 where
  gmap' f (Par1 a) = Par1 (f a)

instance GFunctor' (K1 i c) where
  gmap' _ (K1 a) = K1 a

instance (GFunctor f) => GFunctor' (Rec1 f) where
  gmap' f (Rec1 a) = Rec1 (gmap f a)

instance (GFunctor' f) => GFunctor' (M1 i c f) where
  gmap' f (M1 a) = M1 (gmap' f a)

instance (GFunctor' f, GFunctor' g) => GFunctor' (f :+: g) where
  gmap' f (L1 a) = L1 (gmap' f a)
  gmap' f (R1 a) = R1 (gmap' f a)

instance (GFunctor' f, GFunctor' g) => GFunctor' (f :*: g) where
  gmap' f (a :*: b) = gmap' f a :*: gmap' f b

instance (GFunctor f, GFunctor' g) => GFunctor' (f :.: g) where
  gmap' f (Comp1 x) = Comp1 (gmap (gmap' f) x)


class GFunctor f where
  gmap :: (a -> b) -> f a -> f b
  default gmap :: (Generic1 f, GFunctor' (Rep1 f))
               => (a -> b) -> f a -> f b
  gmap = gmapdefault

gmapdefault :: (Generic1 f, GFunctor' (Rep1 f))
            => (a -> b) -> f a -> f b
gmapdefault f = to1 . gmap' f . from1

要在数据类型上使用它，您必须派生Generic1而不是Generic. 表示的主要区别Generic1在于它使用了Par1编码参数位置的数据类型。

于 2013-07-19T20:01:30.883 回答
3

有一个Generic1用于 kind 数据类型的类* -> *。使用它与使用数据类型的基本相同 kind *，除了Par1参数也有。例如，我在我的可展开包装中使用了它。

于 2013-07-19T17:40:44.213 回答