6

我在这里有一点 Haskell 情况。我正在尝试用 monads 编写两个函数。只要函数的输入/输出条件为真，第一个就应该遍历函数。第二个应该使用第一个将数字作为输入并将其写入输出，直到您输入一个空格。

我被这个卡住了，有什么帮助吗？

module Test where

while :: (a -> Bool) -> (a -> IO a) -> a -> IO a
while praed funktion x = do
                         f <- praed (funktion x)
                         if f == True then do
                                             y <- funktion x
                                             while praed funktion y
                         else return x



power2 :: IO ()
power2 = do putStr (Please enter a number.")
            i <- getChar
            while praed funktion
            where praed x = if x /= ' ' then False else True
                  funktion = i
4

2 回答 2

12 
import Control.Monad

while :: (a -> Bool) -> (a -> IO a) -> a -> IO a
while praed funktion x
    | praed x   = do
        y <- funktion x
        while praed funktion y
    | otherwise = return x


power2 :: IO ()
power2 = do
    putStr "Please enter a number."
    i <- getChar
    let praed x = x /= ' '
    let f x = do
        putChar x
        getChar
    while praed f '?'
    return ()

一些注意事项：

  • usingif x then True else False是多余的，它相当于 just x。
  • 同样if x == True ...是多余的，等价于if x ...。

  • 您需要区分IO操作及其结果。例如，如果你这样做

    do
    i <- getChar
    ...

    那么 in ...i代表动作的结果，一个字符，所以i :: Char. 而是getChar :: IO Char动作本身。您可以将其视为Char执行时返回的配方。您可以将配方传递给函数等，并且仅在某处执行时才执行。

  • 您while调用funktion了两次，这可能不是您想要的 - 它会读取一个字符两次，检查第一个并返回第二个。请记住，您funktion是一个动作，因此每次“调用”该动作（例如通过<- funktion ...在do符号中使用）时，该动作都会再次运行。所以它应该是这样的

    do
    y <- funktion x
    f <- praed y
    -- ...

    （我的代码有些不同，它检查传递给它的参数。）

于 2013-07-18T09:55:55.167 回答
4

对于纯版本：

{-# LANGUAGE BangPatterns #-}

while :: (a -> Bool) -> (a -> a) -> a -> a
while p f = go where go !x = if p x then go (f x) else x

test1 :: Int
test1 = while (< 1000) (* 2) 2
-- test1 => 1024

对于一元：

import Control.Monad

whileM :: (Monad m, MonadPlus f) => (a -> m Bool) -> m a -> m (f a)
whileM p f = go where
  go = do
    x <- f
    r <- p x
    if r then (return x `mplus`) `liftM` go else return mzero

test2 :: IO [String]
test2 = whileM (return . (/= "quit")) getLine
-- *Main> test2
-- quit
-- []
-- *Main> test2
-- 1
-- 2
-- 3
-- quit
-- ["1","2","3"]

power2 :: IO (Maybe Char)
power2 = whileM (return . (/= 'q')) getChar
-- *Main> power2
-- q
-- Nothing
-- *Main> power2
-- 1
-- 2
-- 3
-- q
-- Just '\n'

也可以看看：

http://hackage.haskell.org/package/monad-loops，http://hackage.haskell.org/package/loop-while，http://hackage.haskell.org/package/control-monad-loop。_ _ _ _

http://www.haskellforall.com/2012/01/haskell-for-c-programmers-for-loops.html

于 2013-07-18T10:52:26.407 回答