0

我有一些代码应该运行我正在查询的 SQL 表的参数化查询。它这样做的方式是有一个指定的单元格 (Z1)，它应该从我的一个列中获取输入值，然后自动更新查询以在 excel 表中显示结果。我不断收到运行时错误：“1004”，表示这是一般 ODBC 错误，但我不确定发生了什么。这是我连接到的数据库：数据库

我使用的是 SQL Express，所以服务器是 .\SQLEXPRESS

这是我拥有的代码：

Sub ParameterQueryExample()
'---creates a ListObject-QueryTable on Sheet1 that uses the value in 
'        Cell Z1 as the ProductID Parameter for an SQL Query
'        Once created, the query will refresh upon changes to Z1. 

Dim sSQL As String
Dim qt As QueryTable
Dim rDest As Range


'--build connection string-must use ODBC to allow parameters
Const sConnect = "ODBC;" & _
    "Driver={SQL Server Native Client 10.0};" & _
    "Server=.\SQLEXPRESS;" & _
    "Database=TSQL2012;" & _
    "Trusted_Connection=yes"


'--build SQL statement
sSQL = "SELECT *" & _
        " FROM TSQL2012.Production.Products Products" & _
        " WHERE Products.productid = ?;"


'--create ListObject and get QueryTable
Set rDest = Sheets("Sheet1").Range("A1")
rDest.CurrentRegion.Clear  'optional- delete existing table


Set qt = rDest.Parent.ListObjects.Add(SourceType:=xlSrcExternal, _
    Source:=Array(sConnect), Destination:=rDest).QueryTable


'--add Parameter to QueryTable-use Cell Z1 as parameter
With qt.Parameters.Add("ProductID", xlParamTypeVarChar)
    .SetParam xlRange, Sheets("Sheet1").Range("Z1")
    .RefreshOnChange = True
End With


'--populate QueryTable
With qt
    .CommandText = sSQL
    .CommandType = xlCmdSql
    .AdjustColumnWidth = True  'add any other table properties here
    .BackgroundQuery = False
    .Refresh
End With


Set qt = Nothing
Set rDest = Nothing
End Sub
4

1 回答 1

1

在 Control Panel\System and Security\Administrative Tools 中打开 ODBC Data Source Admin 程序并检查您在代码中指定的驱动程序是否"Driver={SQL Server Native Client 10.0};"与 Drivers 选项卡下的驱动程序匹配。不匹配会产生此错误。

于 2013-07-18T15:44:53.650 回答