1

你能告诉我这段代码有什么问题吗？

我需要用来DataAdapter插入表格吗？

我知道connectionString没问题，因为我在服务器资源管理器上对其进行了测试。

    Dim mydao As New Connection
    Dim connectionString As String = mydao.GetConnectionString()
    Dim connection As New SqlConnection(connectionString)
    Dim cmd As New SqlCommand

Public Function add(ByVal area As String, ByVal user As String) As Integer

        cmd.CommandText = "INSERT into Area (Area, user) VALUES ('" + area + "','" + user + "')"
        Try
            connection.Open()
            Dim cant As Integer = cmd.ExecuteNonQuery()'it throws exception here
            connection.Close()
            Return cant
        Catch ex As Exception
            Console.WriteLine(ex.Message)
            Return 0
        End Try

    End Function

上面的代码在之后就失败了ExecuteNonQuery()，无法弄清楚为什么。

目标字段（SQL Server 2008）：

AREA        varchar(100)  NOT NULL ,
USER        varchar(100)  NOT NULL

我收到的例外是：Connection property has not initialized

4

1 回答 1

11

这段代码有一些问题。

最重要的是您没有设置命令的连接属性，因此命令无法知道如何连接到数据库。

我还强烈建议使用using，并参数化您的查询：

最后，除非需要，否则不要在函数之外声明连接和命令。您应该只在需要时保持连接和命令。

所以你的函数最终看起来像：

Public Function add(ByVal area As String, ByVal user As String) As Integer

    Dim mydao As New Connection

    Using connection As New SqlConnection(mydao.ConnectionString())

        Using command As New SqlCommand()
            ' Set the connection
            command.Connection = connection 

            ' Not necessary, but good practice
            command.CommandType = CommandType.Text 

            ' Example query using parameters
            command.CommandText = "INSERT into Area (Area, user) VALUES (@area, @user)" 

            ' Adding the parameters to the command
            command.Parameters.AddWithValue("@area", area)
            command.Parameters.AddWithValue("@user", user)

            connection.Open()

            Return command.ExecuteNonQuery()

        End Using ' Dispose Command

    End Using ' Dispose (and hence Close) Connection

End Function

请注意，目前，您将一直返回 0。上面的示例无需检查函数返回的值，而是简单地抛出异常。这使得代码更加简洁（因为调用者必须理解 0 是错误条件），并且，如果您需要处理异常，只需将对该函数的调用包装在一个Try-Catch块中

于 2013-07-18T16:42:26.430 回答