5

我有一些看起来像这样的 clojure 代码：

(defn rect [x y w h]
  {:x x, :y y, :w w, :h h})

(def left :x)
(def top :y)
(def width :w)
(def height :h)

(defn right [r]
  (+ (left r) (width r)))

(defn bottom [r]
  (+ (top r) (height r)))

现在下面的代码似乎有点不常见：

(def left :x)

但是我不知道任何其他方式来获得封装。

假设，我稍后想以不同的方式表示我的矩形。然后依赖 (:x rect) 不是一个好主意，因为 :x 仅适用于 hashmap 和记录，所以我会在 api 中泄露实现细节，至少在 OO 语言中这被认为是不好的做法。

现在，如果我决定在 java 中实现我的 rect，它会变得更糟，因为那时我将不得不编写如下包装器：

(defn left [rect] (.getLeft rect))

以确保界面不会改变。

clojure 如何解决这个问题？

4

2 回答 2

4

您可以使用协议。

首先是 Clojure 记录：

(defprotocol Rectangular
  (left [this])
  (right [this]))

(defrecord Rect [x y w h]
  Rectangular
  (left [this] x)
  (right [this] (+ x w)))

(def my-rect (Rect. 1 2 3 4))
(right my-rect) ;=> 4

现在是一个 Java 对象：

(import java.awt.Rectangle)

(extend-type Rectangle
  Rectangular
  (left [this] (int (.getX this)))
  (right [this] (int (+ (.getX this) (.getWidth this)))))

(def my-other-rect (Rectangle. 1 2 3 4))
(right my-other-rect) ;=> 4
于 2013-07-18T14:34:31.330 回答
2

Clojure 有协议和类型。您使用协议（如 Java 接口）识别抽象，并为这些抽象创建实现。还有多种方法可以让您更自由地选择方法分派的发生方式。

但是，按照示例中的方式构建数据非常常见。查看Leiningen 项目文件以及Ring 请求和响应的内容。即使您决定完全改变查找 x 和 y 值的方式，您也可以简单地创建一个在与映射相同的抽象上操作的类型。在这种情况下，这就是ILookup 协议。

于 2013-07-18T14:29:32.047 回答