5

YouTube Flash API 中的错误代码 0 是什么意思？尝试使用 API 播放某些视频时会发生这种情况。API 参考中解释了其他错误代码，但没有错误代码 0。

如何让 YouTube 播放器播放所有视频，就像在YouTube 播放器演示中一样？

FLA 和 SWF 文件：https ://s3.amazonaws.com/YouTubeAPIError0/YouTubeAPIError0.zip

package {
    import flash.system.Security;
    import flash.display.MovieClip;
    import flash.display.Loader;
    import flash.events.Event;
    import flash.net.URLRequest;
    import fl.data.DataProvider;
    import fl.controls.ComboBox;
    import fl.controls.TextArea;

    public class YouTubeAS3 extends MovieClip {
        public var VidHolder:MovieClip;
        public var VidSelection:ComboBox;
        public var traceArea:TextArea;

        private var player:Object;
        private var loader:Loader;
        private var vidCollection:DataProvider;

        public function YouTubeAS3():void {
            Security.allowInsecureDomain("*");
            Security.allowDomain("*");

            vidCollection = new DataProvider();
            vidCollection.addItem({data:"eDdI7GhZSQA", label:"Video 1"});
            vidCollection.addItem({data:"S09F5MejfBE", label:"Video 2"});
            vidCollection.addItem({data:"QUwxKWT6m7U", label:"Video 3"});
            vidCollection.addItem({data:"TAbnQZZ6QXc", label:"Video 4"});
            vidCollection.addItem({data:"QH2-TGUlwu4", label:"Errorless Video"});

            VidSelection.dataProvider = vidCollection;
            VidSelection.addEventListener(Event.CHANGE, cueVideo);

            loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.INIT, onLoaderInit);
            loader.load(new URLRequest("http://www.youtube.com/apiplayer?version=3"));
        }

        private function onLoaderInit(event:Event):void {
            VidHolder.addChild(loader);
            loader.content.addEventListener("onReady", onPlayerReady);
            loader.content.addEventListener("onError", onPlayerError);
            loader.content.addEventListener("onStateChange", onPlayerStateChange);
            loader.content.addEventListener("onPlaybackQualityChange", onVideoPlaybackQualityChange);
        }

        private function onPlayerReady(event:Event):void {
            traceArea.text += "player ready: " + Object(event).data + "\r";
            player = loader.content;
            player.setSize(480, 360);
            VidSelection.selectedIndex = 0;
            VidSelection.dispatchEvent(new Event(Event.CHANGE));
        }
        private function cueVideo(event:Event):void {
            traceArea.text += "switch to: " + event.target.selectedItem.label + "\r";
            player.cueVideoById(event.target.selectedItem.data);
        }

        private function onPlayerError(event:Event):void {
            traceArea.text += "player error: " + Object(event).data + "\r";
        }

        private function onPlayerStateChange(event:Event):void {
            traceArea.text += "player state: " + Object(event).data + "\r";
        }

        private function onVideoPlaybackQualityChange(event:Event):void {
            traceArea.text += "video quality: " + Object(event).data + "\r";
        }
    }
}
4

3 回答 3

0

这是与YouTube AS3 Player API 错误代码 0相同的问题……当然，该问题也没有答案（不过，有趣的是，相同的 4 个视频被用作不可播放视频的示例）。

我唯一的建议是在数据中寻找模式。例如，v3 数据 API 显示您列出的所有 4 个未播放的视频在德国都被屏蔽，而您提供的可以播放的视频则没有这样的屏蔽。这将导致错误可能与区域块有关的假设（请注意，区域块与“可嵌入”块不同，后者是上传者可以设置的元数据）。在德国被屏蔽的视频都是这样，因为那里不允许 Vevo，而且都是 Vevo 视频。

当然，我并不一定暗示“不可玩性”是故意的，尽管它可能是；我不知道直接文档详细说明了当 API（与 Youtube 站点相反，它使用不同的方法来播放视频，因此您无法进行任何直接比较）尝试播放区域阻止的视频时会发生什么。也许@Dominic Orme 是正确的，因为它与超时有关，超时是由区域块引起的（或通过尝试使用代理绕过区域块）。

您可以通过查找其他适合该模式的视频来测试该理论。例如，是否所有 Vevo 视频都无法使用您的代码播放？在其他国家/地区被屏蔽的视频也无法播放吗？

于 2013-07-27T03:30:16.913 回答
0

我的错误状态为 0 - 当视频超时时。

如果您查看您正在使用的任何浏览器的开发人员工具，您应该会看到一个名为“videoplayback”的标注，该标注将超时。我在 7.5 分钟后超时，但这可能与连接有关。

此外，当前记录的错误状态中未涵盖“超时”错误。

于 2013-07-22T07:06:11.830 回答