2

我有这个工具（SSMS Tools Pack），它为特定表生成 CRUD sp

但是我看看“插入”代码

/*1*/   CREATE PROC [dbo].[usp_EServices_ME_Country_InfoInsert] 
/*2*/       @MasterEntityID int,
/*3*/       ...
/*4*/   AS 
/*5*/       SET NOCOUNT ON 
/*6*/       SET XACT_ABORT ON  
/*7*/       
/*8*/       BEGIN TRAN
/*9*/       
/*10*/      INSERT INTO [dbo].[EServices_ME_Country_Info] ([MasterEntityID],...)
/*11*/      SELECT @MasterEntityID, ...
/*12*/      
/*13*/      -- Begin Return Select <- do not remove
/*14*/      SELECT [ID], [MasterEntityID],...
/*15*/      FROM   [dbo].[EServices_ME_Country_Info]
/*16*/      WHERE  [ID] = SCOPE_IDENTITY()
/*17*/      -- End Return Select <- do not remove
/*18*/                  
/*19*/      COMMIT
/*20*/   GO

我的问题是关于第 14 行 - 他们/我可以使用output关键字吗？如果是这样，output会返回所有插入的记录吗？（如果在第 11 行插入了 >1 条记录）

4

2 回答 2

6

有趣的问题！根据此处OUTPUT条款的信息，我认为您可以更改此内容：

INSERT INTO [dbo].[EServices_ME_Country_Info] ([MasterEntityID],...)
SELECT @MasterEntityID, ...

-- Begin Return Select <- do not remove
SELECT [ID], [MasterEntityID],...
FROM   [dbo].[EServices_ME_Country_Info]
WHERE  [ID] = SCOPE_IDENTITY()
-- End Return Select <- do not remove

对此：

INSERT INTO [dbo].[EServices_ME_Country_Info] ([MasterEntityID],...)
OUTPUT INSERTED.MasterEntityID, ...
SELECT @MasterEntityID, ...

结果相同。这只是目前的理论，我会去测试这个并跟进。

跟进：

我的OUTPUT条款不正确，您必须OUTPUT在条款之后使用INSERT。在上面的查询中进行了编辑。我使用以下代码对此进行了测试：

-- Create a test table
CREATE TABLE TestTable (
    ID INT IDENTITY
    ,TestV1 INT
    ,TestV2 INT
    ,TestV3 INT
);
GO

-- Example sp with the 'old' method using SCOPE_IDENTITY()
CREATE PROCEDURE usp_InsertFirstMethod
(
    @v1 INT
    ,@v2 INT
    ,@v3 INT
)
AS

SET NOCOUNT ON 
SET XACT_ABORT ON  

BEGIN TRAN

INSERT INTO dbo.TestTable (TestV1, TestV2, TestV3)
SELECT @v1, @v2, @v3;

-- Begin Return Select <- do not remove
SELECT ID, TestV1, TestV2, TestV3
FROM   dbo.TestTable
WHERE  ID = SCOPE_IDENTITY()
-- End Return Select <- do not remove

COMMIT TRAN;
GO

-- Example sp to show use of OUTPUT clause
CREATE PROCEDURE usp_InsertSecondMethod
(
    @v1 INT
    ,@v2 INT
    ,@v3 INT
)
AS

SET NOCOUNT ON 
SET XACT_ABORT ON  

BEGIN TRAN

INSERT INTO dbo.TestTable (TestV1, TestV2, TestV3)
OUTPUT INSERTED.*
SELECT @v1, @v2, @v3;

COMMIT TRAN;
GO

两者都EXECUTE dbo.usp_InsertFirstMethod 1, 2, 3;显示EXECUTE dbo.usp_InsertSecondMethod 1, 2, 3;相同的结果。似乎工作！

于 2013-07-18T07:35:08.457 回答
1

这是使用OUTPUT子句 DECLARE @@table_variable table(MasterEntityID,...)的示例

INSERT INTO [dbo].[EServices_ME_Country_Info] ([MasterEntityID],...)
OUTPUT inserted.MasterEntityID,...
INTO  @table_variable
SELECT @MasterEntityID, ...

而且，是的，您还可以获得默认插入或作为 IDENTITY 插入的所有值。

于 2013-07-18T07:54:37.773 回答